If we are looking for real solutions, there are none.
Reduce[{ x - Exp[-(1 - x - y - z)] == 0,
y - Exp[-(1 - x/2 - y - z)] == 0,
z - Exp[-(1 - x - 4/5 y - z)] == 0}, {x, y, z}, Reals]
False
Without domain specification (it means we are looking for complex solutions) Reduce has been working for several minutes without yielding results. This is not surprising.
Instead we take a pedestrian approach, although it might be automized a bit more.
From the first equation we see that $x=a$ where we introduced $\quad a = \exp(-1+x+y+z)$. Now we have from the second equation we get $y=a \exp(-x/2) $ and from the third equation we get $z=a\exp(-y/5)$. Next we get an equation for x by eliminating $y$ and $z$ i.e. $x=e^{-1+x+x e^{-\frac{x}{2}} + x e^{-\frac{x}{5} e^{-\frac{x}{2}}}}$. We need to restrict appropriately the complex domain since knowing properties of exponential functions we expect there are infinitely many solutions.
Reduce[ x == Exp[-1 + x (1 + Exp[-x/2] + Exp[-(x/5) Exp[-(x/2)]])] &&
Abs[x] < 2, x]
sx = {ToRules @ % } // N;
x == Root[{-E^(
E^(-(#1/2) -
1/5 E^(-(#1/2)) #1) (-E^(#1/2 + 1/5 E^(-(#1/2)) #1) +
E^(#1/2) #1 + E^(1/5 E^(-(#1/2)) #1) #1 +
E^(#1/2 + 1/5 E^(-(#1/2)) #1) #1)) + #1 &,
0.055803204968110806464128827202522530324263607292 -
0.510206373369089749181274412607230169611834407013 I}] ||
x == Root[{-E^(
E^(-(#1/2) -
1/5 E^(-(#1/2)) #1) (-E^(#1/2 + 1/5 E^(-(#1/2)) #1) +
E^(#1/2) #1 + E^(1/5 E^(-(#1/2)) #1) #1 +
E^(#1/2 + 1/5 E^(-(#1/2)) #1) #1)) + #1 &,
0.055803204968110806464128827202522530324263607292 +
0.510206373369089749181274412607230169611834407013 I}]
The above we've got symbolic representation of exact solutions.
For example taking restriction Abs[z]<5 after roughly 3 minutes I got 133 complex solutions for x.
The results for y and z might be expressed also in the symbolic form, nontheless for brevity we demonstrate them only in the numerical form
sy = y -> x Exp[-x/2] /. sx
{y -> 0.177717 - 0.466416 I, y -> 0.177717 + 0.466416 I}
z -> x Exp[-y/5] /. Transpose[{sx // Flatten, sy}]
{z -> 0.0994856 - 0.485233 I, z -> 0.0994856 + 0.485233 I}
Reduce couldn't find solutions without approprate restriction of domains for x, y, z separately. This is crucial point to get any solutions.