This is a tricky sum because for $m>\frac{1}{\sqrt{2}}$ we need analytic continuation or regularization to compute it.
A simplified version of the sum approximates $\zeta[2(k-1)]\approx 1$ and
$$
f(m)=-2\sum_{k=0}^{\infty}\binom{1/2}{k}\left(2^{2(k-1)}-1\right)\zeta\left[2(k-1)\right]\left(m^2-\frac14\right)^k\\
\approx-2\sum_{k=2}^{\infty}\binom{1/2}{k}\left(2^{2(k-1)}-1\right)\left(m^2-\frac14\right)^k\\
= \sqrt{4 m^2+3}-m-\frac{3}{2}.
$$
The last step is only strictly correct when the exponential term is smaller than 1 in magnitude: $\left(2^{2k-1}-1\right)\left(m^2-\frac14\right)^k\approx\frac12\left(4m^2-1\right)^k$ and the sum only converges if $\left|4m^2-1\right|\le1$, meaning $|m|\le\frac{1}{\sqrt{2}}$. For larger $m$ the sum converges only after regularization.
You can see the effect of this in @UlrichNeumann's solution: for $m>\frac{1}{\sqrt{2}}$ explicit summing no longer works, and regularization is required.
However, I don't know how to use regularization in a numerical sum. Better ask at the math StackExchange.
update: numerical summing that works
Expand the Riemann ζ-function by its definition: $\zeta[2(n-1)]=\sum_{k=1}^{\infty}\frac{1}{k^{2(n-1)}}$, from which
$$
f(m)=-2\sum_{n=0}^{\infty}\binom{1/2}{n}\left(2^{2(n-1)}-1\right)\zeta\left[2(n-1)\right]\left(m^2-\frac14\right)^n\\
=-2\sum_{n=2}^{\infty}\binom{1/2}{n}\left(2^{2(n-1)}-1\right)\left(m^2-\frac14\right)^n\sum_{k=1}^{\infty}\frac{1}{k^{2(n-1)}}
$$
(the lower limit on $n$ can be set to 2 because for $n=0$ and $n=1$ the summand is zero).
Interchange the order of summation: (this is the "renormalization step" that maybe some mathematicians will take issue with; but it works in practice)
$$
f(m)=-2\sum_{k=1}^{\infty}\sum_{n=2}^{\infty}\binom{1/2}{n}\left(2^{2(n-1)}-1\right)\left(m^2-\frac14\right)^n\frac{1}{k^{2(n-1)}}
$$
Now we can do the $n$-summation exactly:
f[m_, n_, k_] = -2 (-1 + 2^(2 (-1 + n))) (-(1/4) + m^2)^n Binomial[1/2, n] 1/k^(2 (n - 1));
f[m_, k_] = Assuming[0 < m < 1 && Element[k, PositiveIntegers],
Sum[f[m, n, k], {n, 2, ∞}] // FullSimplify]
(* -(1/2) k (3 k + Sqrt[-1 + k^2 + 4 m^2] - 2 Sqrt[-1 + 4 k^2 + 4 m^2]) *)
This formulation is no longer divergent and can be summed numerically for any $m$:
f[m_] = Sum[f[m, k], {k, 1, 10^3}] // Expand;
Plot[f[m], {m, 0, 1}]
If you need more accuracy in the sum, I'd suggest using an asymptotic expansion of the summand for large $k$ and then summing that all the way to infinity:
f∞[m_, k_] = Series[f[m, k], {k, ∞, 10}] // Normal
$$
\frac{3 \left(4 m^2-1\right)^2}{64 k^2}
-\frac{15\left(4 m^2-1\right)^3}{512 k^4}
+\frac{315 \left(4 m^2-1\right)^4}{16384 k^6}
-\frac{1785 \left(4 m^2-1\right)^5}{131072 k^8}
+\frac{21483 \left(4 m^2-1\right)^6}{2097152 k^{10}}
$$
With[{kmax = 10^3},
f[m_] = Sum[f[m, k], {k, 1, kmax}] +
Sum[f∞[m, k], {k, kmax + 1, ∞}] // Expand];
f[1/Sqrt[2]] // N
(* 0.057067155838012695 *)
