Is there a way to add a tooltip to points on the x axis?

Question

I have a list of values associated with the xaxis, but I do not want to plot them as y values. Rather I want to do something like "TickLabels" in Matlab, but make them Tooltips (because they can be rather long). Conceptually, it would be something like this:

timepoint 1 -> "this is the first point"
timepoint 2 -> "but then we started to wander"
timepoint 3 -> "we found our way back again"
timepoint 4 -> "on track!"

For anyone who stumbles on this request: I did find this helpful guide, but it appears to expect a list of actual values (associated with location along the axis).

Answer 1

pts = {π/4, π/2, (2 π)/3, π};

msgs = {"this is the first point", "but then we started to wander", 
   "we found our way back again", "on track!"};

Show[Plot[Sin[x], {x, 0, 2 Pi}, GridLines -> {pts, None}], 
 NumberLinePlot[MapThread[Tooltip]@{pts, msgs}, 
  PlotStyle -> Directive[Red, 
    Opacity -> Dynamic[If[CurrentValue["MouseOver"], 1., .2]], 
    AbsolutePointSize[Dynamic[If[CurrentValue["MouseOver"], 15, 5]]]],
   Spacings -> 0]]

Answer 2

Clear["Global`*"];
pts = {π/4, π/2, 2 π/3, π};
msgs = {"this is the first point", "but then we started to wander", 
   "we found our way back again", "on track!"};
tips = Transpose[{{#, 0} & /@ pts, msgs}];

p1 = Plot[Sin[x], {x, 0, 2 Pi}
   , GridLines -> {pts, None}
   ];

p2 = Show[
   Region[
      Tooltip[Style[Point[First@#]
        , Directive[Red, AbsolutePointSize[6], Opacity[1]]]
       , Rotate[Last@#, π/2]]] & /@ tips
   ];

Show[p1, p2]

You can set Opacity[0] to make the Red point disappear, remove or keep the GridLines and Rotate the label (or not).