Run Does not Work

Question

Hi I would like to use the terminal code OCR softwar, called: Tesseract Optical Character Recognition (OCR)

Here you have a nice description of how to set it up: http://chillyfacts.com/convert-image-to-text-using-cmd-prompt/

Now my question is:

When I type: "C:\OCR\tesseract" "C:\Image_to_OCR.jpg" "C:\out" in the cmd command line, it works...

But when I try to run it from Mathematica:

Run["\"C:\\OCR\\tesseract\" \"C:\\Image_to_OCR.jpg \" \"C:\\out\""]

it does not work and returns "1" .

Any idea why or how I can fix it ? Anyone ?

Answer 1

Files

Let's create some test files

Table[
 Export[
  StringTemplate["Test``.jpg"][k],
  Rasterize@TextCell[
    RandomChoice[DictionaryLookup["*"]],
    RandomChoice[{"Text", "Subsection", "Section", "Title"}]
    ]
  ]
 , {k, 10}
 ]

RunProcess

Test a single file using RunProcess (advisable).

RunProcess[
 {
  "C:\\Program Files (x86)\\Tesseract-OCR\\tesseract.exe",
  "Test1.jpg",
  "Test1"
  }
 ]
(* <|"ExitCode" -> 0, "StandardOutput" -> "", 
 "StandardError" -> 
  "Tesseract Open Source OCR Engine v3.02 with Leptonica

  "|> *)

Run

Test a single file using Run, notice the extra quotation marks go only around the long path name to protect the spaces. Arguments do not need quotation marks.

Run[
  "\"C:\\Program Files (x86)\\Tesseract-OCR\\tesseract.exe\" Test1.jpg Test1"
 ]
 (* 0 *)

Processing many files

Table[
 {
  StringTemplate["Test``.jpg"][k],
  RunProcess[
    {
     "C:\\Program Files (x86)\\Tesseract-OCR\\tesseract.exe",
     StringTemplate["Test``.jpg"][k],
     StringTemplate["Test``"][k]
     }
    ]["ExitCode"]
  }
 , {k, 10}
 ]

TextRecognize

Compare with Mathematica's TextRecognize

TableForm[
 Table[
  {
   StringTemplate["Test``.jpg"][k],
   Import[StringTemplate["Test``.jpg"][k]],
   Import[StringTemplate["Test``.txt"][k], "String"],
   TextRecognize[StringTemplate["Test``.jpg"][k]]
   }
  , {k, 10}
  ]
 , TableHeadings -> {Automatic, {"File Name", "Image", "Tesseract", 
    "Mathematica\nTextRecognize" }}
 ]