Find and load all ResourceFunctions as top level functions?

Question

I would like to be able to use ResourceFunction's as top-level symbols:

The reason being that some of them are so useful it would be really great not to have to type out ResourceFunction["FunctionName..."] each time.

Is there some way to load them all into System context once? For a bonus: add documentation locally.

The first issue is that I don't know how to find them all:

Answer 1

There is a helpful function named PersistResourceFunction that permanently stores a function.

Here is what I did:

<< ResourceSystemClient`;
ResourceFunction["PersistResourceFunction"]["PersistResourceFunction"];
names = ResourceSystemClient`Private`publicResourceInformation["Names"]["Function"];
PersistResourceFunction /@ names;

Update. Here is my code to prevent scope conflicts between functions in the repository that later became reserved:

<<ResourceSystemClient`;
ResourceFunction["PersistResourceFunction"]["PersistResourceFunction"];
reservednames=Names[];
resourcefunctionnames=ResourceSystemClient`Private`publicResourceInformation["Names"]["Function"];
distinctresourcefunctionnames=Complement[names,Intersection[names,reservednames]];
PersistResourceFunction /@ distinctresourcefunctionsnames;

Answer 2

I dug and found where the names for the autocomplete are cached:

<<ResourceSystemClient`;
names = ResourceSystemClient`Private`publicResourceInformation["Names"]["Function"];

If that doesn't work do this:

names =
  ResourceSearch[{"ResourceType" -> "Function", "Name" -> "*"}, MaxItems -> 1000][[All, "Name"]] // Normal;

Now you can do something like:

ToExpression[
 "System`" <> # & /@ names, 
 StandardForm,
 Function[
  Null,
  With[{sn = SymbolName[Unevaluated[#]]},
   SetDelayed[#, # = ResourceFunction[sn]]
   ],
  HoldAllComplete
  ]
 ]

And all the resource functions are dynamically loaded into the "System`" context

Answer 3

Just do

DynamicMap = ResourceFunction["DynamicMap"]

and now you can use

DynamicMap[# + 1 &, Range[100]]

as expected.

Answer 4

I'll post how I did it by scraping, but it's not a great solution:

html = Import[
   "https://resources.wolframcloud.com/FunctionRepository/all/", 
   "String"];
names = StringCases[html, 
   "<h3>" ~~ Whitespace ~~ "<a " ~~ Shortest[__] ~~ ">" ~~ 
     x : Shortest[__] ~~ "</a>" :> x];
With[{u = ToExpression[#]}, u := ResourceFunction[#]] & /@ names

Then we have all of them

In the system context

Then they load on demand, but trying to load all at once takes 16 minutes:

I haven't found a way to cache them and or to load the docs locally yet...

Answer 5

We can install, group, use, and uninstall resource functions with

PacletizeResourceFunction

list = {"AppendColumn", "ColumnMap", "PrependColumn"};

ResourceFunction["PacletizeResourceFunction"][Evaluate @ list, 
 "PacletName" -> "MatrixFunctions"]

ColumnMap[0 &, {{1, 1, 1}, {2, 2, 2}, {3, 3, 3}}, {3}]

{{1, 1, 0}, {2, 2, 0}, {3, 3, 0}}

We can use Information and get the function documentation by clicking the i-symbol in the upper right corner.

?ColumnMap