Compilation of a 2d array and a 1d array

Question

With a list say {{x1, y1}, {x2, y2}, …} and a list {z1}, what is the best way to create a list {{x1, y1, z1}, {x2, y2, z1}, {x3, y3, z1}, …}?

Answer 1

You can use PadRight:

PadRight[
    {{x1, y1}, {x2, y2}},
    {Automatic, 3},
    z1
]

{{x1, y1, z1}, {x2, y2, z1}}

Or ArrayPad:

ArrayPad[
    {{x1, y1}, {x2, y2}, {x3, y3}},
    {{0,0},{0,1}},
    z1
]

{{x1, y1, z1}, {x2, y2, z1}, {x3, y3, z1}}

Answer 2

n = 1000000;
a = RandomReal[{-1, 1}, {n, 2}];
b = ConstantArray[0., 1];
c = Join[a, ConstantArray[b, Length[a]], 2]; // RepeatedTiming // First

0.016

Answer 3

xy = {{x1, y1}, {x2, y2}, ...}
z = {z1, z2, ...}
xyz = Partition[Flatten[Riffle[xy, z]], 3]

and you're done. Riffle also works with just one z-value: it'll do exactly what you asked, after re-reading your question more carefully.

Explanation:

First, Riffle[list1, list2 **or** element, so just z1 works, too] makes

{ {x1, y1}, z1, {x2, y2}, z2, ...}

then, Flatten[list] makes

{ x1, y1, z1, x2, y2, z2, ... }

finally, Partition[list, 3] turns it into

{ {x1, y1, z1}, {x2, y2, z2}, ...}

Answer 4

If z1 is a list (as indicated in the question), then does the following do what you want:

z1 = {1, 2, 3};
xy = {{x1, y1}, {x2, y2}, {x3, y3}};
Flatten[{#, z1}] & /@ xy
(* {{x1, y1, 1, 2, 3}, {x2, y2, 1, 2, 3}, {x3, y3, 1, 2, 3}} *)

Or should the output be as follows:

z = {z1, z2, z3};
xy = {{x1, y1}, {x2, y2}, {x3, y3}};
Flatten[{#, zz}] & /@ xy /. zz -> z
(* {{x1, y1, {z1, z2, z3}}, {x2, y2, {z1, z2, z3}}, {x3, y3, {z1, z2, z3}}} *)