Symbolic integration of SphericalBesselJ

Question

Backslide introduced in v10 and persisting through v10.3.1.

---

Consider the following integral

AbsoluteTiming[
 Integrate[k^(n) SphericalBesselJ[l, R*k], {k, 0, ∞}, 
  Assumptions -> {l > 0, R > 0}]]

On my machine Mathematica 10.3.1 (Linux version) can do it in roughly 20 seconds

{19.7088, 
 ConditionalExpression[(
  Sqrt[π] 2^(n - 1) R^(-n - 1) Gamma[1/2 (l + n + 1)])/Gamma[
  1/2 (l - n + 2)], Re(n) < 1 ∧ l + Re(n) > -1]}

Since for my purpose n is an integer, one would think that specifying this condition in the assumptions will make it easier for Mathematica to solve the integral. Right? Apparently not! For

AbsoluteTiming[
 Integrate[k^(n) SphericalBesselJ[l, R*k], {k, 0, ∞}, 
  Assumptions -> {l > 0, R > 0, n ∈ Integers}]]

I obtained

{69.0534, 
 Integrate[k^n SphericalBesselJ[l,k R], {k, 0,  ∞}, 
  Assumptions -> {l > 0, R > 0, n ∈ \!\(\*
TagBox["\[DoubleStruckCapitalZ]", Function[{}, Integers]]\)}]}

i.e. now Mathematica failed to solve my integral. Is this a bug or I'm missing something about Assumptions for symbolic integration?

EDIT (3.01.2016): According to WRI this is not a bug/backslide but merely a timing issue. As pointed out by @bbgodfrey, one can avoid this behavior by using Integrate together with TimeConstrained.

Answer 1

There are many possible variants of Assumptions here, including

AbsoluteTiming[Integrate[k^n SphericalBesselJ[l, R*k], {k, 0, ∞}, 
    Assumptions -> {l > 0, R > 0, n ∈ Reals}]]
(* {4.00979075897103, ConditionalExpression[
    (2^(-1 + n)*Sqrt[Pi]*R^(-1 - n)*Gamma[(1 + l + n)/2])/Gamma[(2 + l - n)/2], 
    n < 1 && l + n > -1]} *)

or

AbsoluteTiming[Integrate[k^n SphericalBesselJ[l, R*k], {k, 0, ∞}, 
    Assumptions -> {l > 0, R > 0, -1 - l < n < 1}]]
(* {11.002235487576527, 
    (2^(-1 + n)*Sqrt[Pi]*R^(-1 - n)*Gamma[(1 + l + n)/2])/Gamma[(2 + l - n)/2]} *)

or

AbsoluteTiming[Integrate[k^n SphericalBesselJ[l, R*k], {k, 0, ∞}, 
    Assumptions -> {l > 0, R > 0, (n | l) ∈ Integers}]]
(* {4.107987620241559, ConditionalExpression[
    (2^(-1 + n)*Sqrt[Pi]*R^(-1 - n)*Gamma[(1 + l + n)/2])/Gamma[(2 + l - n)/2], 
    n <= 0 && l + n >= 0]} *)

All works sometimes and not others. The latter two seem faster and more reliable, however.

Addendum

A work-around is to run the same Integrate two or three times in succession. I have posted a question about this strange behavior, in the hope of gaining more insight.

Solution

From comments made on the question referenced above, it has become apparent that Integrate times out after 60 seconds when attempting to do many of the integrals above when called the first time. The solution is to give it more time. For instance,

TimeConstrained[
    Integrate[k^n SphericalBesselJ[l, R*k], {k, 0, ∞}, 
        Assumptions -> {l > 0, R > 0, n ∈ Integers}], 120] // AbsoluteTiming

returns with the correct answer after about 70 seconds.

Answer 2

The problem arises in trying to determine the conditions for which the integral is defined. Using GenerateConditions -> False provides a solution with the additional assumption and is much faster.

AbsoluteTiming[
 Assuming[{l > 0, R > 0, Element[n, Integers]},
  Integrate[
   k^n SphericalBesselJ[l, R*k],
   {k, 0, ∞}, GenerateConditions -> False]]]

(*  {0.364262, (2^(-1 + n)*Sqrt[Pi]*
        R^(-1 - n)*Gamma[
          (1/2)*(1 + l + n)])/
     Gamma[(1/2)*(2 + l - n)]}  *)