How to build equations from list of lists

Question

I have something like this

edgesList = {{1, 3}, {1, 5}, {2, 1}, {2, 6}, {5, 2}, {5, 6}, {6, 1}, {6, 4}}

And I need something like this as output.

{Subscript[x, 1 \[RightArrow] 3] + Subscript[x, 1 \[RightArrow] 5] - 
  Subscript[x, 2 \[RightArrow] 1] - Subscript[x, 6 \[RightArrow] 1], 
 Subscript[x, 2 \[RightArrow] 1] + Subscript[x, 2 \[RightArrow] 6] - 
  Subscript[x, 5 \[RightArrow] 2], -Subscript[x, 
  1 \[RightArrow] 3], -Subscript[x, 
  6 \[RightArrow] 4], -Subscript[x, 1 \[RightArrow] 5] + Subscript[x, 
  5 \[RightArrow] 2] + Subscript[x, 
  5 \[RightArrow] 6], -Subscript[x, 2 \[RightArrow] 6] - Subscript[x, 
  5 \[RightArrow] 6] + Subscript[x, 6 \[RightArrow] 1] + Subscript[x, 
  6 \[RightArrow] 4]}

I have accomplished this in procedural way, but I'm curious how to make it functional.

equations = Array[0 &, nVertexes];
For[i = 1, i <= nEdges, i++, 
  equations[[edgesList[[i, 1]]]] = 
   equations[[edgesList[[i, 1]]]] + 
    Subscript[x, edgesList[[i, 1]] \[RightArrow] edgesList[[i, 2]]]; 
  equations[[edgesList[[i, 2]]]] = 
   equations[[edgesList[[i, 2]]]] - 
    Subscript[x, edgesList[[i, 1]] \[RightArrow] edgesList[[i, 2]]];];

Answer 1

Clear[x]
equations = Array[0 &, 6];
edgesList = {{1, 3}, {1, 5}, {2, 1}, {2, 6}, {5, 2}, {5, 6}, {6, 
    1}, {6, 4}};
Fold[With[{i = First@#2, j = Last@#2}, ReplacePart[#1,
    {i -> #1[[i]] + Subscript[x, i \[RightArrow] j],
     j -> #1[[j]] - 
       Subscript[x, i \[RightArrow] j]}]] &, equations, edgesList]

Answer 2

Another functional way:

Table[
 If[#1 == j, 1, -1] Subscript[x, #1 -> #2] & @@@ Select[edgesList, MemberQ[#, j] &] // Total,
 {j, 1, Max@Flatten@edgesList}]