Precision Lost for Simultaneous NonLinearModelFit

Question

I am having trouble with the below code. I have two data sets, dataf and datag, which are exponential decays. datag decays faster than dataf. These two data sets are then later joined to make datah. I would like to simultaneously fit these two data sets with the functions f[x] and g[x], respectively. In the NonLinearModelFit of datah I use suitable initial conditions for the values of a and b, but as can be seen from the below plot the fits are not good. If I don't use initial conditions, I get the following error message: "General::munfl: Exp[-1.25177*10^10] is too small to represent as a normalized machine number; precision may be lost", and other similar error messages.

dataf = Table[{x, Exp[-x/250]}, {x, 0, 500, 50}];
datag = Table[{x, Exp[-x/100]}, {x, 0, 500, 50}];

datah = Join[{1, Sequence @@ #} & /@ dataf, {2, Sequence @@ #} & /@ 
    datag];

f[x_] := Exp[-47000^2 ((a (4 a^2 + 21 a b + 9 b^2))/(
     30 (a + b) (4 a + b))) x];
g[x_] := Exp[-130000^2 ((a (4 a^2 + 21 a b + 9 b^2))/(
     30 (a + b) (4 a + b))) x];

h[\[Omega]_, x_] := 
  KroneckerDelta[\[Omega] - 1]*f[x] + 
   KroneckerDelta[\[Omega] - 2]*g[x];

Clear[a, b]

nlmf = NonlinearModelFit[datah, 
   h[\[Omega], x], {{a, 10^-12}, {b, 10^-12}}, {\[Omega], x}];

Show[ListPlot[{dataf, datag}, PlotMarkers -> {\[FilledCircle], 10}, 
  Joined -> False], Plot[{nlmf[1, x], nlmf[2, x]}, {x, 0, 500}]]

nlmf["ParameterConfidenceIntervalTable"]

If the exponential decays are quicker and the values inside the exponentials are smaller then the fits become reasonable. If anyone has any suggestions about how to resolve this issue then that would be greatly appreciated. Thanks.

Answer 1

There's a very simple answer to your question: you have only one free parameter in your fitting function.

You may think you have two of them, $a$ and $b$, but in reality, you only have one, let's name it $c$:

$$c = \frac{a (4 a^2 + 21 a b + 9 b^2)}{ (a + b) (4 a + b)}$$

The functions you are trying to fit are then:

$$f(x) = e^{-\alpha c x}, \quad g(x) = e^{-\beta c x}, \quad \alpha=\frac{220900000 }{3}, \beta=\frac{1690000000}{3}.$$

This means that the two exponentials have a predefined ratio of their decays. That is:

$$\frac{\text{decay rate of }f(x)}{\text{decay rate of }g(x)} = \frac{\alpha c}{\beta c} = \frac{\alpha}{\beta}= \frac{2209}{16900}\approx 0.13.$$

Therefore, when you decide about the decay rate of $f(x)$, you also fix the other one. But look at your data! dataf decays with the rate $-1/250$ and datag with $-1/100$. Their ratio is $2/5 = 0.4$.

\[Alpha] = 220900000/3;
\[Beta] = 1690000000/3;
f[x_, c_] := Exp[-\[Alpha] c x];
g[x_, c_] := Exp[-\[Beta] c x];
h[\[Omega]_, x_, c_] := 
 KroneckerDelta[\[Omega] - 1]*f[x, c] + 
  KroneckerDelta[\[Omega] - 2]*g[x, c]

Manipulate[
 Show[Plot[Evaluate[{h[1, x, c], h[2, x, c]}], {x, 0, 500}, 
   PlotRange -> {0, 1}], ListPlot[{dataf, datag}]], {c, 0, 1*^-10}]

I don't really know what the underlying model is and why you are trying to simultaneously fit both of the curves. You can, of course, fit each of them separately with their own $c$ (or $a$ and $b$, if you want).

nlmf = NonlinearModelFit[#[[1]], Exp[-#[[2]] c x], {{c, 1*^-10}}, 
    x] & /@ {{dataf, \[Alpha]}, {datag, \[Beta]}}

Show[ListPlot[{dataf, datag}], 
 Plot[Evaluate@Through[nlmf[x]], {x, 0, 500}]]