Bags and non-standard evaluation

Question

What can internally be happening here? Is the evaluator just messing with us and going non-standard because it's a Bag? Or am I just not seeing how something like this could be done in Mathematica?

AppendTo[$ContextPath, "Internal`"];

In[19]:= ClearAll[x, y];
{x, y} = {Bag[{1, 2, 3}], Bag[{4, 5}]};

Heads are

In[21]:= Head /@ {x, y}

Out[21]= {Bag, Bag}

But they are just a head, no depth. Depths

In[22]:= Depth /@ {x, y}

Out[22]= {1, 1}

However, they are different. I take their second elements, or I print them in InputForm

In[23]:= BagPart[#, 2] & /@ {x, y}
InputForm /@ {x, y}

Out[23]= {2, 5}

Out[24]= {InputForm[Internal`Bag[{1, 2, 3}]], InputForm[Internal`Bag[{4, 5}]]}

Answer 1

This is not related to evaluation. Internal`Bag, like many other special types, is an atomic object. You can verify this using AtomQ[x]. This is despite its InputForm suggesting a structure.

This is no different from how Graph, Rational, Complex or SparseArray behave. (Though for SparseArray, most list manipulation functions are implemented, so it's much more difficult to notice that it is atomic).

---

A similar example using Rational:

In[206]:= rats={1/2,2/3}
Out[206]= {1/2,2/3}

In[208]:= Head/@rats
Out[208]= {Rational,Rational}

In[209]:= Depth/@rats
Out[209]= {1,1}

In[210]:= FullForm[rats]
Out[210]//FullForm= List[Rational[1,2],Rational[2,3]]

Answer 2

I think Internal`Bag is a monolithic object which is only constructed using the Bag[list] syntax. Note that the same is true for Graph:

Graph[{1<->2,2<->3}]//Head
(*
==> Graph
*)
Graph[{1<->2,2<->3}]//Depth
(*
==> 1
*)

Also note the output of the objects when typing directly in the kernel:

Internal`Bag[{2,3}]
(*
==> Internal`Bag[<2>]
*)
Graph[{1<->2,2<->3}]
(*
==> Graph[<3>, <2>]
*)

Even FullForm doesn't give more information, which shows that on the Mathematica expression level that's all there is.