How to verify a FactorialPower identity?

Question

How to verify that FactorialPower[x, m*n, k] is always the same as Product[FactorialPower[x - i*k, n, m*k], {i, 0, m - 1}] wherever Element[{k, m, n}, PositiveIntegers]?

The obvious choice

FullSimplify[
 FunctionExpand[
  FactorialPower[x, m*n, k] == 
   Product[FactorialPower[x - i*k, n, m*k], {i, 0, 
     m - 1}]], {Element[{k, m, n}, PositiveIntegers]}]

doesn't seem to work.

Answer 1

Another way is to use FindSequenceFunction

We start from

FactorialPower[x - i*k, n, m*k]

and compute a few values, say m=1,2,3,4,5

In the numerator we have Gamma[something] with the something being the same in all cases. All we need to do is write a general formula for its pre-factor and the denominator. We do that as follows:

(Table[Product[FactorialPower[x - i*k, n, m*k], {i, 0, m - 1}], {m, 1,
           10}] // FunctionExpand // 
       FullSimplify[#, Element[{k, m, n}, PositiveIntegers]] & // 
      Numerator) /. Gamma[x_] :> 1 // FindSequenceFunction[#, m] & // 
  Expand // FullSimplify[#, Element[{k, m, n}, PositiveIntegers]] &
(Table[Product[FactorialPower[x - i*k, n, m*k], {i, 0, m - 1}], {m, 1,
          10}] // FunctionExpand // 
      FullSimplify[#, Element[{k, m, n}, PositiveIntegers]] & // 
     Denominator) /. Gamma[x_] :> x // 
  FindSequenceFunction[#, m] & // Expand

and we get the 2 results

k^(m n)

1 - m n + x/k

The above, means that we have obtained

(k^(m n) Gamma[(k + x)/k])/Gamma[1 - m n + x/k]

And now you can compare it directly to

FactorialPower[x, m*n, k] // FunctionExpand // 
 FullSimplify[#, Element[{k, m, n}, PositiveIntegers]] &

which gives

(k^(m n) Gamma[(k + x)/k])/Gamma[1 - m n + x/k]

Answer 2

A very good indication is that it's true for $m=1\ldots30$ (and higher, if you have the patience):

check[m_] := FullSimplify[FunctionExpand[
   FactorialPower[x, m*n, k] == Product[FactorialPower[x - i*k, n, m*k], {i, 0, m - 1}]],
   Assumptions -> k > 0]

Table[check[m], {m, 30}]
(*    {True, True, True, True, True, True, True, True, True, True,
       True, True, True, True, True, True, True, True, True, True,
       True, True, True, True, True, True, True, True, True, True}    *)