Fortunately, [Wikipedia has the answer](http://en.wikipedia.org/wiki/Centroid#Centroid_of_polygon), as long as we are content to restrict ourselves to non-intersecting closed polygons. This will probably be an acceptable limitation, given that excessively complicated plot markers tend to look slightly distracting anyway.

Because we seek an aesthetic rather than rigorously well defined result, we do not need to be mathematically precise with the way that the polygons are scaled, provided that the centroids are accurate and they all look subjectively about the same size. So, I propose to normalize them by area, and if this does not look quite right, adjustments can be made until a tasteful result is obtained.

We code it in *Mathematica*:

    BeginPackage["PolygonPlotMarkers`"];
    
    ClearAll[PolygonMarker];
    
    Begin["`Private`"];
    
    ClearAll[centroidedAndScaled];
    centroidedAndScaled[coords : {{_?NumericQ, _?NumericQ} ..}] :=
      With[{
        x = coords[[All, 1]], y = coords[[All, 2]],
        i = Range@Length[coords]
        },
       With[{
         xi = x[[i]], yi = y[[i]],
         j = Mod[i + 1, Length[coords], 1]
         },
        With[{
          xj = x[[j]], yj = y[[j]]
          },
         With[{
           area = 1/2 (xi.yj - xj.yi),
           factor = xi yj - xj yi
           },
          With[{
            centroid = 1/(6 area) {(xi + xj).factor, (yi + yj).factor}
            },
           Transpose[{x, y} - centroid]/Sqrt@Abs[area]
           ]
          ]
         ]
        ]
       ];
    
    ClearAll[ngon];
    ngon[n_Integer, phase_?NumericQ] :=
      centroidedAndScaled@Table[
        {Sin[2 Pi k/n + phase], Cos[2 Pi k/n + phase]},
        {k, 0, n - 1}
        ];
    
    ClearAll[coords];
    coords["DownTriangle"] = ngon[3, Pi/3];
    coords["LeftTriangle"] = ngon[3, Pi/6];
    coords["RightTriangle"] = ngon[3, -Pi/6];
    coords["DiagonalSquare" | "Diamond"] = ngon[4, 0];
    coords["Square"] = ngon[4, Pi/4];
    coords["Pentagon"] = ngon[5, 0];
    coords["FivePointedStar"] = {
       {26/27, 5/16}, {12/61, 3/11}, {1/363, 93/92}, {-17/86, 3/11},
       {-26/27, 6/19}, {-8/25, -3/29}, {-31/52, -31/38}, {0, -64/191},
       {28/47, -14/17}, {8/25, -3/29}, {26/27, 5/16}
       };
    coords["Hexagon"] = ngon[6, 0];
    coords["SixPointedStar"] = {
       {17/26, -5/13}, {7/16, 0}, {17/26, 5/13}, {5/23, 5/13},
       {0, 19/25}, {-5/23, 5/13}, {-17/26, 5/13}, {-7/16, 0},
       {-17/26, -5/13}, {-5/23, -5/13}, {0, -19/25}, {5/23, -5/13},
       {17/26, -5/13}
       };
    coords["Cross"] = {
       {20/17, -2/19}, {20/17, 5/46}, {3/26, 5/46}, {3/26, 57/49},
       {-2/17, 57/49}, {-2/17, 5/46}, {-34/29, 5/46}, {-34/29, -2/19},
       {-2/17, -2/19}, {-2/17, -7/6}, {3/26, -7/6}, {3/26, -2/19},
       {20/17, -2/19}
       };
    coords["DiagonalCross"] = {
       {35/38, -23/30}, {7/45, 0}, {35/38, 13/17}, {13/17, 23/25},
       {0, 5/32}, {-13/17, 23/25}, {-35/38, 13/17}, {-7/45, 0},
       {-35/38, -23/30}, {-13/17, -23/25}, {0, -5/32}, {13/17, -23/25},
       {35/38, -23/30}
       };
    
    PolygonMarker[name_String, size_?NumericQ] :=
      Polygon[size coords[name]];
    PolygonMarker[name_String, Scaled[size_?NumericQ]] :=
      Polygon[Scaled[size #, {0, 0}] & /@ coords[name]];
    
    End[];
    
    EndPackage[];

Here, the coordinates of the polygons other than the *n*-gons have come from the font glyphs after converting them to outlines, centroiding, and scaling.

The polygon sizes can be given either in absolute or scaled forms, and the results look okay:

    Graphics[{
      FaceForm[Blue], EdgeForm@Directive[Red, Thickness[0.02]],
      PolygonMarker["FivePointedStar", Scaled[0.2]]
      }, Axes -> True, PlotRange -> {{-1, 1}, {-1, 1}}
     ]

![plot of five-pointed star][1]

Let's check it as an actual plot marker:

    ListPlot[
     ConstantArray[Range[5], 4] + Range[0, 6, 2],
     PlotStyle -> Black, Joined -> True,
     PlotMarkers -> {
       Graphics[{FaceForm[Red], EdgeForm[Red], 
         PolygonMarker["FivePointedStar", Scaled[0.05]]}],
       Graphics[{FaceForm[None], EdgeForm[Green], 
         PolygonMarker["UpTriangle", Scaled[0.05]]}],
       Graphics[{FaceForm[Blue], EdgeForm[Blue], 
         PolygonMarker["DiagonalSquare", Scaled[0.05]]}],
       Graphics[{FaceForm[None], EdgeForm[Black], 
         Disk[{0, 0}, Scaled[0.03]]}]
       },
     PlotRange -> {{0, 6}, All}
    ]

![polygonal PlotMarkers used on a ListPlot][2]

Everything seems good. It may not look absolutely perfect on-screen, because graphics objects are [snapped to the pixel grid](http://mathematica.stackexchange.com/questions/38745/graphics-elements-do-not-line-up-perfectly-in-exported-pdfs) for display. But exporting the resulting plot as e.g. a PDF file will demonstrate that the placement is correct.

  [1]: https://i.sstatic.net/Vm0iT.png
  [2]: https://i.sstatic.net/L2YbH.png