1
$\begingroup$

I'm sorry my title is not descriptive; the function I am interested in is too long to put in there. What I am studying is the real, positive roots of the following function: $f(\epsilon) = (\Delta^2-\epsilon^2)(\epsilon^2 - (\Gamma_1+\Gamma_2)^2/4) + \Delta^2 \Gamma_1 \Gamma_2 + (\Gamma_1+\Gamma_2)\,\epsilon^2\,\sqrt{\Delta^2-\epsilon^2}$

Here all coefficients are real and positive.

Now, this function is readily evaluated with numerical methods, but I would like to know if there is some analytics we can do to end up with expressions for how things scale.

Specifically, I am interested in the scaling of $\epsilon$ (for which $f(\epsilon) = 0$) with $\delta = \vert{\Gamma_1-\Gamma_2}\vert$, in the case that $\Delta \gg \max{(\Gamma_1,\Gamma_2)}$. Indeed, one finds that for $\Gamma_1 = \Gamma_2$, $\epsilon = 0$. I'd like to know how $\epsilon$ approaches 0 as $\delta$ goes to 0. Is that something that is possible analytically? I'm completely fine with only knowing how it behaves to first order, that'd be a great start.

What I've tried doing myself so far constitutes the following:

eqn = (Δ^2 - ϵ^2)*(ϵ^2 - 0^2 - (Γ1 + Γ2)^2/4) + Δ^2*Γ1*Γ2*1 + (Γ1 + Γ2)*ϵ^2*Sqrt[Δ^2 - ϵ^2] 
        == 0;

sols = Solve[{eqn, Γ1 > 0, Γ2 > 0, Δ > Γ1, Δ > Γ2}, ϵ, Reals]

This results in two pretty complicated-looking solutions, and upon numerical inspection one of these is positive and the other is negative. Lets say I'm interested in the positive one for now. Putting in some numbers and having a look at the result

Plot[{ϵ /. {Last@sols}} /. {Δ -> 1, Γ2 -> 0.1}, {Γ1, 0, 1}]

enter image description here

This indeed shows the behaviour I expect at $\Gamma_1 = \Gamma_2$, so we're on the right track. But now I'd like to maybe introduce a limit of $(\Gamma_1, \Gamma_2)/\Delta \rightarrow 0$ or something like that, and do a series expansion in $\delta = \vert{\Gamma_1-\Gamma_2}\vert$, but I am a little bit stuck on how to achieve that. Would anyone be able to assist?

For context, the equation comes from Resonant Josephson Current through a Quantum Dot by Beenakker and van Houten from 1992 and describes the energy-phase relationship of a bound state in the system.

$\endgroup$
2
$\begingroup$

You can solve for $\epsilon$ as a Root object:

eqn = (Δ^2-𝜖^2)(𝜖^2 - (Γ1+Γ2)^2/4) + Δ^2 Γ1 Γ2 + (Γ1+Γ2) 𝜖^2 Sqrt[Δ^2-𝜖^2] == 0;
root = 𝜖 /. Solve[eqn, 𝜖, Quartics->False];
root // TeXForm

