How to get the analytical form of a solution to an algebraic equation?

Question

The real analytical solution of the algebraic equation $x^5 + 10 x^3 + 20 x == 4$ is $x=-2^{2/5} + 2^{3/5}$, how to get it with Mathematica?

I've tried with Solve, but it returns x -> Root[-4 + 20 # + 10 #^3 + #^5& , 1, 0] in its original form.

The analytical solution is obtained by let $x=t-2/t$, so that $t^5-32/t^5==4$, then it is easy to solve it. But I believe and hope that smart Mathematica can get the analytic form of this concise solution without me prompting this trick.

The code is shown below.

eqn = x^5 + 10 x^3 + 20 x == 4;
SolveValues[eqn, x, Reals]
Solve[eqn /. x -> t - 2/t, t, Reals];
t - 2/t /. % // Simplify

Answer 1

Using answer in Solving quintic in radicals

QuinticToRadicals[sol[[1]]]

gives

Full code (see post above)

QuinticToRadicals[root_Root].....

Now to use it, just do

eqn=x^5+10 x^3+20 x==4;
sol=SolveValues[eqn,x];
QuinticToRadicals[sol[[1]]]

For all the roots it gives

Map[QuinticToRadicals,sol]// Column

Answer 2

The simplest approach relies on observation that our polynomial $x^5 + 10 x^3 + 20 x -4$ is of the fifth order with integer coefficients divisible by $2$ (beside one with the highest order power). And so it is natural to look for its factorization with Extension $2^{1/5}$:

Factor[x^5 + 10 x^3 + 20 x - 4, Extension -> 2^(1/5)]

We can see a factor $(x-(2^{3/5}-2^{2/5}))$ and so it becomes clear that $2^{3/5} - 2^{2/5}$ is a real root of the polynomial

Simplify[ x^5 + 10 x^3 + 20 x - 4 /. x -> -2^(2/5) + 2^(3/5)]

0

Q.E.D.

All complex solutions one can get with

Factor[x^5 + 10 x^3 + 20 x - 4, Extension -> {2^(1/5), (-1)^(1/5)}]

or in explicitly complex form ( the output in TeXForm)

ComplexExpand /@ Factor[ x^5 + 10 x^3 + 20 x - 4,
                         Extension -> {2^(1/5), (-1)^(1/5)}]

$$-\left(\left(-x+2^{3/5}-2^{2/5}\right) \\ \left(-x+i \left(2^{2/5} \sqrt{\frac{5}{8}-\frac{\sqrt{5}}{8}}+2^{3/5} \sqrt{\frac{5}{8}-\frac{\sqrt{5}}{8}}\right)-\frac{\sqrt{5}}{2\ 2^{2/5}}+\frac{\sqrt{5}}{2\ 2^{3/5}}-\frac{1}{2\ 2^{2/5}}+\frac{1}{2\ 2^{3/5}}\right)\\ \left(-x+i \left(2^{2/5} \sqrt{\frac{5}{8}+\frac{\sqrt{5}}{8}}+2^{3/5} \sqrt{\frac{5}{8}+\frac{\sqrt{5}}{8}}\right)+\frac{\sqrt{5}}{2\ 2^{2/5}}-\frac{\sqrt{5}}{2\ 2^{3/5}}-\frac{1}{2\ 2^{2/5}}+\frac{1}{2\ 2^{3/5}}\right)\\ \left(x+i \left(2^{2/5} \sqrt{\frac{5}{8}-\frac{\sqrt{5}}{8}}+2^{3/5} \sqrt{\frac{5}{8}-\frac{\sqrt{5}}{8}}\right)+\frac{\sqrt{5}}{2\ 2^{2/5}}-\frac{\sqrt{5}}{2\ 2^{3/5}}+\frac{1}{2\ 2^{2/5}}-\frac{1}{2\ 2^{3/5}}\right)\\ \left(x+i \left(2^{2/5} \sqrt{\frac{5}{8}+\frac{\sqrt{5}}{8}}+2^{3/5} \sqrt{\frac{5}{8}+\frac{\sqrt{5}}{8}}\right)-\frac{\sqrt{5}}{2\ 2^{2/5}}+\frac{\sqrt{5}}{2\ 2^{3/5}}+\frac{1}{2\ 2^{2/5}}-\frac{1}{2\ 2^{3/5}}\right)\right)$$

Answer 3

Here is a way to do the manipulations in Mathematica/Wolfram Language:

eqn = x^5 + 10  x^3 + 20  x - 4 == 0
eqn2 = SubtractSides[
   MultiplySides[FullSimplify[eqn /. x -> (t - 2/t)], t^5][[1, 1, 
      1]] // Simplify, 32 + 4 t^5] // Expand
eqn3 = eqn2 /. t -> u^(1/5)
is = u /. Solve[eqn3, u];
res = DeleteDuplicatesBy[
   a - 2/a /. Join @@ (Solve[a^5 == #, a] & /@ is), N];
Extract[res, Position[N[res], _Real]][[1]]