15
$\begingroup$

$x^3-x-t=0$ has three roots that can be expressed in hypergeometric form, for example

$$x_1=-1-\frac{t}{2}{_2F_1\left(\frac{1}{3},\frac{2}{3};\frac{3}{2};\frac{27t^2}{4} \right)}+\frac{3t^2}{8} {_3F_2\left(\frac{5}{6},\frac{7}{6},1;\frac{3}{2},2;\frac{27t^2}{4} \right)}$$

See here for more information.

How can I get the solution of the general equation $x^n-x-t=0$ in hypergeometric form with Mathematica?

$\endgroup$
19
$\begingroup$

Since Root objects can be symbolically differentiated, we can find the closed form for its Taylor series (for an explicit n).

root = Root[#1^4 - #1 - t &, 1];
coeff = Refine[FunctionExpand[SeriesCoefficient[root, {t, 0, k}]], k >= 0];
Sum[coeff t^k, {k, 0, ∞}] // FullSimplify
-t HypergeometricPFQ[{1/4, 1/2, 3/4}, {2/3, 4/3}, -256t^3/27]

We can pack this into a function, but we need an alternative to FullSimplify because it becomes too slow.

PostProcess[f_] := Collect[f, _HypergeometricPFQ] /. {a_ F_HypergeometricPFQ :> 
  With[{r = Rationalize[Chop[N[a]]]}, 
    r F /; Precision[r] === ∞
  ]
}

RootToHypergeometric[n_] := Module[{coeff, k},
  coeff = Refine[FunctionExpand[
    SeriesCoefficient[Root[#1^n - #1 - t &, 1], {t, 0, k}]], k >= 0];
  PostProcess[Sum[coeff t^k, {k, 0, ∞}]]
]

Table[n -> RootToHypergeometric[n], {n, 4, 6}]
{
 4 -> -t HypergeometricPFQ[{1/4, 1/2, 3/4}, {2/3, 4/3}, -256 t^3/27], 
 5 -> -HypergeometricPFQ[{-1/20, 3/20, 7/20, 11/20}, {1/4, 1/2, 3/4}, 3125 t^4/256] +
      1/4 t HypergeometricPFQ[{1/5, 2/5, 3/5, 4/5}, {1/2, 3/4, 5/4}, 3125 t^4/256] +
      5/32 t^2 HypergeometricPFQ[{9/20, 13/20, 17/20, 21/20}, {3/4, 5/4, 3/2}, 3125 t^4/256] +
      5/32 t^3 HypergeometricPFQ[{7/10, 9/10, 11/10, 13/10}, {5/4, 3/2, 7/4}, 3125 t^4/256], 
 6 -> -t HypergeometricPFQ[{1/6, 1/3, 1/2, 2/3, 5/6}, {2/5, 3/5, 4/5, 6/5}, -46656 t^5/3125]
}

I don't really see a pattern for a solution in terms of n.

Edit

It looks like the closed form is in the link you provided.

$\endgroup$
  • $\begingroup$ The link that OP provided is a preliminary version of the paper linked in my comment. $\endgroup$ – J. M. will be back soon Nov 2 '15 at 23:07
9
$\begingroup$

It's been a while; I guess I can post my take on the question now.

The following routine for solving the trinomial equation $x^n-x+t=0$ (where $t$ is complex) is of course based on the results of this paper. It returns all $n$ roots, as opposed to just one root. The wrinkle in my implementation is that I elected to represent the (series of) hypergeometric functions presented in the paper in terms of the Meijer $G$-function. (Actually, the Fox $H$-function would have been the more appropriate function to use for the general solution, but since it's not yet built into Mathematica, I had to make do with MeijerG[] through repeated use of the Gauss multiplication formula for the gamma function.)

Here's the routine:

trinomRoots[n_Integer /; n > 1, t_] :=
Append[Table[Exp[-(2 π I j)/(n - 1)] - t/(2 π)^(n - 3/2) Sqrt[n/(n - 1)^3]
             MeijerG[{Append[Range[n - 1]/n, (n - 2)/(n - 1)], {}},
                     {Range[0, n - 2]/(n - 1), {-1/(n - 1)}},
                     -(n^(n/(n - 1)) t Exp[(2 π I j)/(n - 1)])/(n - 1), 1/(n - 1)],
             {j, 0, n - 2}],
       Sqrt[n/(n - 1)^3] (t/Sqrt[2 π])
       MeijerG[{Range[0, n - 1]/n, {}}, {{0}, Range[-1, n - 3]/(n - 1)},
               -n^n (t/(n - 1))^(n - 1)]]

Here are a few examples:

Sort[trinomRoots[5, 1], Re[#1] <= Re[#2] &] // Quiet
   {-1 - (Sqrt[5/2] MeijerG[{{1/5, 2/5, 3/5, 3/4, 4/5}, {}},
                            {{0, 1/4, 1/2, 3/4}, {-1/4}}, 5 5^(1/4)/4, 1/4])/(64 π^(7/2)),
    -I - (Sqrt[5/2] MeijerG[{{1/5, 2/5, 3/5, 3/4, 4/5}, {}},
                            {{0, 1/4, 1/2, 3/4}, {-1/4}}, -5 I 5^(1/4)/4, 1/4])/(64 π^(7/2)),
    I - (Sqrt[5/2] MeijerG[{{1/5, 2/5, 3/5, 3/4, 4/5}, {}},
                           {{0, 1/4, 1/2, 3/4}, {-1/4}}, 5 I 5^(1/4)/4, 1/4])/(64 π^(7/2)),
    1 - (Sqrt[5/2] MeijerG[{{1/5, 2/5, 3/5, 3/4, 4/5}, {}},
                           {{0, 1/4, 1/2, 3/4}, {-1/4}}, -5 5^(1/4)/4, 1/4])/(64 π^(7/2)),
    Sqrt[5/(2 π)]/8 MeijerG[{{1/5, 2/5, 3/5, 4/5}, {}},
                            {{0}, {-1/4, 1/4, 1/2}}, -3125/256]}

FunctionExpand[%[[1]]] // FullSimplify (* show explicit hypergeometric expression *)
   -1 - (261 π^2)/(140 5^(3/4) Gamma[-(7/20)] Gamma[17/20] Gamma[21/20]
       Gamma[49/20]) -
   HypergeometricPFQ[{-1/20, 1/5, 9/20, 7/10}, {2/5, 3/5, 4/5}, 256/3125] -
   1/5 HypergeometricPFQ[{3/20, 2/5, 13/20, 9/10}, {3/5, 4/5, 6/5}, 256/3125] +
   1/25 HypergeometricPFQ[{7/20, 3/5, 17/20, 11/10}, {4/5, 6/5, 7/5}, 256/3125] -
   1/125 HypergeometricPFQ[{11/20, 4/5, 21/20, 13/10}, {6/5, 7/5, 8/5}, 256/3125]

{N[%], N[Root[1 - #1 + #1^5 &, 1]]} (* check *)
   {-1.167303978261419, -1.1673039782614187}

Sort[N[trinomRoots[9, -3 + 4 I], 20]]
   {-1.15737300065622390026 - 0.25869616182022624031 I,
    -1.04152925102213535542 + 0.52458846764227132511 I,
    -0.73118138143615817856 - 0.96088154253626318503 I,
    -0.48212736972957767713 + 1.05763503540895842021 I, 
    0.07216502145935959748 - 1.21942175005944057635 I, 
    0.29590581961582700752 + 1.14008946378455944936 I, 
    0.85499258660164957177 - 0.87742956898864238100 I, 
    0.97603686085833181128 + 0.69847391536413082742 I, 
    1.21311071430892712332 - 0.10435785879534763941 I}

% - Sort[x /. NSolve[x^9 - x + (-3 + 4 I), x, 20]] // Chop // Union
   {0}

As shown above, use FunctionExpand[] on the output of trinomRoots[] to convert the MeijerG[] expressions to their corresponding hypergeometric forms.

$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.