$\left\{\operatorname{Root}\left[4 \#1^4+\#1^2 \left(\text{$\Gamma $1}^2+2 \text{$\Gamma $1} \text{$\Gamma $2}+\text{$\Gamma $2}^2-4 \Delta ^2\right)+\#1 \left(2 \text{$\Gamma $1}^2 \Delta -2 \text{$\Gamma $2}^2 \Delta \right)+\text{$\Gamma $1}^2 \Delta ^2-2 \text{$\Gamma $1} \text{$\Gamma $2} \Delta ^2+\text{$\Gamma $2}^2 \Delta ^2\&,1\right],\operatorname{Root}\left[4 \#1^4+\#1^2 \left(\text{$\Gamma $1}^2+2 \text{$\Gamma $1} \text{$\Gamma $2}+\text{$\Gamma $2}^2-4 \Delta ^2\right)+\#1 \left(2 \text{$\Gamma $1}^2 \Delta -2 \text{$\Gamma $2}^2 \Delta \right)+\text{$\Gamma $1}^2 \Delta ^2-2 \text{$\Gamma $1} \text{$\Gamma $2} \Delta ^2+\text{$\Gamma $2}^2 \Delta ^2\&,2\right],\operatorname{Root}\left[4 \#1^4+\#1^2 \left(\text{$\Gamma $1}^2+2 \text{$\Gamma $1} \text{$\Gamma $2}+\text{$\Gamma $2}^2-4 \Delta ^2\right)+\#1 \left(2 \text{$\Gamma $1}^2 \Delta -2 \text{$\Gamma $2}^2 \Delta \right)+\text{$\Gamma $1}^2 \Delta ^2-2 \text{$\Gamma $1} \text{$\Gamma $2} \Delta ^2+\text{$\Gamma $2}^2 \Delta ^2\&,3\right],\operatorname{Root}\left[4 \#1^4+\#1^2 \left(\text{$\Gamma $1}^2+2 \text{$\Gamma $1} \text{$\Gamma $2}+\text{$\Gamma $2}^2-4 \Delta ^2\right)+\#1 \left(2 \text{$\Gamma $1}^2 \Delta -2 \text{$\Gamma $2}^2 \Delta \right)+\text{$\Gamma $1}^2 \Delta ^2-2 \text{$\Gamma $1} \text{$\Gamma $2} \Delta ^2+\text{$\Gamma $2}^2 \Delta ^2\&,4\right],\operatorname{Root}\left[4 \#1^4+\#1^2 \left(\text{$\Gamma $1}^2+2 \text{$\Gamma $1} \text{$\Gamma $2}+\text{$\Gamma $2}^2-4 \Delta ^2\right)+\#1 \left(2 \text{$\Gamma $2}^2 \Delta -2 \text{$\Gamma $1}^2 \Delta \right)+\text{$\Gamma $1}^2 \Delta ^2-2 \text{$\Gamma $1} \text{$\Gamma $2} \Delta ^2+\text{$\Gamma $2}^2 \Delta ^2\&,1\right],\operatorname{Root}\left[4 \#1^4+\#1^2 \left(\text{$\Gamma $1}^2+2 \text{$\Gamma $1} \text{$\Gamma $2}+\text{$\Gamma $2}^2-4 \Delta ^2\right)+\#1 \left(2 \text{$\Gamma $2}^2 \Delta -2 \text{$\Gamma $1}^2 \Delta \right)+\text{$\Gamma $1}^2 \Delta ^2-2 \text{$\Gamma $1} \text{$\Gamma $2} \Delta ^2+\text{$\Gamma $2}^2 \Delta ^2\&,2\right],\operatorname{Root}\left[4 \#1^4+\#1^2 \left(\text{$\Gamma $1}^2+2 \text{$\Gamma $1} \text{$\Gamma $2}+\text{$\Gamma $2}^2-4 \Delta ^2\right)+\#1 \left(2 \text{$\Gamma $2}^2 \Delta -2 \text{$\Gamma $1}^2 \Delta \right)+\text{$\Gamma $1}^2 \Delta ^2-2 \text{$\Gamma $1} \text{$\Gamma $2} \Delta ^2+\text{$\Gamma $2}^2 \Delta ^2\&,3\right],\operatorname{Root}\left[4 \#1^4+\#1^2 \left(\text{$\Gamma $1}^2+2 \text{$\Gamma $1} \text{$\Gamma $2}+\text{$\Gamma $2}^2-4 \Delta ^2\right)+\#1 \left(2 \text{$\Gamma $2}^2 \Delta -2 \text{$\Gamma $1}^2 \Delta \right)+\text{$\Gamma $1}^2 \Delta ^2-2 \text{$\Gamma $1} \text{$\Gamma $2} \Delta ^2+\text{$\Gamma $2}^2 \Delta ^2\&,4\right]\right\}$

Then, replace $\Gamma 2$ with $\Gamma 1 + \delta$ and use Series:

s = Quiet @ Series[root /. Γ2 -> Γ1 + 𝛿, {𝛿, 0, 1}];
s //TeXForm

$\left\{-\sqrt{\Delta ^2-\text{$\Gamma $1}^2}+\frac{\left(\text{$\Gamma $1}^3-\Delta ^2 \text{$\Gamma $1}-\Delta \sqrt{\Delta ^2-\text{$\Gamma $1}^2} \text{$\Gamma $1}\right) \delta }{2 \left(\text{$\Gamma $1}^2-\Delta ^2\right) \sqrt{\Delta ^2-\text{$\Gamma $1}^2}}+O\left(\delta ^2\right),\frac{\Delta \delta }{2 (\text{$\Gamma $1}-\Delta )}+O\left(\delta ^2\right),\frac{\Delta \delta }{2 (\text{$\Gamma $1}+\Delta )}+O\left(\delta ^2\right),\sqrt{\Delta ^2-\text{$\Gamma $1}^2}+\frac{\left(-\text{$\Gamma $1}^3+\Delta ^2 \text{$\Gamma $1}-\Delta \sqrt{\Delta ^2-\text{$\Gamma $1}^2} \text{$\Gamma $1}\right) \delta }{2 \left(\text{$\Gamma $1}^2-\Delta ^2\right) \sqrt{\Delta ^2-\text{$\Gamma $1}^2}}+O\left(\delta ^2\right),-\sqrt{\Delta ^2-\text{$\Gamma $1}^2}+\frac{\left(\text{$\Gamma $1}^3-\Delta ^2 \text{$\Gamma $1}+\Delta \sqrt{\Delta ^2-\text{$\Gamma $1}^2} \text{$\Gamma $1}\right) \delta }{2 \left(\text{$\Gamma $1}^2-\Delta ^2\right) \sqrt{\Delta ^2-\text{$\Gamma $1}^2}}+O\left(\delta ^2\right),-\frac{\Delta \delta }{2 (\text{$\Gamma $1}+\Delta )}+O\left(\delta ^2\right),\frac{\Delta \delta }{2 (\Delta -\text{$\Gamma $1})}+O\left(\delta ^2\right),\sqrt{\Delta ^2-\text{$\Gamma $1}^2}+\frac{\left(-\text{$\Gamma $1}^3+\Delta ^2 \text{$\Gamma $1}+\Delta \sqrt{\Delta ^2-\text{$\Gamma $1}^2} \text{$\Gamma $1}\right) \delta }{2 \left(\text{$\Gamma $1}^2-\Delta ^2\right) \sqrt{\Delta ^2-\text{$\Gamma $1}^2}}+O\left(\delta ^2\right)\right\}$

The roots that vanish when $\delta \to 0$ are:

Cases[s, t_ /; SeriesCoefficient[t, {𝛿, 0, 0}] == 0] //TeXForm

$\left\{\frac{\Delta \delta }{2 (\text{$\Gamma $1}-\Delta )}+O\left(\delta ^2\right),\frac{\Delta \delta }{2 (\text{$\Gamma $1}+\Delta )}+O\left(\delta ^2\right),-\frac{\Delta \delta }{2 (\text{$\Gamma $1}+\Delta )}+O\left(\delta ^2\right),\frac{\Delta \delta }{2 (\Delta -\text{$\Gamma $1})}+O\left(\delta ^2\right)\right\}$

$\endgroup$
  • $\begingroup$ Thank you very much. For some reason I only knew about Solve and FindRoot, when Root was there all along. The usage of Cases was also new to me, very useful. $\endgroup$ – user129412 Feb 19 at 8:46
  • $\begingroup$ I do have to admit that I don't fully understand the syntax used in Cases here. Would you be able to add one line about that? $\endgroup$ – user129412 Feb 19 at 16:31

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.