Problem with extracting a constant multiplier out of sum

Question

For a generic symbol A[i]

2 Sum[A[i], {i, 1, n}] == Sum[2 A[i], {i, 1, n}]

does not return True.

Is there any reason behind these behaviors? Do we have any way to evaluate the equation correctly?

ADDED:

I would like to thank everyone who noted the comments. I am afraid my use of Simplify makes everyone confused. I want to ask not the behavior of Simplify, but that of Sum and Equal. Is it intentional or kind of a "bug"?

Edited:

What I would like to ask is about Sum and I have not intended to ask the use of Simplify. So, I edited the title again.

As I have written below, mathematically Sum[2 ..] is equivalent to 2 Sum[..]. I thought that as long as mathematically correct, Mathematica returns immediate values, especially for trivial cases, just like the examples of a + b == b + a or a b == b a. Does not this hold for Sum? Do we have any way to let Mathematica evaluate the relation mathematically correctly? This is my question. I am sorry if my question was ambiguous.

Answer 1

Simplify just transforms the equation into another, hopefully simpler form. Do not expect it to "solve" problems. It is not its purpose.

Simplify also does not give any guarantees about success. It only guarantees that the output is equivalent to the input. Simplify does a heuristic search by applying various transformation. If it does not find a simpler form, it does not mean that one does not exist.

To give some insight into why it handled one case but not the other:

• Simplify generally works with expressions consisting of plain functions, not things like sums or integrals

• Setting an explicit value for n allows the sums to evaluate

Answer 2

Your question "Do we have any way to evaluate the equation correctly?" is yes because Mathematica allows you to define arbitrary rules to perform manipulation of expressions.

In your particular use case the simplistic code

2 Sum[A[i], {i, n}] == Sum[2 A[i], {i, n}] /. Sum[k_ x_, {y_, z_}] :> k Sum[x, {y, z}]

returns True as you wanted. However, the code is too loose. Therefore, you may want to use the pattern k_?NumberQ instead of just k_. For more generality, try the code

rule =  Sum[Times[Longest[u___], x___] , {y_, z___}] :> 
         Times[u] Sum[Times[x], {y, z}] /; (FreeQ[{u}, y]);
2 b[j] Sum[A[i], {i, n}] == Sum[b[j] 2 A[i], {i, n}] /. rule

which returns True as you would expect. Notice the use of FreeQ to ensure that what is moved outside the summation does not depend on the summation index. Also notice that the rule allows summations over range variations such as {i, a, b} or {i}.

In general, Mathematica does certain transformations to expressions automatically. For example, the Plus and Times functions have attributes Orderless and Flat which means that they are commutative and associative. That is the reason why a + b == b + a and a b == b a evaluate to True automatically by default. However, that does not extend to a (b + c) == a b + a c which seems as though it should be true also. For cases like this Mathematica has certain transformations that are used if requested by Expand or Simplify. That allows the expressions a (b + c) == a b + a c // Expand or a (b + c) == a b + a c // Simplify to evaluate to True as you would expect.

In the particular case of summations, the designers of Mathematica, for unknown reasons, decided not to implement a general rule which would move factors out of a summation even if they are constant. Perhaps that may change in future versions.