How to define function which changes at certain condition

Question

T1[z_, t_] = (A1 Cos[z] + B1 Sin[z]) Exp[t];(*from z=0 to z=a=1*)
T2[z_, t_] = (A2 Cos[z] + B2 Sin[z]) Exp[t];(*from z=a=1 to z=b=2*)
T3[z_, t_] = (A3 Cos[z] + B3 Sin[z]) Exp[t];(*from z=b=2 to z=c=3*)
Interval1 = [0, a];
Interval2 = [a, b];
Interval3 = [b, c];
T[z_,t_]=...

This is basic definition of my problem. Is have temperature function depending on time t and location z.

I have 1D problem (z) where i have three different layers and in each layer, temperature has its own function T1,T2,T3. A1,A2,A3,B1,B2,B3 are known (random) constants (you can make them up for this example)

For each area/interval temperature changes by its presented function T1,T2,T3.

Is it possible to define globally mora general temperature function T[z_,t_] where you can define that on certain/given interval takes form of the predefined Ti[z,t] function, for instance when z=[0,a], T[z,t]=T1[z,t], when z is in [a,b],then T[z,t]=T2[z,t] and so on...

Answer 1

Something like this?

T[z_,t_]:=
  Which[
    z<0,BadT[z,t],
    z<a,T1[z,t],
    z<b,T2[z,t],
    z<c,T3[z,t],
    True,BadT[z,t]]

Alternatively, you can add conditions:

T[z_, t_] := (A1 Cos[z] + B1 Sin[z]) Exp[t] /; 0 <= z < a;
T[z_, t_] := (A2 Cos[z] + B2 Sin[z]) Exp[t] /; a <= z < b;
T[z_, t_] := (A3 Cos[z] + B3 Sin[z]) Exp[t] /; b <= z < c;

Or another option with Piecewise:

T = 
  Piecewise[
    {{T1[z, t], 0 <= z < a}, 
     {T2[z, t], a <= z < b},
     {T3[z, t], b <= z < c}, 
     {BadT[z, t], True}}]

In this latter case, you would use it something like this:

Plot3D[T, {z, 0, c}, {t, 0, 1}]

(For all of these, I'm assuming that a, b, c, A1, B1, etc have all been defined)