Using Block with a list of variables

Question

I have a list of variables

var={v1,v2};

which I want to protect/localize during a particular operation. I have decided that I want to use Block and if I write

Block[{v1,v2},Print[4]] 

everything is fine but what I really need is to somehow implement the functionality:

Block[vars,Print[4]] 

Is there any way to achieve this?

Answer 1

Storing v1 and v2 in a variable makes it more complicated. It is better to construct custom dynamic environments based on Block, which would be closures, closed over symbolic variables you want.

Here is a generator for such environments:

withBlockedVars = Function[vars, Function[code, Block[vars, code], HoldAll], HoldAll];

Here is how you generate a particular one you need (v1 and v2 here may have global values, this doesn't matter):

myBlock = withBlockedVars[{v1, v2}]

(* Function[code$, Block[{v1, v2}, code$], HoldAll] *)

What you get is a closure, with your specific variables embedded into it. Here is how you can use it:

{v1, v2} = {1, 2};
myBlock[Print[{v1, v2}]]

(* {v1,v2} *)

If you insist on using var, you can do it like so:

myBlock = Hold[var] /. OwnValues[var] /. Hold[val_]:> withBlockedVars[val],

and then continue in the same way as above.

Answer 2

Using my bump function (horrible name, sorry) from Elegant manipulation of the variables list:

func_[bump[lst_, idx___], arg___] ^:= 
  func[#, arg] & @ Part[List @@@ Unevaluated @@ {lst}, {1}, idx]

{v1, v2} = {7, 9}; (* existing values *)

vars = Hold[v1, v2];

Block[bump[vars], Print[v1, ", ", v2]]

v1, v2

See the linked question for many other uses of this flexible function.

Answer 3

Actually, it turns out that what I was looking for was a simple use of Evaluate, i.e. the following code:

var={v1,v2};
Block[Evaluate[var],Print[4]] 

does the trick, provided there are no values assigned to v1 and v2. If that is an important consideration, the more complicated code from the other answers can be used, but for me the above simple solution proved sufficient.

As Mr.Wizard pointed out in the comments the above code allows for assignments to the variables that are only local. For example the code

var={v1,v2};
Block[Evaluate[var],v1=1;v2=2;{v1,v2}] 

returns

{1,2}

whereas

var={v1,v2};
Block[Evaluate[var],v1=1;v2=2;{v1,v2}];
{v1,v2}

returns

{v1,v2}

demonstrating that the local assignments do not affect the global variables.

Once more, as Leonid points out, if there are assignments made to the variables initially, the code fails and more elaborate solutions are needed.