4
$\begingroup$

I am trying to find pairs of integers $(x,y)$ $(x >0, y >0)$ satisfying $$(x + y) (5 x + y)^3 + x y^3 = (5 x + y)^3 + x^2 y^3 + x y^4 $$ I tried

SolveValues[(x + y) (5 x + y)^3 + x y^3 == (5 x + y)^3 + x^2 y^3 + 
    x y^4 && x > 0 && y > 0, {x, y}, Integers]

I can not get the results $(8,40)$ and $(216, 216)$. How can I get solutions if we do not know $(8,40)$ and $(216, 216)$ are solutions?

Improve this question
$\endgroup$
1
  • 1
    $\begingroup$ Are you looking for a single solution? A fixed number of solutions? All solutions within some bounded domain? A characterization of the complete solution set? $\endgroup$
    – Michael Seifert
    Commented Jun 20, 2022 at 12:27

3 Answers 3

Reset to default
6
$\begingroup$

Show, this two solutions are all possible solutions with variable transformation.

feq = Subtract @@ ((x + y) (5 x + y)^3 + x y^3 == (5 x + y)^3 + 
      x^2 y^3 + x y^4) // Expand

Solve[0 == feq && x > 0 && y > 0, {y}, Integers] // ToRadicals // 
 FullSimplify[#, x > 0] &

(*   {{y -> ConditionalExpression[(
    5 x)/(-1 + x^(1/3)), (x | y) \[Element] Integers && x >= 2]}}   *)

sol = First@Solve[x^(1/3) == xx, x]

y == (5 x)/(-1 + x^(1/3)) /. sol // Simplify[#, xx > 1] &

(*   5 xx^3 + y == xx y   *)

Solve[5 xx^3 + y == xx y && xx > 1 && y > 0, xx, Integers] /. 
 xx -> x^(1/3)

(*   {{x^(1/3) -> ConditionalExpression[2, y == 40]}, 
      {x^(1/3) -> ConditionalExpression[6, y == 216]}}   *)

Edit

As the fine comment of @DanielLichtblau (thanks a lot !) shows, from y == (5 x)/(-1 + x^(1/3)) x^(1/3) , which is my xx, has to be an integer. This is used in the last Solve command.

Improve this answer
$\endgroup$
2
  • $\begingroup$ From the equation y == (5 x)/(-1 + x^(1/3)) you know x is a cube of an integer, call it x=t^3. So the numerator is 5*t^3 and the denominator is t-1. This that has no factors in common with t^3 so it must divide 5. This means either t=2 or t=6, thus x is 2^3=8 or 6^3=216. Unless I missed something, this exhausts all cases. $\endgroup$
    – Daniel Lichtblau
    Commented Jun 21, 2022 at 0:02
  • $\begingroup$ By the way, you don't really need Solve, just some algebra on paper (or in a notebook). Rewrite the equation as (x + y - 1) ((5 x + y)^3 - x y^3)==0. The constraints mean the first factor cannot vanish, so we have (5 x + y)^3 = x y^3. Take cube roots (these are real-valued) to get 5 x + y=x^(1/3)*y. Rearrange as y=5x/(x^(1/3)-1). $\endgroup$
    – Daniel Lichtblau
    Commented Jun 21, 2022 at 19:54
6
$\begingroup$

Try

FindInstance[(x + y) (5 x + y)^3 + x y^3 == (5 x + y)^3 + x^2 y^3 + x y^4, {x, y}, PositiveIntegers] 
(* {{x -> 8, y -> 40}} *)

Also NSolve (and Solve too) in a restricted domain evaluates all solutions:

NSolve[{(x + y) (5 x + y)^3 + x y^3 == (5 x + y)^3 + x^2 y^3 +x y^4,Element[{x, y}, PositiveIntegers ], x < 300, y < 300}, {x,y}]
(*{{x -> 8, y -> 40}, {x -> 216, y -> 216}}*)
Improve this answer
$\endgroup$
4
  • $\begingroup$ I think this is not a completed answer. Because, you used x<300 and y<300. $\endgroup$
    – minhthien_2016
    Commented Jun 20, 2022 at 12:05
  • 1
    $\begingroup$ @minhthien_2016 The answer is quite correct given the way you have posed the question. One can get finitely many solution only if the solution domain is bounded. Otherwise an equation in two variables has infinitely many solutions. $\endgroup$
    – PlatoManiac
    Commented Jun 20, 2022 at 13:04
  • 3
    $\begingroup$ @PlatoManiac: That last sentence isn't strictly true if we're only looking at integer solutions. For example, there are only 12 solutions of $x^2 + y^2 = 25$ over all of the integers, and only two if we want $x >0$ and $y > 0$. $\endgroup$
    – Michael Seifert
    Commented Jun 20, 2022 at 16:00
  • $\begingroup$ @MichaelSeifert Correct I should have been more careful framing the comment and should have considered the Integer domain criteria in the question. $\endgroup$
    – PlatoManiac
    Commented Jun 21, 2022 at 17:40
1
$\begingroup$

Not sure if you can assume y >= x, but that is needed to find your preferred solutions:

Solve[(x + y) (5 x + y)^3 + x y^3 == (5 x + y)^3 + x^2 y^3 + x y^4 && 
x > 0 && y > 0 && y >= x, {x, y}, Integers]

returns

{{x -> 8, y -> 40}, {x -> 216, y -> 216}}
Improve this answer
$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.