Translate selection from one list to another

Question

I wanted to know the most efficient and less resource consuming way to do the following: first, use the Select function to filter some values out of some list, e.g.

a={1,2,3,4,5,6};
a2=Select[a,EvenQ];

Now, let's create another list of the same length, b={a,b,c,d,e,f}. I want to pick exactly the same elements that I picked in a, i.e. b2={b,d,f}. Is there a built-in function that allows me to do that? If not, what would be the quickest way to do that (in terms of computing time)?

Edit: after some useful responses, I want to clarify something: I still want to do the selection in list a, i.e. I want to know if there is a way to do the selection in both lists a,b in one single step. What I've thought of is combining both lists with c=Transpose[{a,b}] and then applying Select with the condition on c[[i,1]], where i represents the index of either aor b. However, if there is any other solution, I'd like to hear it.

Answer 1

An update

Using the third argument of GroupBy, PositionIndex and Extract:

Extract[GroupBy[PositionIndex[blist], EvenQ, Keys], Key[{True}]]

(*{b, d, f}*)

Or using AssociationThread, GroupBy and Lookup:

Keys@Lookup[GroupBy[AssociationThread[#, Range[Length@#]] &@blist, EvenQ], True]

(*{b, d, f}*)

Answer 2

You could use Pick[]:

Pick[{a, b, c, d, e, f}, EvenQ[{1, 2, 3, 4, 5, 6}]]
(*  {b, d, f}  *)

Timing examples (numerical methods on packed arrays are naturally fastest, but data is not always numerical and packed):

biglist = Range[10^7];
Pick[biglist, EvenQ[biglist]]; // RepeatedTiming
(*  {0.454526, Null}  *)

biglist = Developer`FromPackedArray@Range[10^7];
Pick[biglist, EvenQ[biglist]]; // RepeatedTiming
(*  {0.28087, Null}  *)

biglist = Range[10^7];
Pick[biglist, Mod[biglist, 2], 0]; // RepeatedTiming
(*  {0.076138, Null}  *)

biglist = Developer`FromPackedArray@Range[10^7];
Pick[biglist, Mod[biglist, 2], 0]; // RepeatedTiming
(*  {1.35772, Null}  *)

Answer 3

Or use Association.

Clear[list1, list2, asso, list];
list1 = {1, 2, 3, 4, 5, 6};
list2 = {a, b, c, d, e, f};
asso = Association[Thread[list2 -> list1]];
list = Select[asso, EvenQ]
Keys@list

<|b -> 2, d -> 4, f -> 6|>

{b, d, f}

Answer 4

There can be many solutions, and here is one of them.

Clear[alist, blist]
alist = {1, 2, 3, 4, 5, 6};
blist = {a, b, c, d, e, f};
Extract[blist, Position[alist, x_ /; EvenQ[x]]]

---

Another one could be:

Pick[blist, EvenQ[alist]]

---

Using Transpose:

Select[Transpose[{alist, blist}], EvenQ@First@# &][[All, -1]]

---

Result

{b, d, f}

Answer 5

The most minimal way -I think- to pick the even elements is to use the step specification in the Part like so:

list = {a, b, c, d, e, f};

list[[2 ;; -1 ;; 2]]

{b, d, f}

Answer 6

KeySelect is another possibility

al = {1, 2, 3, 4, 5, 6};
bl = {a, b, c, d, e, f};

KeySelect[EvenQ] @ Thread[al -> bl]

Values[%]

{b, d, f}

It should be noted that KeySelect automatically creates an Association. So we can use Thread instead of AssociationThread saving 11 keystrokes.