Is there an option to change the space/distance between tick labels and axes labels for plots?

Question

In an attempt to squeeze more plots and controls into the limited space for a demo UI, I am trying to remove any extra white spaces I see.

I am not sure what options to use to reduce the amount of space between the ticks labels and the actual text that represent the labels on the axes.

Here is a small Plot example using Frame->True (I put an outside Frame as well, just for illustration, it is not part of the problem here)

Framed[

 Plot[Sin[x], {x, -Pi, Pi},
  Frame -> True,
  FrameLabel -> {{Sin[x], None}, {x, 
     Row[{"This is a plot of ", Sin[x]}]}},
  ImagePadding -> {{55, 10}, {35, 20}},
  ImageMargins -> 0,
  FrameTicksStyle -> 10,
  RotateLabel -> False
  ],

 FrameMargins -> 0
 ]

Is there an option or method to control this distance?

Notice that ImagePadding affects distance below the frame label, and not between the frame label and the ticks. Hence changing ImagePadding will not help here.

Depending on the plot and other things, this space can be more than it should be. The above is just a small example I made up. Here is a small part of a UI, and I think the space between the t(sec) and the ticks is too large. I'd like to reduce it by few pixels. I also might like to push the top label down closer to the plot by few pixels also.

I am Using V9 on windows.

update 12/22/12

Using Labeld solution by @kguler below is a good solution, one just need to be little careful with the type-sitting for the labels. Plot automatically typeset things as Text in TraditionalFormat, which is a nice feature. To do the same when using Labeled one must do this manually using TraditionalForm and Text as well.

Here is example to show the difference

1) Labeled used just with TraditionalForm. The left one uses Plot and the right one uses Labeled with TraditionalForm. Notice the difference in how labels look.

Grid[{
  {

   Plot[Sin[x], {x, -Pi, Pi}, Frame -> True, 
    FrameLabel -> {{Sin[x], None}, {x, E Tan[x] Sin[x]}}, 
    ImageSize -> 300, FrameTicksStyle -> 10, FrameStyle -> 16,RotateLabel -> False],

   Labeled[
    Plot[Sin[x], {x, -Pi, Pi}, Frame -> True, ImageSize -> 300], 
    TraditionalForm /@ {Sin[x], x, E Tan[x] Sin[x]}, {Left, Bottom, Top}, 
    Spacings -> {0, 0, 0}, LabelStyle -> "Panel"]
   }

   }, Frame -> All]

2) Now we do the same, just need to add Text to get the same result as Plot.

Grid[{
  {
   Plot[Sin[x], {x, -Pi, Pi}, Frame -> True, FrameTicksStyle -> 10, 
    FrameStyle -> 16, 
    FrameLabel -> {{Sin[x], None}, {x, E Tan[x] Sin[x]}}, 
    ImageSize -> 300, RotateLabel -> False],

   Labeled[
    Plot[Sin[x], {x, -Pi, Pi}, Frame -> True, ImageSize -> 300], 
    Text /@ TraditionalForm /@ {Sin[x], x, E Tan[x] Sin[x]}, {Left, 
     Bottom, Top}, Spacings -> {0, 0, 0}, LabelStyle -> "Panel"]
   }

   }, Frame -> All]

Update 12/22/12 (2)

There is a big problem with controlling the spacing.

Labeled spacing only seem to work for horizontal and vertical spacing, taken togother.

i.e. One can't control spacing on each side of the plot separately? Here is an example, where I tried to move the bottom axes label up, this ended with moving the top label down as well. Which is not what I want.

Labeled[Plot[Sin[x], {x, -Pi, Pi}, Frame -> True, ImageSize -> 300], 
 Text /@ TraditionalForm /@ {Sin[x], x, E Tan[x] Sin[x]}, {Left, 
  Bottom, Top}, Spacings -> {-.2, -0.7}]

Will see if there is a way to control each side spacing on its own. Trying Spacing->{-0.2,{-0.7,0}} does not work, it seems to take the zero in this case and ignored the -0.7

This gives the same result as above:

Labeled[Plot[Sin[x], {x, -Pi, Pi}, Frame -> True, ImageSize -> 300], 
 Text /@ TraditionalForm /@ {Sin[x], x, E Tan[x] Sin[x]}, {Left, 
  Bottom, Top}, Spacings -> {-.2, -0.7, .0}]

