3
$\begingroup$

Is there a command on Mathematica that helps me to get the answer of some harmonic series in terms on $\zeta(2n)$ instead of $\pi^{2n}$? Let me give you an example:

The command :

Sum[HarmonicNumber[n, 5]/n^8, {n, 1, Infinity}]

gives :

$$-(1/63) [\pi]^6 \zeta[7] - (13/15) [\pi]^4 \zeta[9] - 55 [\pi]^2 \zeta[11] + 644 \zeta[13]$$

I know converting $\pi^2$, $\pi^4$ and $\pi^6$ to $\zeta(2)$ , $\zeta(4)$ and $\zeta(6)$ is not a big deal but I deal with harmonic series a lot and converting is time consuming. Also I deal with harmonic series of high height which means more converting to do. So is there any command that gives the answer of the harmonic sum in terms of $\zeta(2n)$ instead of $\pi^{2n}$?

Thank you.

$\endgroup$
  • 1
    $\begingroup$ See Stop the Zeta function from evaluating for a related question. $\endgroup$ – Carl Woll Oct 4 '19 at 8:38
  • $\begingroup$ Perhaps sum /. Pi^n_?EvenQ :> Inactive[Zeta][n] // TraditionalForm $\endgroup$ – Michael E2 Oct 4 '19 at 10:58
  • $\begingroup$ Thank you Carl and Michael. $\endgroup$ – Ali Shather Oct 7 '19 at 3:51
5
$\begingroup$

One can make use of Simplify with Assumptions

I. Compute the sum

s=Sum[HarmonicNumber[n,5]/n^8,{n,1,Infinity}]
(* -(1/63) π^6 Zeta[7]-13/15 π^4 Zeta[9]-55 π^2 Zeta[11]+644 Zeta[13] *)

II. Make a table of Zeta-functions with even arguments

t=Flatten[Table[{ζ[2n]==Zeta[2n]},{n,0,6}]]
(* {ζ[0]==-(1/2),ζ[2]==π^2/6,ζ[4]==π^4/90,ζ[6]==π^6/945,ζ[8]==π^8/9450,ζ[10]==π^10/93555,ζ[12]==(691 π^12)/638512875} *)

III. Simplify with assumptions

Simplify[s/.{π->x,Zeta[n_]->ζ[n]},Assumptions->t/.{π->x}]
(* -15 ζ[6] ζ[7]-78 ζ[4] ζ[9]-330 ζ[2] ζ[11]+644 ζ[13] *)

Comments:

  1. A much cleaner solution would be to use the method of Carl Woll to deactivate the Zetafunction. However, it only works if the sum can be computed in the desired terms, i.e., in terms of Zeta[2n+1] and Zeta[2n]. This seems not to be the case.
  2. The present method only replaces the occurrences of $\pi^{2n}$ for $n\ge1$. The zeroth-order term is left unchanged. Below I show how Zeta[0] can be taken into account.

Different approach using SolveAlways

Define some functions

Clear[sf,sx,sxx]
sf[a_,b_]:=Sum[HarmonicNumber[n,a]/n^b,{n,1,Infinity}]/.{Zeta[n_]->ζ[n]}
sxx[c_]:=Sum[a[i]ζ[i]Zeta[c-i],{i,c,Floor[c/2],-2}]
sx[c_]:=Sum[a[i]ζ[i]ζ[c-i],{i,c,Floor[c/2],-2}]

Let us try

k=5;l=8;
sx[k+l]/.First[SolveAlways[(sf[k,l]==sxx[k+l]),Table[ζ[i],{i,k+l,Floor[(k+l)/2],-2}]]]
(* -15 ζ[6] ζ[7]-78 ζ[4] ζ[9]-330 ζ[2] ζ[11]-1288 ζ[0] ζ[13] *)
|improve this answer|||||
$\endgroup$
  • $\begingroup$ Thank you sir that's very helpful $\endgroup$ – Ali Shather Oct 4 '19 at 15:10
  • $\begingroup$ so what zeta(0) in the answer stands for ? $\endgroup$ – Ali Shather Oct 4 '19 at 16:43
  • 1
    $\begingroup$ $\zeta(0)=-\tfrac12$ as follows from the integral representation or from the analytic continuation of series. The series representation of $\zeta(s)$ converges only for $\mathrm{Re}s>1$ (en.wikipedia.org/wiki/Riemann_zeta_function). See also here math.stackexchange.com/questions/404401/… $\endgroup$ – yarchik Oct 4 '19 at 17:02
  • $\begingroup$ Thanks ... all clear now. $\endgroup$ – Ali Shather Oct 4 '19 at 17:33

Not the answer you're looking for? Browse other questions tagged or ask your own question.