How to calculate the Fourier transform of Sinc[b (ω1 - ω2)]?

Question

I would like to calculate the Fourier transform of Sinc[ b (ω1 - ω2)], but there are some problems as follows:

---

My target is

$\int _{-\infty }^{\infty }\int _{-\infty }^{\infty }\text{Sinc}(b (\text{$\omega_1$}-\text{$\omega_2$})) e^{-i \text{$ \omega_1 t_1$} } e^{-i \text{$ \omega_2 t_2 $} } d \text{$\omega_1$} d\text{$\omega_2$} =\frac{2 \pi ^2}{b} \Pi \left(\frac{\text{$t_1$}}{2 b}\right) \delta (\text{$t_1$}+\text{$t_2$})$

---

The problem is as follow:

I use the following code

    Assuming[{b >0 }, FourierTransform[  Sinc[b (ω1 - ω2)], {ω1, ω2}, {t1, t2}, \!\(TraditionalForm\`FourierParameters -> {1, \(-1\)}\)]]

After runing the above code for a long time, the out put is

    (I \[Pi] DiracDelta[t1+t2] (-Log[I b-I t1]+Log[-I b+I t1]+Log[-I (b+t1)]-Log[I (b+t1)]))/b

It can be further simplified to be 0, because

    Log[-I (b - t1)] + Log[-I (b + t1)] - Log[I (b - t1)] - Log[I (b + t1)]

    = Log[I (b - t1)*I (b + t1)] - Log[I (b - t1)*I (b + t1)]

    = Log[-b^2 + t1^2] - Log[-b^2 + t1^2]

    = 0

This means $\int _{-\infty }^{\infty }\int _{-\infty }^{\infty }\text{Sinc}(b (\text{$\omega_1$}-\text{$\omega_2$})) e^{-i \text{$ \omega_1 t_1$} } e^{-i \text{$ \omega_2 t_2 $} } d \text{$t_1$} d\text{$t_2$} =0$ ??

How to solve this porblem?

---

Clue 1: $Sinc[ω1 - ω2]$

    FourierTransform[ Sinc[ω1 - ω2], {ω1, ω2}, {t1,   t2}, \!\(TraditionalForm\`FourierParameters -> {1, \(-1\)}\)]

The result is $ π^2 DiracDelta[t1 + t2] (Sign[1 - t1] + Sign[1 + t1]) $.

But in Mathematica, (Sign[1 - t1] + Sign[1 + t1]) does not equal to 2 UnitBox[t1/2], because FullSimplify[Sign[1 - t1] + Sign[1 + t1] - 2 UnitBox[t1/2]] = Piecewise[{{-1, t1 == -1 || t1 == 1}}, 0]

---

Clue 2: $Sinc[b ω]$

    FourierTransform[ Sinc[b ω], {ω}, {t}, \!\(TraditionalForm\`FourierParameters -> {1, \(-1\)}\)]

The result is $ \frac{\pi}{2 b} (Sign[b - t] + Sign[b + t])$.

---

Clue 3: $Sinc[3 (ω1 - ω2)]$

    Assuming[{a > b },  FourierTransform[Sinc[3 (ω1 - ω2)], {ω1, ω2}, {t1, t2}, \!\(TraditionalForm\`FourierParameters -> {1, \(-1\)}\)]]

The result is 0.

---

Any comment or suggestion would be highly appreciated.

Answer 1

By Fubini's theorem, we can relate multiple integrals to iterated integrals, i.e. $$\int f(x,y) dxdy=\int\left(\int f(x,y)dx\right)dy$$ as long as the integrand is sufficiently convergent. I am not sure if this is the case at hand, but I will assume it nonetheless.

In practise, this means that we can replace FourierTransform[f[a,b],{a,b},{x,y}] with FourierTransform[FourierTransform[f[a,b],a,x],b,y]. To simplify the calculations further, I will insert a FullSimplify between the FourierTransforms so that the calculation is faster and simpler.

Timing[ FourierTransform[ FullSimplify[ FourierTransform[Sinc[a( x-y)],x,t,FourierParameters->{1,-1}] ,{t,y,a}\[Element]Reals ],y,s,FourierParameters->{1,-1} ] ]

yields

{0.039023,(\[Pi]^2 DiracDelta[s+t] (Sign[a-t]+Sign[a+t]))/a}

on my laptop.

Answer 2

Still not a full answer, but maybe pointing towards the solution.

PiecewiseExpand[
 FourierTransform[
  Sinc[ω1 - ω2], 
  {ω1, ω2}, {t1, t2}, 
  FourierParameters -> {1, -1}
  ],
 t1 ∈ Reals
 ]

This does not work with Sinc[b (ω1 - ω2)], though and I don't know why. It should only be a matter of the transformation formula, but apparently, Mathematica is not clever enough to apply it automatically.

Answer 3

Starting with the previous result as $f$ and using Simplify we can obtain

f = π/b I DiracDelta[t1 + t2] 
     (-Log[I b - I t1] + Log[-I b + I t1] + Log[-I (b + t1)] - Log[I (b + t1)]);
Simplify[f, Assumptions -> 0 < b < t1]
Simplify[f, Assumptions -> -b < t1 < b]
Simplify[f, Assumptions -> t1 < -b < 0]

(*
    0
    (2 π^2 DiracDelta[t1 + t2])/b
    0
*)

However, we get another factor of 2 when we evaluate

FourierTransform[ Sinc[b (ω1 - ω2)], {ω1, ω2}, {t1, t2},
 FourierParameters -> {1, -1}, Assumptions -> -b < t1 < b]


(*   (4 π^2 DiracDelta[t1 + t2])/b   *)

Answer 4

The problem becomes simpler when you do a unitary variable substitution:

$$ s = \frac{t_1+t_2}{\sqrt{2}} \qquad \sigma = \frac{t_1-t_2}{\sqrt{2}}\\ x = \frac{\omega_1+\omega_2}{\sqrt{2}} \qquad y = \frac{\omega_1-\omega_2}{\sqrt{2}}\\ $$

The double Fourier integral then separates into two easy ones:

$$ \int_{-\infty}^{\infty}\int_{-\infty}^{\infty}\text{sinc}[b(\omega_1-\omega_2)]e^{-i\omega_1t_1}e^{-i\omega_2t_2}d\omega_1d\omega_2 = \int_{-\infty}^{\infty}\int_{-\infty}^{\infty}\text{sinc}(\sqrt{2}by)e^{-isx}e^{-ity}dx\,dy\\ = \left( \int_{-\infty}^{\infty} e^{-isx} dx\right) \left( \int_{-\infty}^{\infty} \text{sinc}(\sqrt{2}by)e^{-ity}dy\right) $$

These we can do with Mathematica:

Sqrt[2π]*InverseFourierTransform[1, x, s]
(* 2π*DiracDelta[s] *)

Sqrt[2π]*InverseFourierTransform[Sinc[Sqrt[2]*b*y], y, t] // Simplify

(* π*(Sign[Sqrt[2]*b-t] + Sign[Sqrt[2]*b+t])/(2*Sqrt[2]*b) *)

Hence the result is

$$ 2\pi\delta(s) \cdot \frac{\pi[\text{sign}(\sqrt{2}b-t)+\text{sign}(\sqrt{2}b+t)]}{2\sqrt{2}b}\\ = \frac{\pi^2}{\sqrt{2}b}\delta\left(\frac{t_1+t_2}{\sqrt{2}}\right)\left[\text{sign}\left(\sqrt{2}b-\frac{t_1-t_2}{\sqrt{2}}\right)+\text{sign}\left(\sqrt{2}b+\frac{t_1-t_2}{\sqrt{2}}\right)\right]\\ = \frac{\pi^2}{b}\delta(t_1+t_2)\left[\text{sign}\left(b-\frac{t_1-t_2}{2}\right)+\text{sign}\left(b+\frac{t_1-t_2}{2}\right)\right]\\ = \frac{\pi^2}{b}\delta(t_1+t_2)\left[\text{sign}(b-t_1)+\text{sign}(b+t_1)\right] $$

where the last step uses the $\delta$-function to constrain $t_2=-t_1$ and thus to simplify the $\text{sign}$-functions' arguments with $\frac{t_1-t_2}{2}=t_1$.

If you're not too picky about the boundaries where $t_1=\pm b$, then the second half can be written as twice the UnitBox function $\Pi$:

$$ \ldots = \frac{2\pi^2}{b}\delta(t_1+t_2)\cdot \Pi\left(\frac{t_1}{2b}\right) $$

This confirms your target solution.