Why does MakeBoxes mess up RowBox ordering?

Question

When I use RowBox for MakeBoxes the order of the elements is changed for TraditionalForm, if there is a plus (+) in the list of elements.

MakeBoxes[x, form_] = RowBox[{"b", "+", "a"}];
MakeBoxes[x, StandardForm]
MakeBoxes[x, TraditionalForm]
(* Out[2] = RowBox[{"b", "+", "a"}]
   Out[3] = RowBox[{"a", "+", "b"}] *)

Sometimes Mathematica really makes me wonder. Does this only happen when there is a plus in RowBox? Is there any way to fix this?

Answer 1

When I see this right, then the evil function is TraditionalFormDump`ordplus. This seems to change the order. The arguments can be extracted from a Trace

TraditionalForm[a + b]; (* Dummy call *)
TraditionalFormDump`ordplus[{{"+", "b"}, {"+", "a"}}, {}]

(* {2,1} *)

If we change this to give a sorted list, then your arguments are not reordered

ClearAll[TraditionalFormDump`ordplus]
TraditionalFormDump`ordplus[l1_, _] := Range[Length[l1]]

MakeBoxes[x, form_] = RowBox[{"b", "+", "a"}];
MakeBoxes[x, StandardForm]
MakeBoxes[x, TraditionalForm]

(* 
  RowBox[{"b", "+", "a"}]
  RowBox[{"b", "+", "a"}]
*)

Answer 2

halirutan gave a very nice explanation why this only happens in TraditionalForm and not in StandardForm. For completeness I will add the workaround that Rojo mentioned: Associate the definition to x and not to MakeBoxes using UpSet:

MakeBoxes[x, form_] ^= RowBox[{"b", "+", "a"}];

Association with TraditionalForm also works:

Unprotect[TraditionalForm];
TraditionalForm /: MakeBoxes[x, TraditionalForm] = RowBox[{"b", "+", "a"}];

Answer 3

You can also interfere with the sorting done by TraditionalForm by wrapping your boxes in TagBox, InterpretationBox or TemplateBox:

MakeBoxes[x, form_] = TagBox[RowBox[{"b", "+", "a"}], #&];
MakeBoxes[x, StandardForm]
MakeBoxes[x, TraditionalForm]

TagBox[RowBox[{"b", "+", "a"}], #1 &]

TagBox[RowBox[{"b", "+", "a"}], #1 &]

(I would actually use a TagSet here, but for pedagogical reasons I avoided it.) This avoids the need to modify an internal Mathematica symbol, as in the accepted answer (there may also be good examples where the reordering is beneficial, as in multivariate polynomials). Also, as Mr.Wizard points out, the other answers using TagSet only work when x is at the top-level. For example:

y /: MakeBoxes[y, form_] = RowBox[{"b", "+", "a"}];
MakeBoxes[y, TraditionalForm]
MakeBoxes[{y}, TraditionalForm]

RowBox[{"b", "+", "a"}]

RowBox[{"{", RowBox[{"a", "+", "b"}], "}"}]

With the TagBox approach, the non-top level example still works:

MakeBoxes[{x}, TraditionalForm]

RowBox[{"{", TagBox[RowBox[{"b", "+", "a"}], #1 &], "}"}]