Creating Boolean expressions over a set of indexed variables

Question

I've read lots of examples here on how to set one matrix Equal to another, but how do you nest And and Or around several different equalities for values a matrix of variables can take on? Using what I've found so far, I've been able to cobble something together that works, but surely someone knows a better way?

The idea: Variables V can take on the values in either A or B or C.

Minimum Working Example:

Apply[
  And, 
  Apply[
    Or, 
    MapThread[
       Equal,
       {Transpose[
          Table[v[i], {c, 3}, {i, 10}]], 
          Table[{-1, 0, 1}, {i, 10}]},
       2], 
    {1}]]

Good output:

(v[1] == -1 || v[1] == 0 || v[1] == 1) && (v[2] == -1 || v[2] == 0 || v[2] == 1) &&
(v[3] == -1 || v[3] == 0 || v[3] == 1) && (v[4] == -1 || v[4] == 0 || v[4] == 1) &&
(v[5] == -1 || v[5] == 0 || v[5] == 1) && (v[6] == -1 || v[6] == 0 || v[6] == 1) &&
(v[7] == -1 || v[7] == 0 || v[7] == 1) && (v[8] == -1 || v[8] == 0 || v[8] == 1) &&
(v[9] == -1 || v[9] == 0 || v[9] == 1) && (v[10] == -1 || v[10] == 0 || v[10] == 1)

Ideally the answer would be something of the form

And[Or[V == {A, B, C}]]

instead of the heavy use of Table like I have, so we can see what's happening and adapt it for other problems, and often the possible values won't have such a regular pattern as these do (A, B, & C may have irregular patterns and even repetitions in order to fill out the matrix to the right shape).

Conceivably there's a way to do something like this, but I couldn't get this to work either (for use in Reduce or FindInstance):

Eqns && V ∈ {-1, 0, 1}

Answer 1

2D array solution for multiple target arrays for OP's ideal answer (And[Or[V == {A, B, C}]]).

This is demonstrated with Indexed as it make it easier to see the effect of the solution.

First set up the 2D arrays.

index = Table[{r, c}, {r, 2}, {c, 2}];
\[ScriptV] = Map[Indexed[v, #] &, index, {2}];
\[ScriptA] = Map[Indexed[a, #] &, index, {2}];
\[ScriptB] = Map[Indexed[b, #] &, index, {2}];
\[ScriptC] = Map[Indexed[c, #] &, index, {2}];

MatrixForm /@ {\[ScriptV], \[ScriptA], \[ScriptB], \[ScriptC]}

arrayContainsAny builds the inequality.

arrayContainsAny[m_, arrayList_] :=
 And @@ Flatten@MapThread[
    Or,
    First@ListCorrelate[m, #, {1, -1}, Nothing, Equal, List] & /@ arrayList,
    3]

Call it with the 2D arrays.

eqs = arrayContainsAny[\[ScriptV], {\[ScriptA], \[ScriptB], \[ScriptC]}]

If values are assigned to a, b, and c

SeedRandom[123];
{a, b, c} = RandomInteger[{1, 10}, {3, 2, 2}];

Then Indexed will kick in and eqs will update.

However, you don't need to use Indexed for the arrayList arrays parameter. You can use the arrays directly. I just used them there to demonstrate.

Hope this helps.

Answer 2

Here are two options.

And @@ Map[Or @@ Thread[# == Range[-1, 1]] &, Array[v, 10]]

Alternatively, using Outer:

Apply[And, Or @@@ Outer[Equal, Array[v, 10], Range[-1, 1]]]

---

Also of possible interest, in the situation where you are using Solve, Reduce and friends:

And @@ Map[-1 <= # <= 1 && # ∈ Integers &, Array[v, 10]]

Alternatively, since Solve, Reduce and friends take a domain restriction as an optional third argument, leave out the Integers:

conds = And @@ Map[-1 <= # <= 1 &, Array[v, 10]]

and do something like

Solve[eqn && conds, Array[v, 10], Integers]