0
$\begingroup$

I am interested in examining the Fourier coefficients of functions of a couple of weight $2$ modular forms which are essentially logarithmic derivatives of Klein's modular function $$j(\tau) = q^{-1} + 744 + 196884q + 21493760q^2 + \cdots, \qquad q := e^{2\pi i\tau}.$$ The two functions I want to see the $q$ expansions of are $$f(\tau) = \frac{j'(\tau)}{j(\tau)}$$ and $$g(\tau) = \frac{j'(\tau)}{j(\tau) - 1728}.$$ Does anyone know how to do this in Mathematica 11? I know there is the built in function KleinInvariantJ but that seems to be useful for evaluating the function, not giving the $q$ expansion. Thanks.

Improve this question
$\endgroup$
9
  • $\begingroup$ Are those primes derivatives with respect to $q$, or to $\tau$? $\endgroup$
    – J. M.'s missing motivation ♦
    Commented Dec 19, 2016 at 4:27
  • $\begingroup$ Series[1728*KleinInvariantJ[τ], {τ, 0, 4}] seems to give your first series. Then isn't it a matter of applying Series on the combinations? $\endgroup$
    – QuantumDot
    Commented Dec 19, 2016 at 4:33
  • 1
    $\begingroup$ @QuantumDot - I believe that the definition of q needs to be changed to q == Exp[-2 Pi I / τ] $\endgroup$
    – Bob Hanlon
    Commented Dec 19, 2016 at 4:37
  • $\begingroup$ @Bob, there are two different conventions for the nome $q$ in place; sometimes one uses $q$ to denote $\exp(\pi i\tau)$ (personally, the convention I'm accustomed to) and sometimes one uses it for what is otherwise denoted as $\bar{q}=\exp(2\pi i\tau)$, which is apparently the convention the OP is using. Have a look at the MathWorld article for the Klein invariant, for instance. $\endgroup$
    – J. M.'s missing motivation ♦
    Commented Dec 19, 2016 at 4:43
  • $\begingroup$ @J.M. - The series expansion Series[1728*KleinInvariantJ[τ], {τ, 0, 4}] has the τ in the denominator of the exponent of E $\endgroup$
    – Bob Hanlon
    Commented Dec 19, 2016 at 4:52

2 Answers 2

Reset to default
1
$\begingroup$

The relationship between KleinInvariantJ[τ] and the Alwaise's (OP) definition is:

alwaiseJ[q_] = 1728*KleinInvariantJ[-((2 I π)/Log[q])]

To check this, apply Series to recover the OP's expansion (apparently, there is a bug causing not enough terms to be displayed):

Series[alwaiseJ[q], {q, 0, 4}] // Expand

(* 744 + 1/q + 196884 q + 21493760 q^2 *)

To obtain series expansions for the combinations requested by the OP, the ideal method is simply to form the combination and apply Series. But after a minute of computing time it yields an overly complicated (propbably wrong) result:

Series[D[alwaiseJ[q], q]/alwaiseJ[q], {q, 0, 3}]

(*Probably wrong result?*)

A workaround is to apply Series on each alwaiseJ, apply the necessary derivative, and then apply Series on the final result:

Series[D[Series[alwaiseJ[q], {q, 0, 10}], q] / Series[alwaiseJ[q], {q, 0, 10}], {q, 0, 3}]

(* -(1/q) + 744 - 159768 q + 36866976 q^2 - 8507424792 q^3 + O[q]^4 *)

Same thing for OP's second example:

Series[D[Series[alwaiseJ[q], {q, 0, 10}], q] / (Series[alwaiseJ[q], {q, 0, 10}] - 1728), {q, 0, 3}]

(* -(1/q) - 984 - 574488 q - 307081056 q^2 - 164453203992 q^3 + O[q]^4 *)
Improve this answer
$\endgroup$
2
  • $\begingroup$ Thanks! Just one question. How do I get mathematica to actually multiply the coefficients of $J$ by $1728$? When I type in the code you have here and apply Series to alwaiseJ, Mathematica displays $$1728\left(\frac{31}{72} + \frac{1}{1728q} + \frac{1823q}{16} + \frac{335840q^2}{27}\right).$$ How can I make it actually distribute the $1728$? Thanks. $\endgroup$
    – Ethan Alwaise
    Commented Jan 16, 2017 at 0:17
  • $\begingroup$ @EthanAlwaise Expand should do the trick. $\endgroup$
    – QuantumDot
    Commented Jan 16, 2017 at 0:24
2
$\begingroup$

Some trickery is necessary here. In particular, we will need to use the expression of the $j$-invariant in terms of theta functions:

jf = With[{a = EllipticTheta[2, 0, Sqrt[#]]^8, b = EllipticTheta[3, 0, Sqrt[#]]^8, 
           c = EllipticTheta[4, 0, Sqrt[#]]^8}, 32 (a + b + c)^3/(a b c)] &;

and expand as a series in the nome:

ser = Series[jf[q], {q, 0, 6}]
   1/q + 744 + 196884 q + 21493760 q^2 + 864299970 q^3 + 20245856256 q^4 +
   333202640600 q^5 + 4252023300096 q^6 + O[q]^(49/8)

before using the chain rule judiciously.

$f(\tau)$:

2 π I q D[Log[ser], q]
   -2 I π + 1488 I π q - 319536 I π q^2 + 73733952 I π q^3 - 17014849584 I π q^4 +
   3926422987488 I π q^5 - 906079372542144 I π q^6 + 209091033317387904 I π q^7 + O[q]^50

$g(\tau)$:

2 π I q D[ser, q]/(ser - 1728)
  -2 I π - 1968 I π q - 1148976 I π q^2 - 614162112 I π q^3 - 328906407984 I π q^4 - 
  176125996903968 I π q^5 - 94314016488431808 I π q^6 - 50504368485468650880 I π q^7 - 
  27044667899456355041328 I π q^8 - 14482193986413608035836912 I π q^9 - 
  7755094033419666997380722976 I π q^10 - 4152788142706024277284841200704 I π q^11 - 
  2223783397581264170979224652742848 I π q^12 -
  1190817453099277203894595701810883488 I π q^13 + O[q]^(105/8)
Improve this answer
$\endgroup$
0

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.