Combining If condition and For loop in Table

Question

I want to generate a square matrix of squares with parallel lines/stripes colored with different colors:

columnNumber = 10;
rowNumber = 10;
icolumn = 1;

Graphics[{EdgeForm[Black],
 Table[{
  If[(i == icolumn  || i == icolumn + 2 || i == icolumn + 4 ||
      i == icolumn + 6 || i == icolumn + 8),
   Blue,
   Green],
  Rectangle[{1.07*i, 1.07*j}]},
 {i, 1, columnNumber, 1.}, {j, 1, rowNumber, 1.}]},
AspectRatio -> 1, ImageSize -> 240]

Here is the result:

I substitute for the If condition,

(i == icolumn || i == icolumn+2 || i == icolumn+4 || i == icolumn+6 || i == icolumn+8)

the For loop

For[icol = 1, icol < 10, icol = icol + 2, If[i == icol, Blue, Green]]

like this:

Graphics[{EdgeForm[Black],
 Table[{
  For[icol = 1, icol < 10, icol = icol + 2,
   If[i == icol, Blue, Green]],
  Rectangle[{1.05*i, 1.05*j}]},
  {i, 1, columnNumber, 1}, {j, 1, rowNumber, 1}]},
 AspectRatio -> 1, ImageSize -> 240]

But then it returns a black image:

Can anyone suggest what is wrong with my code that combines For and If?

Answer 1

Try this for a start:

    lst = Table["", {i, 1, 10}, {j, 1, 10}];
lst1 = Flatten[Table[{{{1, 10}, {i, i}} -> Blue}, {i, 1, 10, 2}], 1];
lst2 = Flatten[Table[{{{1, 10}, {i, i}} -> Green}, {i, 2, 10, 2}], 1];
lst3 = Join[{None, None}, {Join[lst1, lst2]}];

Grid[lst, Dividers -> Directive[White, AbsoluteThickness[0.3]], 
 Background -> lst3, ItemSize -> {2, 2}]

returning this:

Have fun!

Answer 2

In:

matrixPlot[xs_] := 
 MatrixPlot[xs, ColorRules -> {0 -> Green, 1 -> Blue}, Mesh -> All ]
