What is the identity for Tuples?

Question

My question is, what list p in the following statement returns the list q?

Tuples[{{p},{q}}]

If we think of Tuples as a binary operator then p would be the identity for Tuples.

I thought an empty list would work, but evaluating the following

Tuples[{{},{1,2,3}}]

gives {} instead of {1,2,3} or {{1},{2},{3}} as I had hoped.

The following doesn't work either:

Tuples[{{\[EmptySet]},{1,2,3}}]

Certainly, I could write a function like the following

altTuples[p_List,q_List]:= If[Length[p]==0,q,Tuples[{p,q}]

That does exactly what I want, but I want to know if I'm missing something. Is there in fact an identity for Tuples? Is there a way to do what I want with Outer? I've tried the obvious solutions with no luck.

Answer 1

If {{1},{2},{3}} is fine, you can use Nothing:

Tuples[{Nothing, {1, 2, 3}}]
(* {{1}, {2}, {3}} *)

If you want {1,2,3}, you can Flatten the result, of course.

Answer 2

You can use Inactive[Sequence][] as identity like this:

Tuples[{{Inactive[Sequence][]},{q}}]//Activate

{{q}}

Answer 3

Use TagSetDelayed to define a function that behaves as desired:

ClearAll[iDentity]
iDentity /: {iDentity[___], a : {__}} := iDentity[a]
iDentity /: Tuples[iDentity[a_]] := a

Tuples[{iDentity[], {q}}]

{q}

Tuples[{iDentity[blah], {1, 2, 3}}]

{1, 2, 3}

Alternatively, define your function altTuples with two signatures:

ClearAll[altTuples]
altTuples[{tuplesIdentity | {} | Nothing, a_List}] := a
altTuples[x_] := Tuples[x]

altTuples[{{x, y}, {1, 2}}]

{{x, 1}, {x, 2}, {y, 1}, {y, 2}}

altTuples[{tuplesIdentity, {1, 2}}]

{1, 2}

altTuples[{{}, {1, 2}}]

{1, 2}

Answer 4

I think this is what you want:

altTuples[p_List, q_List] := If[Length[p] == 0, q, Tuples[{p, q}]]

The statement

altTuples[{}, {d, e, f}]

returns

{d, e, f}

and

altTuples[{a, b, c}, {d, e, f}]

returns

{{a, d}, {a, e}, {a, f}, {b, d}, {b, e}, {b, f}, {c, d}, {c, e}, {c, f}}