Randomly generated coordinates

Question

I want to code that will do the following:

Write a Mathematica function called randomHop that takes as its argument a list containing two coordinates x and y; your definition should begin

randomHop[{x_, y_}] := 

The function should then generate a random integer r equal to 1 or 2 (this should be locally scoped), and then

• if r is equal to 1, return {{0.5, 0.5}, {0.5, 0.5}} . {x, y};
• if r is 2, return {{-0.5, -0.5}, {0.5, -0.5}} . {x, y} + {1.0, 0}.

I have so far tried

randomHop[{x_, y_}] := (
  r = RandomInteger[{1, 2}]
  If[r == 1, Return[{{0.5, 0.5}, {0.5, 0.5}}.{x, y}], 
  Return[{{-0.5, -0.5}, {0.5, -0.5}} . {x, y} + {1.0, 0}]])

but it's not working, and I don't know why. Any help would be appreciated.

Answer 1

To localize r, I would use Module. Otherwise, the only changes needed are inserting a missing semicolon and getting rid of the unnecessary Return calls.

ClearAll[randomHop];
randomHop[{x_,y_}]:=Module[{
    r
},
    r=RandomInteger[{1,2}];
    If[r==1,
        {{0.5,0.5},{0.5,0.5}}.{x,y},
        {{-0.5,-0.5},{0.5,-0.5}}.{x,y}+{1,0}
    ]
];

SeedRandom[1];

NestList[randomHop,{1,2},10];

{{1, 2}, {-0.5, -0.5}, {1.5, 0.}, {0.75, 0.75}, {0.25, 0.}, {0.125, 0.125}, 
 {0.125, 0.125}, {0.125, 0.125}, {0.875, 0.}, {0.4375, 0.4375}, {0.5625, 0.}}

Visualize the path like:

NestList[randomHop,{1,2},10]//ListLinePlot

Answer 2

randomHop[{x_, y_}] := If[RandomInteger[{1, 2}] == 1, {{0.5, 0.5}, {0.5, 0.5}}.{x, y}, 
    {{-0.5, -0.5}, {0.5, -0.5}}.{x, y} + {1.0, 0}]

also works.