Method to see why systems of equations has no solution

Question

I am trying to solve a set of equations two variables as below. Mathematica said that it has no solution. I would like to research more why it has no solution. I tried to use Trace function but it doesn't reveal anything. Is there any way to see why there is no solution for this system of equations?

Solve[{-((3*(-1 + D1 + D2 + D3)*(5*(-1 + D1 + D2) + 7*D3))/(5*(-1 + D1 + D2)^2 + 
        10*(-1 + D1 + D2)*D3 + 7*D3^2)) == 2, 
    -((3*D3*(5*(-1 + D1 + D2) + 7*D3))/(5*(-1 + D1 + D2)^2 + 10*(-1 + D1 + D2)*D3 + 7*D3^2)) == 5}, 
   {D1, D2}]

Answer 1

There is no solution, because Numerator and Denominator have the same roots.

Bring right side of equations to left side and generate a common denominator

exp2 = eqs[[All, 1]] - eqs[[All, 2]] // Together

(*   {(-25 + 50 D1 - 25 D1^2 + 50 D2 - 50 D1 D2 - 25 D2^2 + 56 D3 - 
56 D1 D3 - 56 D2 D3 - 35 D3^2)/(5 - 10 D1 + 5 D1^2 - 10 D2 + 
10 D1 D2 + 5 D2^2 - 10 D3 + 10 D1 D3 + 10 D2 D3 + 7 D3^2), (-25 + 
50 D1 - 25 D1^2 + 50 D2 - 50 D1 D2 - 25 D2^2 + 65 D3 - 65 D1 D3 - 
65 D2 D3 - 56 D3^2)/(5 - 10 D1 + 5 D1^2 - 10 D2 + 10 D1 D2 + 
5 D2^2 - 10 D3 + 10 D1 D3 + 10 D2 D3 + 7 D3^2)}   *)

Denominators of both expressions are the same

Denominator[exp2[[1]]] == Denominator[exp2[[2]]]

(*   True   *)

Since denominators shall not go to infinity, you only get solutions, if nominators are zero.

sol = Solve[{Numerator[exp2[[1]]] == 0, Numerator[exp2[[2]]] == 0}]

(*   {{D1 -> 1 - D2, D3 -> 0}}   *)

But unfortunately with this solutions, denominators are also zero.

Denominator[exp2] /. First@sol // Simplify

(*   {0, 0}   *)

And in the limit, you don't get zero.

Limit[exp2, D1 -> 1 - D2]

(*   {-5, -8}   *)

Limit[exp2, D3 -> 0]

(*   {-5, -5}   *)

That means, you can never get a solution.