Expanding fractional powers

Question

How does one expand/simplify expressions such as (2 - Sqrt[5])^(1/3)?

Note that this expression equals 1/2 - 1/2 Sqrt[5].

Thank you in advance.

Answer 1

See this, this, and this. In particular,

However, extension of the cube root into the complex plane gives a branch cut along the negative real axis for the principal value of the cube root as illustrated above. By convention, "the" (principal) cube root is therefore a complex number with positive imaginary part. As a result, the Wolfram Language and other symbolic algebra languages and programs that return results valid over the entire complex plane therefore return complex results for $(-x)^{1/3}$.

So if we evaluate

ComplexExpand[(2 - Sqrt[5])^(1/3)]
(* 1/2 (-2 + Sqrt[5])^(1/3) + 1/2 I Sqrt[3] (-2 + Sqrt[5])^(1/3) *)

we see that it gives us the result with the positive imaginary part. As you mentioned in your comment, CubeRoot gives the real-valued cube root, so you can get what you are looking for via

FullSimplify@CubeRoot[2 - Sqrt[5]]
(* 1/2 (1 - Sqrt[5]) *)

You can get all the cube roots via

negativeCubeRoot[x_] := 
 ComplexExpand[(-x)^(1/3) Exp[I # \[Pi]/3] & /@ {-1, 1, 3}]

negativeCubeRoot[(2 - Sqrt[5])]
(* {1/2 (-2 + Sqrt[5])^(1/3) - 1/2 I Sqrt[3] (-2 + Sqrt[5])^(1/3), 
 1/2 (-2 + Sqrt[5])^(1/3) + 1/2 I Sqrt[3] (-2 + Sqrt[5])^(1/3),
 -(-2 + Sqrt[5])^(1/3)} *)

and verify it like

FullSimplify@(%^3)
(* {2 - Sqrt[5], 2 - Sqrt[5], 2 - Sqrt[5]} *)

Answer 2

One roundabout way that sometimes works for radical denesting is to recast as a system of equations, explicitly rewriting every radical as a new variable with a polynomial relation defining it in terms of inner ones. This specific example can be handled as below. Notice that I changed the defining relation from the original question in order to account for the fact that seemingly a surd value was intended rather than the radical as written.

ee = -(-(2 - Sqrt[5]))^(1/3);
polys = {s5^2 - 5, (-(2 - s5)) + s3^3, x - s3};
solns = x /. Solve[polys == 0, {x, s5, s3}];
Quiet[First[Select[solns, Abs[# - ee] < .001 &]]]

(* Out[629]= 1/2 (1 - Sqrt[5]) *)

A related approach is to find a defining polynomial and factor it over an algebraic extension of the rationals that contains whatever values are expected as roots in the eventual result. The lines below indicate how one might go about this.

polys = {s5^2 - 5, (-(2 - s5)) + s3^3, x - s3};
xpoly = First[GroebnerBasis[polys, {s5, s3, x}]]
Factor[xpoly, Extension -> Sqrt[5]]

(* Out[730]= -1 - 4 x^3 + x^6

Out[731]= 1/16 (1 + Sqrt[5] - 2 x) (-1 + Sqrt[5] + 2 x) (-3 + Sqrt[
   5] + (-1 + Sqrt[5]) x - 2 x^2) (3 + Sqrt[5] + (1 + Sqrt[5]) x + 
   2 x^2) *)