Generating uniform random points over a binary image

Question

So I recently read this excellent post about generating random points over arbitrary regions. I hope Wolfram eventually builds that functionality into Mathematica's Random functions. I want to do this for binary images.

Given a binary image like this:

... I can generate random lattice points over the black parts by doing:

 ListPlot[RandomSample[PixelValuePositions[Binarize[img], Black],1500],
  AspectRatio -> ImageAspectRatio[img]]

which gives this plot:

However, the problem is that all generated random points will lie on integer coordinates. For example, the point {150, 100} can be generated by my approach, yet the point {150.278, 100.123} will never be generated. I want to generate random points uniformly anywhere within the coastlines/black regions.

Answer 1

Update

Silvia proposed a much faster algorithm that I believe produces I uniform distribution.
Here is my implementation of it.

pointsInMask2[mask_Image, n_Integer, range : {_, _} : {0, 1/2}] :=
  Reverse @ ImageData @ Binarize[mask, range]\[Transpose] //
    SparseArray[#]["NonzeroPositions"] & //
      RandomChoice[#, n] + RandomReal[{-1, 0}, {n, 2}] &

img = Import["https://i.sstatic.net/yoPNX.png"];

Graphics[{
  AbsolutePointSize[1], Opacity[0.3],
  pointsInMask2[img, 75000] // Point
}]

The optional range parameter specifies the range of values in the mask image that are valid target area.

Graphics[{
  AbsolutePointSize[1], Opacity[0.3],
  pointsInMask2[img, 75000, {1/2, 1}] // Point
}]

---

A "brute force" method

Although my first method will be superior if one wishes to generate many points there is a more direct and simple approach, though it does not benefit from any of the optimizations in the linked question. That is simply to generate random points and select the ones for which the matching ImageValue is closer to black than white. This requires redundant sampling and will be increasingly slow on images with a small percentage of black pixels. (For now I am simply estimating the number of samples needed and not performing a check to make sure the requested number are actually produced; if this method proves useful I shall refine my approach.)

pointsInMask[mask_Image, n_Integer] :=
  Module[{dims, pts, n2},
    dims = ImageDimensions[mask];
    n2 = ⌈ 1.1 n #/(# - ImageData[mask] ~Total~ 2) &[Times @@ dims] ⌉;
    pts = RandomReal[#, n2] & /@ dims // Transpose;
    Select[pts, ImageValue[mask, #] < 0.5 &, n]
  ]

Test:

mask = Binarize @ Import["https://i.sstatic.net/yoPNX.png"]

pts = pointsInMask[mask, 5000];

Graphics[{AbsolutePointSize[1], Point @ pts}]

Answer 2

Following up on my comment and borrowing a method from Vectorizing an image like "Trace Bitmap" in Inkscape:

mask = Binarize @ Import["https://i.sstatic.net/yoPNX.png"];

{row, col} = ImageDimensions[mask];

intf = ListInterpolation @ Reverse @ ImageData @ mask;

region = DiscretizeGraphics @ 
  RegionPlot[intf[c, r] < 1/2, {r, 1, row}, {c, 1, col},
    PlotPoints -> {row, col}, MaxRecursion -> 0]

You can then apply whichever of the methods from How to generate random points in a region? that you find appropriate, e.g.:

pts = randomFromRegion[region, 15000];

Graphics[{AbsolutePointSize[1], Point @ pts}]

Answer 3

In version 11, one can use ImageMesh[] in tandem with RandomPoint[], like so:

imsh = ImageMesh[ColorNegate[Import["https://i.sstatic.net/yoPNX.png"]]];
Graphics[Point[RandomPoint[imsh, 5000]]]