ps. there might be a way to specify the spacing for each side with some tricky syntax. I have not figured it out yet. Still trying thing.... http://reference.wolfram.com/mathematica/ref/Spacings.html

update 12/22/12 (3) Using combination of ImagePadding and Spacing should have worked, but for some reason, the top label now is cut off. Please see screen shot. Using V9 on windows

Note: The above seems to be related to the issue reported here: some Graphics output do not fully render on the screen until an extra click is made into the notebook

Need an extra click inside the notebook. Then label become un-chopped !

Answer 1

The most convenient way I found is to wrap Plot (without FrameLabels and PlotLabel and with appropriate ImagePadding and ImageMargins) inside Labeled and use the Spacings option to position the labels:

 Labeled[Plot[Sin[x], {x, -Pi, Pi}, Frame -> True, 
 ImagePadding -> {{20, 1}, {15, 2}}, ImageMargins -> 0, 
 FrameTicksStyle -> 10], 
 TraditionalForm /@ {Sin[x], x, Row[{"This is a plot of ", Sin[x]}]}, 
 {Left, Bottom, Top}, 
 Spacings -> {0, 0}, LabelStyle -> "Panel"]

Answer 2

This can also be achieved by

• encasing the graphic inside a Show,
• setting the outer Show's PlotRangeClipping to False, and
• adding the labels as Text commands inside an Epilog.

Thus, for your example, you would do

Framed[
 Show[
  Plot[Sin[x], {x, -Pi, Pi}
   , Frame -> True
   , FrameLabel -> {{None, None}, {None, 
      Row[{"This is a plot of ", Sin[x]}]}}
   , ImagePadding -> {{55, 10}, {35, 20}}
   , ImageMargins -> 0
   , FrameTicksStyle -> 10
   , RotateLabel -> False
   ]
  , PlotRangeClipping -> False
  , Epilog -> {
    Text[x, {0, -1.4}],
    Text[Sin[x], {-4.12, 0}]
    }
  ]
 , FrameMargins -> 0
 ]

which produces

You can then freely place the label text anywhere within the image box by adjusting the Text coordinates.

This has the advantage that (as far as I can tell, on v10.1.0) the resulting styling is identical to that produced by setting the labels via AxesLabel or FrameLabel; if you want to style them directly then you can do that as well.

Further, this produces an actual Graphics object, as opposed to an object with a Labeled head, which can be advantageous for manipulating and exporting the resulting plot.

Due credit to David Park's answer on this comp.soft-sys.math.mathematica thread for pointing out the technique.

Answer 3

Another possible (partial) solution is adding negative space. This can be accomplished by putting the label in Framed and setting negative frame margins on one or mode side.

Try this:

Manipulate[
 Framed[Plot[Sin[x], {x, -Pi, Pi}, Frame -> True, 
   FrameLabel -> {{Sin[x], None}, 
     (* HERE'S THE FRAMED LABEL: *)
     {Framed[x, FrameStyle -> None, 
       FrameMargins -> {{0, 0}, {0, -space}}, 
       ContentPadding -> False], 
      Row[{"This is a plot of ", Sin[x]}]}}, 
   ImagePadding -> {{55, 10}, {35, 20}}, ImageMargins -> 0, 
   FrameTicksStyle -> 10, RotateLabel -> False], FrameMargins -> 0],
 {space, 0, 20}
 ]

Adding too much negative space will cause part of the label to be cut off.

Here's a convenience function to shift labels up (positive value) or down (negative value):

shift[space_][x_] := 
 Framed[x, FrameStyle -> None, 
  FrameMargins -> {{0, 0}, If[space > 0, {0, -space}, {space, 0}]}, 
  ContentPadding -> False]

Use it as shift[amount][label] and beware of part of the label getting cut off when the shift is not tiny!

Answer 4

When using SciDraw, we have full control over all label positions. The key option names are variation on TextNudge. The value specified in this option will be added to the label position.

Example with frame labels:

Figure[
 {
   FigurePanel[{}, FrameLabel -> {x, y}, 
     XFrameTextNudge -> 10,     (* shift up by 10 pt *)
     YFrameTextNudge -> {10, 0} (* shift right by 10 pt *)
   ]
 }
]

SciDraw of course draws its own frames and requires working in (and learning) its own framework. It will not help in changing the position of standard frame labels.

The ability of SciDraw to move labels is one of the several reasons why I usually use it for publication figures. I you have the time and are willing to learn it, it is a good option to deal with the label positioning problem.