Removing lists with zero at any position

Question

I want to delete the complete list within a list containing 0 at any position.

I tried using:

DeleteCases[Tuples[Range[-2, 2], 2], {0 ..}]

{{-2, -2}, {-2, -1}, {-2, 0}, {-2, 1}, {-2, 2}, {-1, -2}, {-1, -1}, {-1, 0}, {-1, 1}, {-1, 2}, {0, -2}, {0, -1}, {0, 1}, {0, 2}, {1, -2}, {1, -1}, {1, 0}, {1, 1}, {1, 2}, {2, -2}, {2, -1}, {2, 0}, {2, 1}, {2, 2}}

But only the lists starting with 0 are removed.

How can I remove the entire list that contains 0 at any place?

kglr · Accepted Answer · 2018-09-13 05:36:39Z

11

 DeleteCases[Tuples[Range[-2, 2], 2], {___, 0, ___}] (* or *)
 DeleteCases[data, {0, 0}|{1,0}|{0,1}]

{{-2, -2}, {-2, -1}, {-2, 1}, {-2, 2}, {-1, -2}, {-1, -1}, {-1, 1}, {-1, 2}, {1, -2}, {1, -1}, {1, 1}, {1, 2}, {2, -2}, {2, -1}, {2, 1}, {2, 2}}

Alternatively, if you can, remove zeros from the input lists before using Tuples:

