Exploring Matrix Powers with Wolfram (using Sum Notation)

Question

I am trying to gain an intuition for what algebraically happens to a square matrix (say a $2$-dimensional square matrix) when it is successively multiplied by itself. I have used

m = Table[Subscript[\[Omega], i, j], {i, 2}, {j, 2}];
Manipulate[MatrixForm@Expand@MatrixPower[m, k], {k, 0, 5, 1}]

to show the expansion of the matrix after raising it to the 0th through 5th power. Here's the 3rd power to show how complicated it gets:

This is too complicated for me to discern a pattern, but my guess is that a pattern does emerge if we somehow tidy up this notation using $\sum$ notation.

Question: Does Wolfram provide some way of easily converting the above MatrixPower into a form using $\sum$ notation?

Answer 1

I don't have answer for using Sigma notation but in case of finding pattern, converting existing matrix cells to some graphic maybe become helpful.

For example instead of using this form:

Use these:

,

For power of 2, results are:

,

Here is the interface of the code to play:

Code:

Manipulate[
 Module[{vars, shapes}, 
  vars = Table[
    Subscript[w, i, j], {i, 1, dimension}, {j, 1, dimension}];
  shapes = 
   Transpose[
     Append[{Flatten@vars}, 
      If[useNumber == 1, 
       Text[Style[#, Bold, 16]] & /@ Range[1, dimension^2], 
       MatrixPlot[#, FrameTicks -> None, ImageSize -> 20] & /@ 
        Table[ArrayReshape[
          RotateRight[PadLeft[{1}, dimension^2], i], {dimension, 
           dimension}], {i, 1, dimension^2}]]]] /. {x1_, x2_} -> x1 -> x2;

  Column[{Subsuperscript["M", ToString@dimension <> "x" <> ToString@dimension, power], 

    Grid[(MatrixPower[vars, power]) /. shapes, Frame -> All, 
     FrameStyle -> Directive[LightGray, Thick]]}]], 
     {{dimension, 2, "Dimension"}, 2, 5, 1}, 
     {{power, 1, "Power"}, 1, 5,  1}, 
     {{useNumber, 0, "Use number"}, {0, 1}}]

Answer 2

Here is one of those places where it really helps to know some linear algebra. Say you have a diagonalizable matrix (for example, any symmetric matrix) m. Then you can break it into Inverse[v].d.v where v are the eigenvectors and d is a diagonal matrix of the eigenvalues. Then powers of m have a nice form. For example:

m1 = RandomInteger[{-10, 10}, {2, 2}];
m = m1 + Transpose[m1]

{d, v} = Eigensystem[m]

Note that

Inverse[v] . DiagonalMatrix[d] . v // FullSimplify

is the same as m. More importantly,

Inverse[v] . (DiagonalMatrix[d]^2) . v // FullSimplify

is the same as m.m

and

Inverse[v] . (DiagonalMatrix[d]^n) . v 

is the same as the matrix product of m taken n times. Since the middle term is a diagonal matrix, its power is just the power of the individual diagonal elements. So you can see all powers of m using one formula.

When the matrix isn't diagonalizable, you can do an analogous thing using the Jordan form, but it's a bit more complicated.