How to define UpValues in a different context from within a package

Question

I'm trying to create a function (in a package) to import a lot of data and create a symbol with UpValues to return specific results about the data. I've got it working fine in a regular notebook, but when I define the function within a package I can't get it to work properly.

A simple example of my problem:

TestPackage.m:

BeginPackage["TestPackage`"];

testFunction::usage= "testFunction[] does all kind of interesting things.";

Begin["`Private`"]

testFunction[name_Symbol]:=
 Module[{},(
  ClearAll[name];
  UpValues[name]=
   {
    test[name]->"hello!"
   };
  Protect[name];
 )]

End[]

EndPackage[]

I then call the function in a regular notebook:

Needs["TestPackage`", "/path/to/TestPackage.m"]

testFunction[a]

• test[a] returns test[a]
• and TestPackage`Private`test[a] returns the expected "hello!"

How do I change testFunction so that test[a] also returns "hello!"?

Answer 1

The explanation can be found in the doc to BeginPackage and Begin

• BeginPackage["context`"] makes context` and System`the only active contexts.
• Begin["context`"] resets the current context.

Therefore, at the moment you first mention the symbol test it is not created it in the Global context. This can be seen from you (simplified) example

BeginPackage["TestPackage`"];
testFunction::usage = 
  "testFunction[] does all kind of interesting things.";
Begin["`Private`"];
testFunction[name_Symbol] := name /: test[name] := "hello!";
End[];
EndPackage[]

testFunction[a]
UpValues[a]

(* {HoldPattern[TestPackage`Private`test[a]] :> "hello!"} *)

beside giving test a ::usage message, you can give the context explicitly

testFunction[name_Symbol] := name /: Global`test[name] := "hello!";

Further note

• I don't see why you use Module because you don't localize any variable. And if you want to input a sequence of commands, divided by ; (called a CompoundExpression) you can simply wrap it in parenthesis, as you did.
• Your combination of ClearAll and Protect is such that you can call testFunction on a given Symbol only one time. On the second call you get messages since ClearAll cannot clear a protected symbol. What is the intention behind this?

Answer 2

You should export the test symbol, ie define it between BeginPackage["TestPackage`"] and Begin["`Private`"], for example by giving a usage to test.

test::usage = "test[name] returns ..."
(*or just*) test;

for your definition, as said already in comments, I would use

test[name] ^= "hello";

My answer to this post contains many application of UpValues, it could interest you: Struct equivalent in Mathematica?

You could also not export the symbol, that will be thus in the Private context of the package, and use the full name of test

TestPackage`Private`test[name] ^= "hello";