1
$\begingroup$

My question is related to one I already asked (previous question).

The equation I am working with is cumbersome:

eq = Er k^2 γ ξ (1 + λ Cos[2 ϕ]) (3 I k Cos[ϕ] + 4 σ Cos[2 ϕ] + 
    I k Cos[3 ϕ]) Subscript[α, ac] + (ξ + σ) (σ + I k Cos[ϕ]) (8 k^4 + 
    16 k^2 tf1 + 2 k^4 γ + k^4 γ λ^2 + 8 Er k^2 γ σ + 16 Er tf1 γ σ + 
    4 k^4 γ λ Cos[2 ϕ] + k^4 γ λ^2 Cos[4 ϕ] + 
    4 k^2 (k^2 + Er γ σ) Sin[2 ϕ]^2 Subscript[μ, 1] + 
    4 (k^2 + Er γ σ) (k^2 + tf1 - tf1 Cos[2 ϕ]) Subscript[μ, 2])

The actual equation is Eq==0, and unknown variable is σ, all other letters are parameters. This is third-order algebraic equation, and it has three roots.

My current goal is to find the leading terms of all the roots σ[k] for large k. I need to prove that this leading terms are negative (roots are negative for large k). You can solve the equation directly, and ask for leading term near k = infinity:

coeffs = Reverse@CoefficientList[eq, σ];
sol = σ /.  Solve[FromDigits[Array[#[] &, Length[coeffs], 1], σ] == 
  0, σ] /. n_Integer[] :> coeffs[[n]]; 
Series[sol[[1]], {k, \[Infinity], 0}]

The evalution of the last line takes forever for a simple reason: as long as σ[k] has regular Taylor expansion near k=0, all terms will be given as an answer. For example, if I ask Series[1+k+k^2,{k, \[Infinity], 0}], I will be given all the terms 1+k+k^2, instead of just the leading term k^2.

The other approach I tried is to first divide the σ[k] by k^100, and then take Taylor expansion near infinity. For instance, if I will divide 1+k+k^2 by k^100 and will take Taylor series near infinity, I will be given just the leading term. But for some reason, this approach didn't work as well.

Can you suggest me any method how I can do this? The solution looks cumbersome, but all I need to do is to throw away the terms with low-powers of k. It is hard to do manually. I don't know how to write algorithm for this task.

I tried to plot the solution for different values of the parameters. It looks like all the roots should have leading term in the form c*k^n, as long as they decay slower, than exponent and don't oscillate.

Edit: If that helps, all the parameters, but Subscript[α, ac] are positive real constants, Subscript[α, ac] is negative real constant. Example values are:

Subscript[α, ac]=-1
λ  = 0.9
 Subscript[\[Mu], 2] = 1
 Er = 0.5
γ = 5
Subscript[\[Mu], 1] = 1
ξ=0.013
tf1=0.1
ϕ - any angle, for instance, ϕ=0

With these values it looks like one root is going to negative infinity, two others are constants. Note, that I need only real part of the roots. I want to prove, that the real part of all the roots is not positive as k goes to infinity.

$\endgroup$
  • $\begingroup$ Can you provide example values for all the parameters? $\endgroup$ – george2079 Dec 10 '15 at 19:37
  • $\begingroup$ @george2079 see edit. $\endgroup$ – Mikhail Genkin Dec 10 '15 at 20:47
2
$\begingroup$

This is not rigorous, but may suffice depending on your goals. First look at this thing numerically,

vals = {
   Subscript[α, ac] -> -1,
   λ -> 0.9,
   Subscript[μ, 2] -> 1,
   Er -> 0.5,
   γ -> 5,
   Subscript[μ, 1] -> 1,
   ξ -> 0.013,
   tf1 -> 0.1,
   ϕ -> 0};
eq = Er k^2 γ ξ (1 + λ Cos[
        2 ϕ]) (3 I k Cos[ϕ] + 4 σ Cos[2 ϕ] + 
      I k Cos[3 ϕ]) Subscript[α, 
     ac] + (ξ + σ) (σ + I k Cos[ϕ]) (8 k^4 + 
      16 k^2 tf1 + 2 k^4 γ + k^4 γ λ^2 + 
      8 Er k^2 γ σ + 16 Er tf1 γ σ + 
      4 k^4 γ λ Cos[2 ϕ] + 
      k^4 γ λ^2 Cos[4 ϕ] + 
      4 k^2 (k^2 + Er γ σ) Sin[
         2 ϕ]^2 Subscript[μ, 1] + 
      4 (k^2 + Er γ σ) (k^2 + tf1 - 
         tf1 Cos[2 ϕ]) Subscript[μ, 2]);
sol = (σ /. Solve[(eq /. vals) == 0, σ]);
Series[sol, {k, Infinity, 0}]

{(0. - 1. I) k, 0.160444 - 1.60333 k^2, -0.013}

We have one real finite solution as k->Infinity. ( Looks like ..) Now play with the other parameters, in Particular you can find that the finite result is independent of Er :

sol = (σ /. Solve[(eq /. Er -> 0 /. vals) == 0, σ]);
Series[sol, {k, Infinity, 0}]

{-0.013, (0. - 1. I) k}

Taking Er zero maxes the expression quadratic, so more nicely solved.

 Solve[(eq /. Er -> 0) == 0, σ]

So we see indeed the real result is ..

{{σ -> -ξ}, {σ -> -I k Cos[ϕ]}}

To trust this you really should play with all the parameters over their permissible range.

$\endgroup$
  • $\begingroup$ Thanks! I did similar analythis already! Although it is not rigorous, I think, I will end up with this arguments. $\endgroup$ – Mikhail Genkin Dec 10 '15 at 21:53
  • $\begingroup$ I worked out rigorous solution! $\endgroup$ – Mikhail Genkin Dec 11 '15 at 0:33
1
$\begingroup$

I figured out how do it. One should use singular asymptotic expansion!:

eq = Er k^2 γ ξ (1 + λ Cos[2 ϕ]) (3 I k Cos[ϕ] + 4 σ Cos[2 ϕ] + 
I k Cos[3 ϕ]) Subscript[α, ac] + (ξ + σ) (σ + I k Cos[ϕ]) (8 k^4 + 
16 k^2 tf1 + 2 k^4 γ + k^4 γ λ^2 + 8 Er k^2 γ σ + 16 Er tf1 γ σ + 
4 k^4 γ λ Cos[2 ϕ] + k^4 γ λ^2 Cos[4 ϕ] + 
4 k^2 (k^2 + Er γ σ) Sin[2 ϕ]^2 Subscript[μ, 1] + 
4 (k^2 + Er γ σ) (k^2 + tf1 - tf1 Cos[2 ϕ]) Subscript[μ, 2])

We can introduce small parameter eps:

k = k0/ε

I "cheated" a little bit, using @george2079 answer, so that I know, that the largest term in asymptotic expansion is k^2, and we need to choose σ as:

σ = ε^-2*(σ0 + σ1*ε + σ2*ε^2 + σ3*ε^3 + σ4*ε^4 + σ5*ε^5)

Now all we need to do, is to successfully solve equations for σ0,σ1,σ2,... so that coefficient near each of ε power is zero:

s = CoefficientList[eq*ε^8, ε]
temp = Solve[s[[1]] == 0, σ0]
r1 = temp[[1]]
r2 = temp[[2]]
r3 = temp[[3]]

As a result, temp contains three roots (we found σ0). Now take second equation to find σ1, using known σ0:

temp = Solve[Simplify[s[[2]] /. r3] == 0, \σ1]
r3 = Flatten[Append[r3, temp]]

Substitution into s[[2]] r1 and r2 gives us nothing (0=0), so in order to find σ1 for first and second roots, we need to solve next equation s[[3]], etc.

As a result, I got an expansion with symbolic coefficients. When I tried to substitute "example parameters" into my answer, I got the same numbers, as @george2079.

$\endgroup$
1
$\begingroup$

It is easy enough to learn about the lone solution at k=Infinity. One replaces k by 1/k, removes the denominator (it is independent of σ), and now sets k to zero (as I did in the prior related thread for a series expansion around k=0). Here is the code from that thread, adapted to handle k at infinity.

eq = Er k^2 γ ξ (1 + λ Cos[
        2 ϕ]) (3 I k Cos[ϕ] + 4 σ Cos[2 ϕ] + 
      I k Cos[3 ϕ]) Subscript[α, 
     ac] + (ξ + σ) (σ + I k Cos[ϕ]) (8 k^4 + 
      16 k^2 tf1 + 2 k^4 γ + k^4 γ λ^2 + 
      8 Er k^2 γ σ + 16 Er tf1 γ σ + 
      4 k^4 γ λ Cos[2 ϕ] + 
      k^4 γ λ^2 Cos[4 ϕ] + 
      4 k^2 (k^2 + Er γ σ) Sin[
         2 ϕ]^2 Subscript[μ, 1] + 
      4 (k^2 + Er γ σ) (k^2 + tf1 - 
         tf1 Cos[2 ϕ]) Subscript[μ, 2]);
eq2 = Numerator[Together[eq /. k -> 1/k]];
eqk = eq2 /. σ -> σ[k];
derivsys = Table[D[eqk, {k, j}], {j, 0, 3}];
derivvars = Table[D[σ[k], {k, j}], {j, 0, 3}];
newvars = Array[d, 4, 0];
subs = Thread[derivvars -> newvars];
sys = (derivsys /. subs) /. k -> 0;
soln = Solve[sys == 0, newvars];

There is but one solution, and as was already observed, it is at . the series solution is in powers of 1/k and the first order term vanishes.

Most[
   newvars].((1/k)^Range[0, 2]/Factorial[Range[0, 2]]) /. soln

(* Out[23]= {-ξ - (
  Er γ ξ (1 + λ Cos[2 ϕ]) (3 Cos[ϕ] + 
     Cos[3 ϕ]) Sec[ϕ] Subscript[α, ac])/(
  k^2 (8 + 2 γ + γ λ^2 + 
     4 γ λ Cos[2 ϕ] + γ λ^2 Cos[
       4 ϕ] + 4 Sin[2 ϕ]^2 Subscript[μ, 1] + 
     4 Subscript[μ, 2]))} *)

So what happened to the other two solutions forσ? In effect they wandered off to infinity, along I know not what path. What happens form large but finite k when they wander back in? I have tried some approaches from projective geometry in an effort to get at that, but have come up short. If anything new comes to mind that is more informative then I'll edit to indicate that.

$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.