Is there a solution for this equation?

When I try to solve this equation using Mathematica:

Solve[((x^2 - y^2 Cos[2/3 Sqrt[x^2 - y^2]]) Cosh[y/3])/(x^2 - y^2) +
(y Sin[2/3 Sqrt[x^2 - y^2]] Sinh[y/3])/Sqrt[x^2 - y^2] == 1, y]


I don't get any result. I ask for your help, please how to get a solution for this equation?

• Solve deals primarily with linear and polynomial equations. From help Mar 5 '17 at 20:09
• @Nasser One can get many solutions with Solve of this equation. In this context the remark from the help page is misleading. Mar 6 '17 at 2:24

Solve is a really powerful function and its capabilities are much more extensive than polynomial equations as the other answers suggest. It can deal with many transcendental equations, however it doesn't imply that this is the case here. Taking a look at the given equation we expect there exist many (most likely infinitely many) complex solutions, while real solutions are more restricted. I recommend switching to Reduce since one could expect full-dimensional components of the solution set (see e.g. What is the difference between Reduce and Solve?). Another remarkable reason may appear when certain more involved mathematical structure is hidden behind the equations (see e.g. How to get intersection values from a parametric graph? where Reduce works fine while Solve did not at least in version 9). If we are to solve the equation only in reals we could substitute x -> z == x^2 - y^2 and obtain formally simpler equation equivalent under suitable conditions. Then we get ranges of z to be a solution of the underlying equation.

Reduce[((z + y^2 - y^2 Cos[2/3 Sqrt[z]]) Cosh[y/3])/
z + (y Sin[2/3 Sqrt[z]] Sinh[y/3])/Sqrt[z] - 1 == 0 && z >= 0 && y ∈ Reals, {x, y}]

C[1] ∈Integers && ((C[1] >= 0 &&
z == 1/4 (9 π^2 + 36 π^2 C[1] + 36 π^2 C[1]^2) &&
y == 0) || ((-π + (2 Sqrt[z])/3)/(2 π) \[NotElement]
Integers && Tan[Sqrt[z]/3] != 0 && ((C[1] >= 0 &&
1/4 (9 π^2 + 72 π^2 C[1] + 144 π^2 C[1]^2) < z <
1/4 (81 π^2 + 216 π^2 C[1] + 144 π^2 C[1]^2)) ||
0 < z < (9 π^2)/4 || (C[1] >= 1 &&
1/4 (9 π^2 - 72 π^2 C[1] + 144 π^2 C[1]^2) < z <
1/4 (9 π^2 + 72 π^2 C[1] + 144 π^2 C[1]^2))) &&
y == 0) || (C[1] >= 1 && z == 9 π^2 C[1]^2 && y == 0))


The solution set can be illustrated with e.g.

ContourPlot[((z + y^2 - y^2 Cos[2/3 Sqrt[z]]) Cosh[y/3])/z
+ (y Sin[2/3 Sqrt[z]] Sinh[y/3])/Sqrt[z] - 1 == 0,
{z, 0, 15}, {y, -15, 15}]


When we are to find complex solutions we sholud restrict ranges of the variables and when two variables are given we could find solutions of e.g. x given a specific value of y, a detailed discussion can be found e.g. here Solve symbolically a transcendental trigonometric equation and plot its solutions Define

f[x_, y_] := ((x^2 - y^2 Cos[2/3 Sqrt[x^2 - y^2]]) Cosh[y/3])/(x^2 -
y^2) + (y Sin[2/3 Sqrt[x^2 - y^2]] Sinh[y/3])/Sqrt[x^2 - y^2] - 1


Let's find all exact solutions x such that Abs[x] < 20 given y == 2 + 2I:

roots = x /. {ToRules @ Reduce[ f[x, 2 + 2 I] == 0 && Abs[x] < 20, x] //
Quiet};


there are eight of them (evaluate Length[roots]) given in terms of the root objects. We plot them in the complex plane of x:

g[rx_, ix_] := f[rx + I ix, 2 + 2 I]

ContourPlot[{Re[ g[rx, ix]] == 0, Im[ g[rx, ix]] == 0},
{rx, -20, 20}, {ix, -20, 20}, Evaluated -> True,
PlotLegends -> Placed["Expressions", Below],
Epilog -> {Red, PointSize -> 0.015, Point[ReIm[roots]]},
Axes -> True]]


There are infinitely many solutions without the condition Abs[x] < 20 of course. Here are numeric approximations for Abs[x] < 20:

N @ roots

 { -16.6788 - 2.8779 I, -16.4053 + 2.22766 I, -7.57289 - 2.06311 I,
-7.3023 + 0.684591 I, 7.3023 - 0.684591 I, 7.57289 + 2.06311 I,
16.4053 - 2.22766 I, 16.6788 + 2.8779 I}

