How do I get Mathematica to recognize this simplification? (ReplaceAll pattern rule)

Question

I want Mathematica to understand this $$(\sum_{k=0}^n a_k)(\sum_{j=0}^n b_j) = (\sum_{k=0}^n \sum_{j=0}^n a_k b_j)$$ I have tried this

exprr1 = Sum[Subscript[a, k], {k, 0, n}] * 
Sum[Subscript[b, j], {j, 0, n}]

rules = {Sum[Subscript[a, k], {k, 0, n}]*
Sum[Subscript[b, j], {j, 0, n}] :> 
Sum[Subscript[a, k]*Subscript[b, j], {k, 0, n}, {j, 0, n}]}

exprr1 /. rules

Now this works. The problem is that when I try

rules = {Sum[Subscript[d, k], {k, 0, n}]*
Sum[Subscript[e, j], {j, 0, n}] :> 
Sum[Subscript[d, k]*Subscript[e, j], {k, 0, n}, {j, 0, n}]}

This does not work.

I want Mathematica to understand that no matter what the variable in the summation, and no matter what the index variable, the simplification/rules should work.

How do I do this? Thanks in advance!

Answer 1

Answer

You should use Blank, a pattern object that can stand for any Wolfram Language expression, usually written as _. Learn about Patterns here.

rules2 = {
  Times[
    Sum[
     Subscript[d_, k_]
     , {k_, m_, n_}
     ],
    Sum[
     Subscript[e_, j_]
     , {j_, m_, n_}
     ]
    ]
   :>
   Sum[
    Times[
     Subscript[d, k],
     Subscript[e, j]
     ]
    , {k, m, n}
    , {j, m, n}
    ]
  }

exprr1 /. rules2

Try to think about the patterns in FullForm. Indentation is only for readability.

Side note about using Subscript

By the way, not the source of your problem, but you should avoid using Subscript while defining symbols (variables) for anything other than nice display. Subscript[x, 1] is not a symbol, but a composite expression where Subscript is an operator without built-in meaning. You expect to do $x_1=2$ but you are actually doing Set[Subscript[x, 1], 2] which is to assign a Downvalue to the oprator Subscript and not an Ownvalue to an indexed x as you may intend. Read how to properly define indexed variables here.

To see other basic syntax issues please do read this answer.