Is there a way to hide or toggle the visibility of code?

Question

Many of my notebooks have a similar repeating structure, which is very convenient and reliable for my workflow: a chunk of code defining a Manipulate for exploring some phenomenon, the output of the Manipulate, where the phenomenon can be explored, and then some notes or observations about the phenomenon. When I'm focused on coding, this is fine, but as my focus shifts to the phenomenon itself, the code is distracting and takes up a lot of space, so I'd like to be able to hide or collapse it.

Is there a way to hide or toggle the visibility of code, independently of the results it produces? In effect, what I'm seeking is there reverse of the default behavior, in which code and results that are grouped together can be collapsed to show just the code.

Note that I'm not seeking a way to move the code elsewhere: the point is the be able to easily move back and forth between having the code behind some data or visualization visible, and associated with the output, and having it hidden or collapsed.

Answer 1

Double click the output cell instead

EDIT: From murrays comment: tutorial/WorkingWithCells: "To specify which cells remain visible when the cell group is closed, select those cells and double-click to close the group."

You can only hide cells within groups, not individual cells. Here is a link to the docs for more info.

Answer 2

You can create a palette to show/hide all the input cells in the selected notebook.

CreatePalette[
    Column[{
        Button["Hide code", {
            NotebookFind[SelectedNotebook[], "Output", All, CellStyle];
            FrontEndExecute[FrontEndToken[SelectedNotebook[], "SelectionCloseUnselectedCells"]]
        }],
        Button["Show code", NotebookFind[SelectedNotebook[], "Input", All, CellStyle]]
    }]
]

Answer 3

I have to do this all the time. I only have an annoyingly manual way to solve this. On a mac, Alt-click on the cell marker on the right for an InputCell containing the code, this should select ALL input cells. Then go to the Cell -> Cell Properties menu at the top and unselect the Open item. All the input cells should hide. On the right there should still be tiny little input cell markers. To open them follow the same procedure and select the Open again.

The answer by "rm -rf" is great! Thanks.

Answer 4

In version 9: suppose nb is your notebook object (this can be nb=EvaluationNotebook[], but if you're going to be closing input cells you probably want to have an auxilary notebook a choose the correct notebook from Notebooks[]). Then, to close all the Input cells, for example, do

cells = Cells[nb, CellStyle->"Input"]
SetOptions[#, CellOpen -> False] & /@ cells

To open them back up

SetOptions[#, CellOpen -> True] & /@ cells

Obviously, you can select any style cell to close and open

Answer 5

Alternatively, remove all inputs entirely: (CAUTION)

Copy-pasting the entire notebook to another, new notebook, then pasting the following in it will delete all input cells rather than minimizing them, such that you could send it to someone if you only wanted them to have the output:

Module[{nb},
 nb = EvaluationNotebook[];
 NotebookFind[EvaluationNotebook[], "Input", All, CellStyle];
 NotebookDelete[nb]]

Though, be careful with this method as it deletes all input cells (including itself) in the respective notebook.

Answer 6

Following the solution given by Sjoerd de Vreis and Itai Seggev, I found useful define this pair of functions using their procedure as follows.

• Function for closing all cells inputs:

  CloseAllInputsCells[] := Module[{nb, cells},
    nb = EvaluationNotebook[];
    cells = Cells[nb, CellStyle -> "Input"];
    SetOptions[#, CellOpen -> False] & /@ cells;
   ];
  

• Function for recovering or made visible again:

   OpenAllInputsCells[] := Module[{nb, cells},
    nb = EvaluationNotebook[];
    cells = Cells[nb, CellStyle -> "Input"];
    SetOptions[#, CellOpen -> True] & /@ cells;
   ];
  

How to use it:

1. Copy / Paste both functions above in a fresh / new notebook and run the notebook.
2. Inside your target Notebook, at the end of your document, run CloseAllInputsCells[] . All input cells will be closed.
3. For recovering all inputs again, run OpenAllInputsCells[]

Answer 7

Compiling all the answers above into one executable code below:

CloseAllInputsCells[] := Module[{nb, cells}, nb = EvaluationNotebook[]; 
cells = Cells[nb, CellStyle -> "Input"]; SetOptions[#, CellOpen -> False]& /@ cells;];

OpenAllInputsCells[] := Module[{nb, cells}, nb = EvaluationNotebook[]; 
cells = Cells[nb, CellStyle -> "Input"]; SetOptions[#, CellOpen -> True]& /@ cells;];

Column[{Button["Hide Code", SelectionEvaluate[CloseAllInputsCells[]]], Button["Show Code", SelectionEvaluate[OpenAllInputsCells[]]]}]