How to recover coordinates from a Point

Question

I'm doing some different engineering and geometric manipulation in MMA and am trying to figure out a way to recover the coordinates from the points I translated to the blue line to do further manipulations on them (like drawing interconnecting lines between the two horizontal lines). I've done a pretty good job searching the documentation for such a function, and also approached the problem from a different angle of perhaps using a geometric transform on the original list of pairs but it always seems to come down to the need to convert the list to Point that becomes a problem to continuing on. Any help would be appreciated. Thanks.

bottom = Line[{{x1,y1},{x2,y2}}];
\[Phi] = ArcTan[(y2-y1)/(x2-x1)]// N; (*angle off horizontal*)
\[Theta] = Pi-(\[Phi]+Pi/2); (*offset angle*)
vec = {Cos[\[Theta] ]*depth,Sin[\[Theta] ]*depth} // N (*offset vector*)
list= Prepend[
 {(Cos[\[Phi]]*#)+x1,(Sin[\[Phi]]*#)+y1} &/@ Table[unit * x, {x,n}],
{x1,y1}]      ;        (*points*)
pts = Point /@ list;(*points*)
pts2 = Translate[#,vec] &/@ pts;(*points*)
Graphics[{{Red,bottom},{Blue,Translate[bottom,vec]},
 {Red, pts},{Blue,pts2}}]

Answer 1

Using unit = 1; depth = 1; n = 10; {{x1, y1}, {x2, y2}} = {{0, 0}, {10, 5}}; before the posted code in OP and

g = Graphics[{Red, bottom, Blue, Translate[bottom, vec], Red, pts, Blue, pts2}];

we can recover the coordinates of all Points using

{bluepoints, redpoints} =  GatherBy[SortBy[Cases[g, _Point | Translate[Point[_], _], ∞] /.
  {Translate[Point[x_], t_]:>{1, x + t},  Point[y_]:>{2, y}}, First], First][[;;, ;;, 2]];

Showing the recovered points together with the original g:

Show[g, Prolog -> {Opacity[.5, Green], AbsolutePointSize[10], 
   Point @ bluepoints, Opacity[.5, Yellow], Point @ redpoints}]