How can I find the least value of a function with parameter?

Question

With the function $f(x) = x^3 - 12 x + 2$. To find the least value of the function $f(x)$ with $-2\leqslant x \leqslant 2$, I tried

Minimize[{f[x], -2 <= x <= 2}, x]

{-14, {x -> 2}}

I am trying to find the least value of the function $(f(x+m))^2$, I tried

Clear["Global`*"]
f[x_] = x^3 - 12  x + 2;
g[x_] = f[x + m]^2;
Minimize[{g[x], -2 <= x <= 2}, x]

I don't get the Out of Mathematica. How can I find the least value of a function with parameter $(f(x+m))^2$?

Answer 1

$Version

(* "14.1.0 for Mac OS X ARM (64-bit) (July 16, 2024)" *)

Clear["Global`*"]

f[x_] = x^3 - 12 x + 2;

Since g is a function of two variables, there should be two arguments.

g[m_, x_] = f[x + m]^2;

If all you need to know is the minimum value, use MinValue rather than Minimize. This will give a leaner result.

min[m_] = MinValue[{g[m, x], -2 <= x <= 2}, x]

To convert the Root expressions to radicals use ToRadicals

min2[m_] = min[m] /. r_Root :> ToRadicals[r]

Graphically,

Plot[min[m], {m, -564/100, 549/100},
 PlotPoints -> 150,
 MaxRecursion -> 5,
 WorkingPrecision -> 15,
 ImageSize -> Large,
 Epilog -> Inset[LogPlot[min[m], {m, -20, 20}],
   {2.75, 5}]]

Answer 2

Clear["Global`*"]
f[x_] = x^3 - 12    x + 2;
g[m_, x_] = f[x + m]^2;
minimizeForEachm[m_] := Minimize[{g[m, x], -2 <= x <= 2}, {x}]
dataPoints = 
  ParallelTable[
   Module[{ele = minimizeForEachm[m]}, {m, x /. Part[ele, 2], 
     Part[ele, 1]}], {m, Range[-20, 20, 0.001]}];
ListPointPlot3D[dataPoints, 
 AxesLabel -> {"parameter m", "optimal x", "MinValue"}, 
 PlotRange -> Full]