Defining stochastic differential equations and simulating a system of three SDEs

Question

I am trying to work on stochastic differential equations and I have been trying to use Mathematica's built-in function to simulate the system of equations below. When i use the randomfunction to simulate it using the Milstein method. I keep getting an output implying the RandomFunction method is not a random process recognized by the system.

Please look at my codes and help.

This is the system of equations:

dx[t] = (-a*s(x[t] + y[t]) - s*z[t])dt + 0.1*x[t] dw1

dy[t] = (p*x[t] - l*y[t] + s*z[t])dt + 0.1*y[t] dw2

dz[t] = (-p*x[t] -l*y[t] -(s + m)*z[t]) + 0.1*z[t] dw3

where w1, w2 and w3 are standard Wiener processes.

a = 10; l = 24.625; m = 14.925; s = 0.415; p = 5;
proc1 = 
  ItoProcess[
    {\[DifferentialD]x[t] == (-a*s x[t] - a*s y[t] - s*z[t] )\[DifferentialD]t + 0.1*x[t] \[DifferentialD]w1[t], 
     \[DifferentialD]y[t] == (p* x[t] - l*y[t] + s*z[t]) \[DifferentialD]t + 0.1*y[t] \[DifferentialD]w2[t], \[DifferentialD]z[t] == (-p*x[t] + {{l*y[t], -(s  + m)*z[t]}}) \[DifferentialD]t + 0.1*z[t] \[DifferentialD]w3[t]}, 
    {x[t], y[t], z[t]}, {{x, y, z}, {0.115, -0.115, 0}}, t, 
    {w1, w2, w3} \[Distributed] WienerProcess[]]

paths = RandomFunction[proc1, {0, 100, 0.01}, 250, Method -> "Milstein"];

Answer 1

Two things:

1) You can't use {} to group terms as in your z equation. See, for example, here for more info.

2) You need to define each noise term separately. {w1, w2, w3} is a list of length three but WienerProcess[] is a scalar, so they don't have the same shape.

The following works:

proc1 = ItoProcess[{
  \[DifferentialD]x[t] == (-a*s x[t] - a*s y[t] - s*z[t]) \[DifferentialD]t
  + 0.1*x[t] \[DifferentialD]w1[t],
  \[DifferentialD]y[t] == (p*x[t] - l*y[t] + s*z[t]) \[DifferentialD]t
  + 0.1*y[t] \[DifferentialD]w2[t],
  \[DifferentialD]z[t] == (-p*x[t] + l*y[t] - (s + m)*z[t]) \[DifferentialD]t
  + 0.1*z[t] \[DifferentialD]w3[t]},
  {x[t], y[t], z[t]}, {{x, y, z}, {0.115, -0.115, 0}}, t,
  {w1 \[Distributed] WienerProcess[], w2 \[Distributed] WienerProcess[], w3 \[Distributed] WienerProcess[]}];