matrixPlot@Array[Mod[#2, 2] &, {10, 10}]

Out:

(Using ColorRules instead of ColorFunction, Thanks to J. M.)

Answer 3

You can use Array pretty much anywhere you can use Table, and when the input is naturally thought of as a function, it is more natural to use Array. In this case the function is

f = Function[{i, j}, {If[OddQ[i], Blue, Green], Rectangle[{1.05*i, 1.05*j}]}]

You can then create the 2d list of rectangles

arr = Array[f, {10, 10}];

and make your graphic:

Graphics[{EdgeForm[Black], arr}]

Naturally you could also use this function with Table, but it is more verbose:

arr2 = Table[f[i, j], {i, 10}, {j, 10}];
Graphics[{EdgeForm[Black], arr2}]

Edit:

Finally, as suggested by bill_s, you might find ArrayPlot adequate to your needs:

f3 = Function[{i, j}, If[OddQ[j], 0, 1]];
arr3 = Array[f3, {10, 10}]
ArrayPlot[arr3, ColorRules -> {0 -> Blue, 1 -> Green}, Mesh -> True, MeshStyle -> Black]

However, the display is a bit different, and you won't have direct access to your array of rectangles.

Edit:

You can change the function however you wish. E.g., To change the width of the strips to 4, just change the f3 to f4:

f4 = Function[{i, j}, If[EvenQ@Floor[(j - 1)/4], 0, 1]]

Answer 4

You mentioned wanting to do it for multiple patterns. Here is a 3-stripe version:

ArrayPlot[ConstantArray[Mod[Range[10], 3], 10],ColorFunction->"Rainbow", Mesh->True]

Change the Mod (change the 3) for a different number of stripes, the colorspace for the coloring, and the size of the array (change the 10) to achieve what you want.

If you want to specify an arbitrary pattern of columns, one approach is to do it with a simple list: for instance a two color pattern with 11 element might be:

pat = {0, 1, 1, 0, 0, 1, 0, 0, 0, 1, 1};
ArrayPlot[ConstantArray[pat, 10], ColorFunction -> "Rainbow", Mesh -> True]

Of course, you can generate the pat in many ways, depending on the exact pattern you want.

Answer 5

I made some changes to YOUR code

Graphics[{EdgeForm[Black], 
Table[{If[EvenQ@i, Green, Blue], Rectangle[{1.05*i, 1.05*j}]}, {i, 
columnNumber}, {j, rowNumber}]}, AspectRatio -> 1, 
ImageSize -> 240]

Answer 6

If you're contemplating complicated coloring patterns, as seems to be the case in the comments, I would suggest creating a function to compute the color of the i,j rectangle.

colorfn[i_, j_] := < your code here >;

Graphics[{EdgeForm[Black],
 Table[{
  colorfn[i, j],
  Rectangle[{1.07*i, 1.07*j}]},
 {i, 1, columnNumber, 1.}, {j, 1, rowNumber, 1.}]},
AspectRatio -> 1, ImageSize -> 240]

For example, the following, with an extra error check, reproduces the OP's figure:

colorfn[i_, j_] :=
  If[(i == icolumn  || i == icolumn + 2 || i == icolumn + 4 ||
      i == icolumn + 6 || i == icolumn + 8),
   Blue,
   Green,
   Red];  (* should not happen; if Red shows up, there's a coding error somewhere *)

See If for an explanation of the fourth argument.

Answer 7

Finally I got four solutions: via ArrayPlot, Graphics, MatrixPlot, and Grid.

columns = 70; (*column numbers*)
rows = 20; (*row numbers*)
j0 = 1; (*first column*)
period = 8;(*period*)
strip = 3; (*strip width*)

Solution with ArrayPlot:

Manipulate[
fStrips = Function[{i, j}, If[Floor[Mod[((j - j0) + period), period], strip] == strip, 
1(*Even numbers*), 0(*Odd numbers*)]];
arrStrips = Array[fStrips, {rows, columns}];
ArrayPlot[arrStrips, ColorRules -> {1 -> Blue, 0 -> Green}, Mesh -> True,   MeshStyle -> Black, ImageSize -> 700], {j0, 1, 10, 
1}, {strip, 1, 6, 1}, {period, 3, 20, 1}]

Solutionwith Graphics:

Manipulate[
colorfn[i_, j_] := If[Floor[Mod[((i - j0) + period), period], strip] == strip, Blue, Green];
Graphics[{EdgeForm[Black], 
Table[{colorfn[i, j], Rectangle[{1.05*i, 1.05*j}]}, {i, 1, columns,
  1}, {j, 1, rows, 1}]}, AspectRatio -> rows/columns, 
ImageSize -> 700], {j0, 1, 10, 1}, {strip, 1, 6, 1}, {period, 3, 20,1}]

Solution with MatrixPlot:

Manipulate[
matrixPlot[xs_] := MatrixPlot[xs, ColorRules -> {0 -> Blue, 1 -> Green, 2 -> Green}, Mesh -> All, AspectRatio -> rows/columns];
matrixPlot@
Array[If[Floor[Mod[(((#2 - j0) - j0) + period), period], strip] == 
  strip, 0, 1] &, {rows, columns}], {j0, 1, 10, 1}, {strip, 1, 6, 1}, {period, 3, 20, 1}]

Solution with Grid:

tableSize = 30;
j0 = 1; (*first column*)
period = 5;(*period*)
strip = 3; (*strip width: used via lstStrip[1], lstStrip[2], and lstStrip[3]*)

lst = Table["", {i, 1, tableSize}, {j, 1, tableSize}];
lst0 = Flatten[Table[{{{1, tableSize}, {i, i}} -> Green}, {i, 1, tableSize, 1}], 1];
lstStrip[veticalLine_] := Flatten[Table[{{{1, tableSize}, {i, i}} -> Blue}, {i, -j0 + veticalLine, tableSize, period}], 1];

lstFinal = Join[{None, 
None}, {Join[lst0, lstStrip[1], lstStrip[2], lstStrip[3]]}];
Grid[lst, Dividers -> Directive[White, AbsoluteThickness[0.3]], Background -> lstFinal, ItemSize -> {2, 2}]

Thanks!!!