How to Create an Efficient Step Function from Data

Question

I have list of rules from where a DateListStepPlot can be created to visualize the problem:

dateToPopulationRules = {DateObject[{2019, 1, 1}] -> 5, DateObject[{2019, 2, 1}] -> 10, DateObject[{2019, 2, 13}] -> 6, DateObject[{2019, 4, 4}] -> 1};
DateListStepPlot[List @@@ dateToPopulationRules, PlotMarkers -> Automatic, FrameLabel -> {None, "Population"}]

I want to create an efficient function for population using a huge instance of dateToPopulationRules. Here's my poor implementation:

Clear[population];
population[dateObj_] := 0;
Table[
  With[{dateLim = First@dpr, pop = Last@dpr},
   population[dateObj_] := Condition[pop, dateObj >= dateLim]
   ]
  , {dpr, dateToPopulationRules}];

An example showing how the population function works is below. You may want to see DownValues@population in case that helps understanding my code.

In[11]:= population[DateObject[{2019, 3, 1}]]
Out[11]= 5

Although this approach is effective I don't think is the most efficient. I would like to see another solution using a Nearest function or other function that can handle large data sets efficiently.

Answer 1

You could use Interpolation as suggested @Sjoerd, for example:

data = List @@@ dateToPopulationRules /. d_DateObject :> AbsoluteTime[d];

p = Interpolation[
    data . {{-1, 0}, {0, 1}},
    InterpolationOrder->0
] @* Minus;

where I need to use a double negation to get the end point behavior correct. Visualization:

Plot[
    p[x],
    {x, AbsoluteTime@DateObject[{2019,1,1}], AbsoluteTime@DateObject[{2019,6,1}]},
    PlotRange->{0,10.5},
    Ticks->{
        Charting`DateTicksFunction[Automatic, DateTicksFormat -> {Automatic}],
        Automatic
    },
    Epilog -> {PointSize[Large], Point[data]} 
]

If you want a faster function, you could try using StepFunction from How can the behavior of InerpolationOrder->0 be controlled:

q = StepFunction[data, Right];
Plot[
    q[x],
    {x, AbsoluteTime@DateObject[{2019,1,1}], AbsoluteTime@DateObject[{2019,6,1}]},
    PlotRange->{0,10.5},
    Ticks->{
        Charting`DateTicksFunction[Automatic, DateTicksFormat -> {Automatic}],
        Automatic
    },
    Epilog -> {PointSize[Large], Point[data]} 
]

Speed comparison:

times = RandomReal[
    AbsoluteTime /@ {DateObject[{2019, 1, 1}], DateObject[{2019, 4, 1}]},
    10^5
];

r1 = p[times]; //RepeatedTiming
r2 = q[times]; //RepeatedTiming

r1===r2

{0.14, Null}

{0.0072, Null}

True

So, using StepFunction is almost 20 times faster.

Answer 2

You may useTimeSeries with the ResamplingMethod option.

tsPop = TimeSeries[List @@@ dateToPopulationRules,
  ResamplingMethod -> {"Interpolation", InterpolationOrder -> 0}]

InterpolationOrder -> 0 repeats prior value until new value is defined.

tsPop[DateObject /@ {{2019, 1, 30}, {2019, 2, 1}}]

{5, 10}

Plot with DateListStepPlot.

DateListStepPlot[tsPop, Mesh -> Full]

Hope this helps.