Why can we assign a value to a function that has not been defined yet?

Question

Consider the following snippet,

fib[1] = fib[2] = 1;
fib[n_Integer] := fib[n - 1] + fib[n - 2]

As a newbie, it seems for me, the first line assigns 1 to fib[1] and fib[2] whereas the fib has not been defined yet.

Question

How can we do that? What is the philosophy behind it (from Mathematica Language's point of view)?

Answer 1

You appear to have expectations that do not conform to the structure of Mathematica definitions and assignments. As Alan notes in his answer f[1] = value is already a definition, specifically a DownValues rule attached to the Symbol f. Such definitions are common in Mathematica, and at least in some contexts are known as indexed objects:

• Tutorial: Making Definitions for Indexed Objects

Many definitions attached to the same Symbol can coexist in Mathematica, and their order of application is determined by certain rules including pattern specificity. Consider for example:

f[a_] = 3;
f[1] = 5;

f[1]

5

This happens because 1 is considered more specific than _, and this definition is placed higher in the rules list despite being specificed second.

?f

Global`f

f[1]=5

f[a_]=3

Answer 2

In fact, you did already define the "function", but only for certain values.

ClearAll[fib]
DownValues[fib]  (* no down values *)
fib[1]  (* no downvalues, so no substitution *)
(* add down values: *)
fib[1] = fib[2] = 1;  (* add down values *)
DownValues[fib]  (* two down values *)
fib[1]  (* matches a down value, so substitution *)
fib[3]  (* does not match, so no substitution *)
fib[n_Integer] := 
 fib[n - 1] + fib[n - 2]  (* add another down value *)
DownValues[fib]  (* three down values *)
fib[3] (* now this matches, so substitution *)