###Summary of the all available information
In the old days space-like characters (spaces, newlines, tabs) inside strings were not interpreted literally, for example [single newlines followed by spaces or tabs were converted to a single space][1]. The `\<\>` syntax was introduced in order to allow literal interpretation of such characters. This syntax was standardized in the modern *Mathematica* notebook format (introduced in 1996).
The kernel simply ignores the `\<\>` delimiters when you `Get` or `Import` a notebook file and also on normal input:
FullForm@"\<1\n2\>"
> "1\n2"
"\<\>" // StringLength
> 0
Note that FrontEnd doesn't remove them on normal input:
"\<\>";
InString[-1]
> "RowBox[{\"\\\"\\\\<\\\\>\\\"\", \";\"}]"
Starting from version 6 the behavior of strings *in normal editing mode* was changed and the `\<\>` syntax is [no longer needed][1] for preserving space-like characters. But when editing the low-level box representation of cells via the FrontEnd (after pressing <kbd>Shift</kbd>+<kbd>Ctrl</kbd>+<kbd>E</kbd>) it is still necessary as [Vladimir shows][2]. These delimiters are also added automatically when you `Export` as `"NB"`, but not added when you `Export` as `"Package"`:
StringCases[ExportString["1\n2", "NB"], "Cell[" ~~ Shortest@__ ~~ "\"Input\"]"] // First //
ImportString[#, "Text"] &
> Cell["\<\
<br>
> 1
<br>
> 2\
<br>
> \\>", "Input"]
ExportString["1\n2", "Package"]
> (* Created with the Wolfram Language : www.wolfram.com *)
>
> "1\n2"
Despite this a Notebook exported as a `"Package"` can be correctly opened or imported as `"NB"` preserving space-like characters:
nb = ImportString[ExportString["1\n2", "NB"], "NB"];
ImportString[ExportString[nb, "Package"], "NB"] === nb
> True
NotebookPut[nb];
[![screenshot][3]][3]
----------
###My experiments with *Mathematica* 11.0.0
Let us consider the example given by John Fultz (please copy the code exactly as written!):
CellPrint@Cell["abc\
d"]
> abc d
It is easy to check that there are 9 spaces between `abc` and `d` in the printed cell (and so are before `d` in the code). But the new line and the backslash are absent! The reason is that the backslash at the end of line is interpreted as an indicator that there is no actual linebreak and the parser should continue reading the expression from the new line.
After pressing <kbd>Shift</kbd>+<kbd>Ctrl</kbd>+<kbd>E</kbd> we can see the code of the printed cell:
Cell["abc d",
GeneratedCell->True,
CellAutoOverwrite->True,
CellChangeTimes->{3.680677305471143*^9}]
Now let us add a space after the backslash (it isn't visible, but it is there!):
CellPrint@Cell["abc\
d"]
> abc
> d
Now we got our newline but the backslash is absent (the next whitespace is present). I think that the absence of the backslash can be related to the series of bugs I discuss in [this answer][4]. The code of the printed cell:
Cell["\<\
abc
d\
\>",
GeneratedCell->True,
CellAutoOverwrite->True,
CellChangeTimes->{3.6806776850508537`*^9}]
Note that similar things happen when we write `\n` instead of entering the newline:
CellPrint@Cell["abc\\n d"]
CellPrint@Cell["abc\ \n d"]
> abc\n d
> abc
> d
In the first case here the newline character `\n` is escaped by the backslash and is present in the output literally. In the second case the backslash is absent again but the space at the first line is preserved.
----------
###An old discussion on MathGroup
A closely related (but not identical) question was asked by user kj and answered by John Fultz in the official newsgroup in 2010, so I'll cite here both the question and the answer completely:
[The question][5]:
> When I examine the source code of *Mathematica* notebooks, I often see
> `Cell` objects whose first argument is preceded by
>
> "\<\
>
> and followed by
>
> \
> \>"
>
> E.g.
>
> Cell["\<\
> Yet another undocumented item.\
> \>", "Text"...
>
> What do these delimiters mean? And how do they differ from the
> `TextData` symbol? (The latter is also undocumented, but at least
> I've seen "cameo appearances" of it in the documentation.)
>
> TIA!
<br>
> ~kj
[The answer][6]:
> `Cell[_String]` is equivalent to `Cell[TextData[{_String}]]` as far as the
> front end is concerned. The former is just an abbreviation of the
> latter syntax, which is necessarily used when the contents are more
> complex (e.g., contain styles or buttons).
>
> The `\<\>` business dates back to a hoarier day (in my opinion) in the
> design of strings in *Mathematica*. Once upon a time, *Mathematica* had
> an odd interpretation of newlines which I probably made more sense in
> the days of 80 character terminal usage. You'll have to forgive
> me...my memory is fuzzy here, and I don't have an old *Mathematica* text
> to double-check this from my current location...but I believe the
> issue was something like this...
>
> "abc\
> d"
>
> ...with the newlines and spaces as shown, being equivalent to "abc d"
> (with just the single space). The `\<\>` business forced everything
> inside the string to really be interpreted literally, with backslash
> at the end of a line meaning to simply escape the newline, and do
> nothing special to leading spaces. Since the *Mathematica* notebook
> format generally wraps at about 70 characters, the non-literal
> interpretation would have made the representation of more than 70
> consecutive spaces difficult.
>
> The modern *Mathematica* notebook format (introduced in 1996) was always
> made to be interpreted properly as a *Mathematica* expression should you
> call `Get[]` on it from the kernel. So this syntax was standardized,
> and is still used today. Now, the kernel simply ignores the `\<\>`
> delimiters as you can see below:
>
> In[1]:== StringLength["\<x\>"]
>
> Out[1]== 1
>
>
> Sincerely,
>
> John Fultz
<br>
> jfultz at wolfram.com
<br>
> User Interface Group
<br>
> Wolfram Research, Inc.
[1]: http://mathematica.stackexchange.com/a/112601/280
[2]: http://mathematica.stackexchange.com/a/105094/280
[3]: https://i.sstatic.net/FMZYa.png
[4]: http://mathematica.stackexchange.com/a/118405/280
[5]: http://forums.wolfram.com/mathgroup/archive/2010/Dec/msg00428.html
[6]: http://forums.wolfram.com/mathgroup/archive/2010/Dec/msg00462.html