Selecting integers which are not a member in an ordered list of integers

Question

I have an ordered list of integers, i.e.:

list = {1,3,5,6,8,10,12,15};

and I want to know if there is a fast way to get a list of the integers that do not appear in this list. The best thing I've come up with is

list2 = Select[Range[Nd], FreeQ[list,#]&];

which for this particular case yields

{2, 4, 7, 9, 11, 13, 14}

but I suspect there is a faster, more efficient way.

Answer 1

This appears to be faster and scales better, depends on sparsity of list I guess:

Complement[Range[Last[#]], #] &@list

Answer 2

list // Pick[Range[Last@#], SparseArray[# -> #], 0] &

{2, 4, 7, 9, 11, 13, 14}

Or:

list // Range[Last@#] /. Thread[# -> Nothing] &

{2, 4, 7, 9, 11, 13, 14}

Answer 3

list = {1, 3, 5, 6, 8, 10, 12, 15};

Using DeleteElements (new in 13.1)

DeleteElements[Range @ Max @ list, list]

{2, 4, 7, 9, 11, 13, 14}

We used Max instead of Last in case list was not sorted.

Answer 4

list = {1, 3, 5, 6, 8, 10, 12, 15};

Using:

Position[ReplacePart[ConstantArray[0, Max[list]], Thread[list -> 1]], 
  0] // Flatten

-> {2, 4, 7, 9, 11, 13, 14}