How to have an Input cell that doubles as an Output

Question

Motivation / examples:

• on a spreadsheet environment, each cell doubles as input and output. If we click on it, it shows the input; if we hit Enter, it shows the output;
• on this answer, I tried to mimic this kind of behaviour, but in the middle of a text cell (which is kind of an extension of the behaviour I'm asking in this post)

• the template WRI uses for many of their presentations, typically makes use of a function named LargeOverviewMouseover, where the content of the cell changes on a mouseover event, but it forces the editor to delete the input so to have a nice formatted presentation (when I use it, sometimes I end up directly editing the cell expression... ctr+shift+E, so that I don't need to retrieve the original input..., since just hiding the input generally leaves too much dead space, and is highly depending on the stylesheet...):

Question: is there a simple way of creating a Cell that doubles as Input and Output? Converting from one to the other, either on mouseover, or on clicking, or with a smarter way (so to still allow for manipulation of the output content, like dynamics, etc., without passing directly to the Input form...)?

EDIT

Ideally, a solution where the Input aspect of the cell is really an Input cell, would be best (I mean, that has all the code formatting, etc...).

Answer 1

Update

Adjusted solution uses "DownArrowKeyDown"+"ShiftKey" EventHandler instead of Mouseover so you can interact with the output. Some of the code or output has to have focus for the switch to trigger. You still have to hit Enter in the InputField for the new code to register before you hit the down arrow.

DynamicModule[{code = Null, codeInput, visible, modeSwitch = 1},
 codeInput = InputField[Dynamic[code],
   Hold[Expression], FieldHint -> "Type code",
   FieldSize -> {50, 25}];
 visible = codeInput;
 EventHandler[Dynamic@visible,
  {"DownArrowKeyDown" :> If[CurrentValue["ShiftKey"],
    (modeSwitch++; 
     visible = If[EvenQ[modeSwitch], ReleaseHold@code, codeInput])]}
  ]]

This makes it a lot less jittery as well. I also made the InputField bigger.

Try it with Plot3D[x^2 - y^2, {x, 0, 10}, {y, 0, 10}]

---

Original post

With this solution the cell you are inputting into is an output cell but you can enter code into it and it does not create a new cell when it is executed.

One caveat is that you should hit Enter when finished entering your code instead of Shift+Enter.

DynamicModule[{code = Null},
 Mouseover[Dynamic@ReleaseHold@code,
  InputField[Dynamic[code],
   Hold[Expression], FieldHint -> "Type code"]]
 ]

Try it with Table[i, {i, 10}], or Plot[x, {x, 0, 10}], or anything else you can think of.

Hope this helps.