• I have removed the offhand comment about Solve and polynomials in my post, it was a bit too sweeping. Nice work here. Mar 6 '17 at 1:51
• @bobbym Thanks, working on such questions can give an insight into various subtleties of the underlying functionality. This is why I had to provide a bit extended post. Mar 6 '17 at 2:02

I tried:

FindInstance[((x^2 - y^2 Cos[2/3 Sqrt[x^2 - y^2]]) Cosh[y/3])/(x^2 - y^2)
+ (y Sin[2/3 Sqrt[x^2 - y^2]] Sinh[y/3])/Sqrt[x^2 - y^2] == 1,
{x, y}, 2]
% // N

{{x -> 89.9234 - 32.2712 I, y -> 42. - 70. I},
{x -> 92.059 + 44.0526 I, y -> 78.5 + 51.9 I}}


You can try for others.

FindInstance[((x^2 - y^2 Cos[2/3 Sqrt[x^2 - y^2]]) Cosh[y/3])/(x^2 -
y^2) + (y Sin[2/3 Sqrt[x^2 - y^2]] Sinh[y/3])/
Sqrt[x^2 - y^2] == 1, {x, y}, Reals, 2]

{{x -> -((57 π)/2), y -> 0}, {x -> 463/10, y -> 0}}


I would guess there are others...try putting 50 at the end of the last FindInstance and then check of course.

In view of Bob Hanlon's comment below we test to see if there are any real solutions other than whith $$y = 0$$.

FindInstance[{((x^2 - y^2 Cos[2/3 Sqrt[x^2 - y^2]]) Cosh[y/3])/(x^2 - y^2)
+ (y Sin[2/3 Sqrt[x^2 - y^2]] Sinh[y/3])/Sqrt[x^2 - y^2] == 1,
y != 0}, {x, y}, Reals, 2]


quickly outputs {}, FindInstance could not find anymore for us.

• eqn /. y -> 0 will show that the equation is satisfied by all points {x, 0} Mar 5 '17 at 20:56
• You are correct, I addressed that in my post. Mar 6 '17 at 1:43
• If the output of FindInstance is { } I wouldn't say there are no solutions, I would rather say FindInstance were unable to find any solutions. Working with symbolic capabilities like e.g. Solve makes such a conclusion plausible unless there are some bugs. Look e.g. at Issue with NSolve providing an example in case on numeric functions. Mar 6 '17 at 1:50
• @Artes I am afraid you got me again. I will modify that right now. Mar 6 '17 at 2:00

I tried:

NMinimize[Norm[((x^2-y^2 Cos[2/3 Sqrt[x^2-y^2]]) Cosh[y/3]) +
(y Sin[2/3 Sqrt[x^2-y^2]] Sinh[y/3])/Sqrt[x^2-y^2]-1], {x,y}]


and the result strongly hints that x==0 && y==0. Substituting those confirms this.

But you do have (x^2-y^2) and Sqrt[x^2-y^2] in denominators in your problem.

• Strictly speaking {x. y} == {0, 0} doesn't belong to the domain of the given function, so it is not a solution. Mar 6 '17 at 2:11

Sometimes one can gain insight if you plot the expression. We will use the difference between the left hand sign of == in your Solve and the value 1.

Where the plot is zero represents a solution.

Plot3D[((x^2 - y^2 Cos[2/3 Sqrt[x^2 - y^2]]) Cosh[y/3])/(x^2 -
y^2) + (y Sin[2/3 Sqrt[x^2 - y^2]] Sinh[y/3])/Sqrt[x^2 - y^2] -
1, {x, -1, 1}, {y, -1, 1}, Exclusions -> {x == y && x == -y},
AxesLabel -> {x, y, z}
]


This generates some errors but plots OK

It appears that when y is zero the expression is zero. Let's validate this.

With[
{
expr = ((x^2 - y^2 Cos[2/3 Sqrt[x^2 - y^2]]) Cosh[y/3])/(x^2 -
y^2) + (y Sin[2/3 Sqrt[x^2 - y^2]] Sinh[y/3])/
Sqrt[x^2 - y^2] - 1 /. y -> 0
},
Plot[expr, {x, -1, 1}]
]


This appears to be the case. Thus the solution to your equation is y= 0.

To further validate we compute

((x^2 - y^2 Cos[2/3 Sqrt[x^2 - y^2]]) Cosh[y/3])/(x^2 -
y^2) + (y Sin[2/3 Sqrt[x^2 - y^2]] Sinh[y/3])/Sqrt[x^2 - y^2] -
1 /. y -> 0

(* 0 *)