How to replace element of list by index

Question

I'd simply like to replace the value x at index [[j,i]] in a two dimensional table with the value -x. There doesn't seem to be an intuitive way to do this. So far I've tried:

Flip[table_, i_, j_] := (table[[j, i]] = -table[[j, i]]; Return[table])

However I get the error:

Set::setps: <my table> in the part assignment is not a symbol.

Any suggestions?

Answer 1

You can use ReplacePart

 data = RandomReal[{}, {2, 2}]

data = ReplacePart[data, {1, 2} -> -data[[1, 2]]]

You need to reassign the result back to data

You can make the above into a function if needed.

 flip[data_, i_, j_] := ReplacePart[data, {i, j} -> -data[[i, j]]];
 data = flip[data, 1, 2]

In your function, you also did something wrong. You can't assign to an input. So your statement table[[j, i]] = -table[[j, i]] is writing to the input argument table. If you really wanted to do as you show, then:

flip[table_, i_, j_] := 
 Module[{myTable = table}, myTable[[i, j]] = -myTable[[i, j]]; 
  myTable]

Now the local variable myTable is used to modify, then it is returned back at the end. No need to use Return since by default, the last expression is the result of the function. (do not use ; at the end, else Null is returned instead)

Answer 2

Others have shown you ways to do what you want in ways which are more common to Mathematica. But I think what you really ask for (though it might not necessarily the best solution for your problem) is "pass by reference" which as such does not exist in Mathematica. But there is the possibility to use Attributes for functions and using e.g. HoldFirst will make your example work as intended:

SetAttributes[flip, HoldFirst]
flip[table_, i_, j_] := (table[[j, i]] = -table[[j, i]]; table)

note that I did change the function name to start with lower case which is good practice to avoid name conflicts with Mathematica owns symbol, including future versions. It is also hardly ever necessary to use a Return as the last expression of a CompoundExpression will be returned anyway.

The Hold*-attribute trick will also be the solution whenever you want to make changes to an existing symbol within a function, but as such must be used with care as it will make your functions have side effects which in general make your programs much harder to understand.

Answer 3

Wouldn't it be easier to use Part?

a = {{2, 3}, {4, 5}};
a[[1, 2]] = -a[[1, 2]];
a

{{2, -3}, {4, 5}}

Answer 4

a = {{2, 3}, {4, 5}};

Using MapAt and Minus

MapAt[Minus, {1, 2}] @ a

{{2, -3}, {4, 5}}

Answer 5

For in-place modification:

a = {{2, 3}, {4, 5}};

ApplyTo[a[[2, 1]], -# &]; a

(* {{2, 3}, {-4, 5}} *)

Or,

a = {{2, 3}, {4, 5}};


a[[2, 1]] //= -# &; a


(* {{2, 3}, {-4, 5}} *)

Answer 6

a = {{2, 3}, {4, 5}};

Another way using SubsetMap and Minus:

SubsetMap[Minus, a, {{1, 2}}]

{{2, -3}, {4, 5}}