Tuples[Join[-Reverse@#, #]&@Range[2],2]

same result

Even if data = Tuples[Range[-2, 2], 2] is already created, processing data to create a zero-free input list and using Tuples on it is (to my surprise) faster than using Pick to remove entries with zeros from pairs of data:

data = Tuples[Range[-100, 100], 2];

ra = Tuples[Join[-Reverse @ #, #]& @ Range[100],2]; // RepeatedTiming // First

0.0000524

rb = With[{r = DeleteCases[DeleteDuplicates @ Flatten[data], 0]},
  Tuples[r, 2]];// RepeatedTiming // First

0.000178

rc = Pick[data, Unitize[data].{1, 1}, 2];//RepeatedTiming//First (*from @Henrik's answer*)

0.0013

rd = DeleteCases[data, {0, 0}|{1,0}|{0,1}];// RepeatedTiming // First

0.017

re = DeleteCases[data, {___, 0, ___}];// RepeatedTiming // First

0.026

rf = Select[data, FreeQ[0] ];// RepeatedTiming // First  (*from David's answer *)

0.060

ra == rb == rc == rd == re == rf

True

edited Sep 13, 2018 at 5:36

answered Sep 12, 2018 at 18:51

kglr

401k18 gold badges488 silver badges929 bronze badges

$\begingroup$ Well.... if you're free to delete 0 before using Tuples simply use Tuples[{-2, -1, 1, 2}, 2]. $\endgroup$
– David G. Stork
Commented Sep 12, 2018 at 20:15
$\begingroup$ @David, yes; i used the more cumbersome way to deal with cases like Range[-100, 100] $\endgroup$
– kglr
Commented Sep 12, 2018 at 20:27
1

$\begingroup$ Oh, method b and c... nice out-of-the-box-thinking! $\endgroup$
– Henrik Schumacher
Commented Sep 12, 2018 at 21:42
$\begingroup$ DeleteCases[DeleteDuplicates @ Flatten[data], 0] is not packed, while Join[-Reverse @ #, #]& @ Range[100] is, explaining the difference in timing $\endgroup$
– Carl Woll
Commented Sep 12, 2018 at 23:39
$\begingroup$ @CarlWoll, good point. But in this case, DeleteDuplicates @ Flatten[data] (which is packed) already takes 0.00011 seconds (RepeatedTiming) compared to 3.06*10^-6 for Join[-Reverse @ #, #]& @ Range[100], simply because the former processes a list with dimensions {40401,2} and the latter with just {200}. $\endgroup$
– kglr
Commented Sep 13, 2018 at 0:28

Add a comment |

Henrik Schumacher · Accepted Answer · 2018-09-12 19:08:29Z

9

Here a more cumbersome (not a code golfer) but faster approach:

data = Tuples[Range[-100, 100], 2];
a = DeleteCases[data, {___, 0, ___}]; // RepeatedTiming // First
b = Pick[data, Unitize[data].{1, 1}, 2]; // RepeatedTiming // First
a == b

0.028

0.00098

True

This skips pattern matching in favor of faster vectorized functions.

edited Sep 12, 2018 at 19:08

answered Sep 12, 2018 at 19:01

Henrik Schumacher

110k7 gold badges186 silver badges323 bronze badges

Add a comment |

David G. Stork · Accepted Answer · 2018-09-12 19:58:56Z

9

Or...

Select[Tuples[Range[-2, 2], 2], ! MemberQ[#, 0] &]

or as @ThatGravityGuy points out...

Select[Tuples[Range[-2, 2], 2], FreeQ[#, 0] &]

edited Sep 12, 2018 at 19:58

answered Sep 12, 2018 at 19:38

David G. Stork

42.3k3 gold badges37 silver badges106 bronze badges

1

$\begingroup$ Instead of !MemberQ couldn't you just use FreeQ? $\endgroup$
– NonDairyNeutrino
Commented Sep 12, 2018 at 19:45
$\begingroup$ Oooh... of course. Yes. Thanks. $\endgroup$
– David G. Stork
Commented Sep 12, 2018 at 19:47
$\begingroup$ You can use the operator form FreeQ[0] instead of FreeQ[#, 0] & $\endgroup$
– kglr
Commented Sep 12, 2018 at 21:36
1

$\begingroup$ .. or operator forms of both Select and FreeQ: Select[FreeQ@0]@data $\endgroup$
– kglr
Commented Sep 12, 2018 at 23:17

Add a comment |

eldo · Accepted Answer · 2024-05-26 22:25:03Z

4

list = Tuples[Range[-2, 2], 2];

Using Pick and ContainsNone (new in 10.2)

Pick[list, ContainsNone[{0}] /@ list]

{{-2, -2}, {-2, -1}, {-2, 1}, {-2, 2}, {-1, -2}, {-1, -1}, {-1, 1}, {-1, 2}, {1, -2}, {1, -1}, {1, 1}, {1, 2}, {2, -2}, {2, -1}, {2, 1}, {2, 2}}

answered May 26 at 22:25

eldo

83.1k6 gold badges72 silver badges202 bronze badges

Add a comment |

eldo · Accepted Answer · 2024-01-25 18:50:26Z

3

list = Tuples[Range[-2, 2], 2];

Using SequenceSplit (new in 11.3) with OrderlessPatternSequence

Join @@ SequenceSplit[list, {{OrderlessPatternSequence[0, _]}}]

{{-2, -2}, {-2, -1}, {-2, 1}, {-2, 2}, {-1, -2}, {-1, -1}, {-1, 1}, {-1, 2}, {1, -2}, {1, -1}, {1, 1}, {1, 2}, {2, -2}, {2, -1}, {2, 1}, {2, 2}}

With long lists SequenceSplit gets very slow

answered Jan 25 at 18:50

eldo

83.1k6 gold badges72 silver badges202 bronze badges

Add a comment |

user1066 · Accepted Answer · 2024-01-25 19:23:59Z

3

Pick[#,Unitize[MapApply[Times]@#],1]&[Tuples[Range[-2, 2], 2]]


(* 
   {{-2,-2},{-2,-1},{-2,1},{-2,2},{-1,-2},{-1,-1},{-1,1},{-1,2},{1,-2},
    {1,-1},{1,1},{1,2},{2,-2},{2,-1},{2,1},{2,2}} 
*)

answered Jan 25 at 19:23

user1066

22.7k3 gold badges36 silver badges59 bronze badges

Add a comment |

bill s · Accepted Answer · 2024-01-25 20:30:05Z

3

Remove all the entries with product of the elements zero:

Complement[list, Extract[list, Position[Times[#[[1]], #[[2]]] & /@ list, 0]]]

answered Jan 25 at 20:30

bill s

69.7k4 gold badges103 silver badges198 bronze badges

Add a comment |

E. Chan-López · Accepted Answer · 2024-01-25 20:59:29Z

3

list = Tuples[Range[-2, 2], 2]

Using Replace:

Replace[list, x_ /; ! FreeQ[x, 0] :> Nothing, {1}]

(*{{-2, -2}, {-2, -1}, {-2, 1}, {-2, 2}, {-1, -2}, {-1, -1}, {-1, 1}, {-1, 2},
   {1, -2}, {1, -1}, {1, 1}, {1, 2}, {2, -2}, {2, -1}, {2, 1}, {2, 2}}*)

Or using SequenceCases:

Join @@ SequenceCases[list, s : {__} /; FreeQ[s, 0] :> s]

(*{{-2, -2}, {-2, -1}, {-2, 1}, {-2, 2}, {-1, -2}, {-1, -1}, {-1, 1}, {-1, 2},
   {1, -2}, {1, -1}, {1, 1}, {1, 2}, {2, -2}, {2, -1}, {2, 1}, {2, 2}}*)

answered Jan 25 at 20:59

E. Chan-López

31.1k3 gold badges29 silver badges50 bronze badges

Add a comment |

E. Chan-López · Accepted Answer · 2024-06-22 00:21:30Z

2

list = Tuples[Range[-2, 2], 2];

Another way using GroupBy:

GroupBy[list, Times @@ # != 0 &][True]

{{-2, -2}, {-2, -1}, {-2, 1}, {-2, 2}, {-1, -2}, {-1, -1}, {-1, 1}, {-1, 2},
{1, -2}, {1, -1}, {1, 1}, {1, 2}, {2, -2}, {2, -1}, {2, 1}, {2, 2}}

answered Jun 22 at 0:21

E. Chan-López

31.1k3 gold badges29 silver badges50 bronze badges

Add a comment |

eldo · Accepted Answer · 2024-06-23 00:19:19Z

2

Create and select tuples in one step with SelectTuples by Sander Huisman:

SelectTuples = ResourceFunction["SelectTuples"];

SelectTuples[Range[-2, 2], 2, FreeQ[0]]

{{-2, -2}, {-2, -1}, {-2, 1}, {-2, 2}, {-1, -2}, {-1, -1}, {-1, 1}, {-1, 2}, {1, -2}, {1, -1}, {1, 1}, {1, 2}, {2, -2}, {2, -1}, {2, 1}, {2, 2}}

answered Jun 23 at 0:19

eldo

83.1k6 gold badges72 silver badges202 bronze badges

Add a comment |

Stack Exchange Network

Removing lists with zero at any position

10 Answers 10

Your Answer

Not the answer you're looking for? Browse other questions tagged
pattern-matching
list-manipulation
or ask your own question.

Linked

Hot Network Questions

Removing lists with zero at any position

10 Answers 10

Your Answer

Sign up or log in

Post as a guest

Not the answer you're looking for? Browse other questions tagged pattern-matchinglist-manipulation or ask your own question.

Linked

Related

Hot Network Questions

Not the answer you're looking for? Browse other questions tagged
pattern-matching
list-manipulation
or ask your own question.