Missing antialiasing on Filling

Question

They seem to forget add antialiasing on Filling.

When style is transparent we can see a rough boundary.

When style is not transparent the boundary is overlaid with the curve of plotting function on which the antialiasing is used, so no rough boundary is visible.

Is this the same with newer versions of Mathematica?

$Version
Plot[{Sin[x], Sin[x] + 0.05, Sin[x] + 0.06, 
  Sin[x] + 0.11}, {x, Pi/2 - 0.5, Pi/2 + 0.5}, 
 Filling -> {1 -> {{2}, Red}, 3 -> {{4}, Red}}, 
 PlotStyle -> {Red, Red, Transparent, Transparent}, 
 Background -> Green]

---

"13.0.1 for Microsoft Windows (64-bit) (January 28, 2022)"

Answer 1

The same behaviour is observed in "14.0.0 for Microsoft Windows (64-bit) (December 13, 2023)", but you can just simply manually enable Antialiasing for fillings.

Plot[{Sin[x], Sin[x] + 0.05, Sin[x] + 0.06, Sin[x] + 0.11}, {x, 
  Pi/2 - 0.5, Pi/2 + 0.5}, PlotStyle -> None,
 Filling -> {1 -> {{2}, Style[Red, Antialiasing -> True]}, 
             3 -> {{4}, Style[Red, Antialiasing -> True]}}]

To get it working also in 13.3, you can put the Antialiasing in FillingStyle:

Plot[{Sin[x], Sin[x] + 0.05, Sin[x] + 0.06, Sin[x] + 0.11}, {x, 
  Pi/2 - 0.5, Pi/2 + 0.5}, PlotStyle -> None, 
 Filling -> {1 -> {2}, 3 -> {4}}, 
 FillingStyle -> Directive[Opacity[1], Red, Antialiasing -> True]]

or, as you've figured it out yourself in the comments, wrap the whole thing with Style:

Style[Plot[{Sin[x], Sin[x] + 0.05, Sin[x] + 0.06, Sin[x] + 0.11}, {x, 
   Pi/2 - 0.5, Pi/2 + 0.5}, PlotStyle -> None, 
  Filling -> {1 -> {{2}, Red}, 3 -> {{4}, Red}}], 
 Antialiasing -> True]