PDE in 3D: Specification boundary condition at infinity

Question

I'm trying to solve the Schrodinger equation and having difficulties to define a limitless region because the problem has the Dirichlet conditions at infinity. Maybe I don't need such a region and should merely to define that condition correctly but I don't know how to implement it

h = 1; m = 1; V[r_] := -1/Sqrt[ r.r];
\[ScriptCapitalL] = -(h^2/(2 m)) \!\(
\*SubsuperscriptBox[\(\[Del]\), \({x, y, z}\), \(2\)]\(f[x, y, 
      z]\)\) + V[{x, y, z}] f[x, y, z];
n = 3;


 A = ImplicitRegion[
     -\[Infinity] < x  < \[Infinity] && -\[Infinity] < 
     y < \[Infinity]  &&  -\[Infinity] < z < \[Infinity] , {x, y, 
        z}];
    {vals, funs} = 
      NDEigensystem[{\[ScriptCapitalL], 
        DirichletCondition[f[x, y, z] == 0, True]}, 
       f, {x, y, z} \[Element] A, n] ;

Answer 1

To limit the binding energy, proceed as follows:

h = 1; m = 1; V[r_] := 1 - 1/Sqrt[ r.r]

\[ScriptCapitalL] = -(h^2/(2 m)) \!\(
\*SubsuperscriptBox[\(\[Del]\), \({x, y, z}\), \(2\)]\(f[x, y, 
      z]\)\) + V[{x, y, z}] f[x, y, z];
 d = 10; n = 3;
A = ImplicitRegion[-d <= x <= d && -d <= y <= d && -d <= z <= d, {x, 
    y, z}];


 {vals, funs} =  
  NDEigensystem[{\[ScriptCapitalL], 
    DirichletCondition[f[x, y, z] == 0, True]}, 
   f, {x, y, z} \[Element] A, n] ;

Here we get three eigenvalues, the first of which is close to -1/2, and the other two to -1/8:

 vals - 1

Out[]= {-0.479657, -0.121793, -0.121756}

The inaccuracy of the definition of eigenvalues is due to the influence of the box boundaries. The distribution of the square of the amplitude of the wave function approximately corresponds to n = 1 and 2. In the second case, the angular momentum l > 0.

Table[ContourPlot[
  Evaluate[funs[[i]][x, y, 0]], {x, -d, d}, {y, -d, d}, 
  PlotRange -> All, PlotLabel -> vals[[i]] - 1, Contours -> 20, 
  PlotLegends -> Automatic], {i, Length[vals]}]